Image Splicing Effect Challenge (Part 1)

Question

I ran across a neat image effect on this image:
Rock In Rio
Thought it might be neat to see how different people in the forums would go about doing this...
Anyhow. Looking forward to your ideas. Take care.
UPDATE*
This thread has been continued into the following thread:
Image Splicing Effect Challenge (Part 2)
“If you want something you've never had, you need to do something you've never done.”
Don't forget to mark
helpful posts and answers
! Answer an interesting question? Write a
new article
about it! My Articles
*This post does not reflect the opinion of Microsoft, or its employees.

Answer 1

I am early staking my claim to pathclip.
Imports System.Drawing.Drawing2D
Public Class Form3
Private path1 As New Drawing2D.GraphicsPath
Private BorderColor As Color = Color.Goldenrod
Private MouseDownIndex As Integer = -1
Private MouseDownX, MouseDownY, MouseDownBmpX, MouseDownBmpY As Integer
Private OffsetX, OffsetY, SliceWidth, SliceStep As Integer
Private bmpSlice As Bitmap = New Bitmap("C:\bitmaps\metallica\metallica bw.jpg")
Private bmpBack As Bitmap = New Bitmap("C:\bitmaps\metallica\metallica background logo.png")
Structure bmpPoint
Public x As Integer
Public y As Integer
Public bmp As Bitmap
End Structure
Private bmpPointList As New List(Of bmpPoint)
Private Sub Form5_Load(sender As Object, e As EventArgs) Handles MyBase.Load
InitilizeControls()
Form5_Resize(0, Nothing)
End Sub
Private Sub PictureBox1_Paint(sender As Object, e As PaintEventArgs) Handles PictureBox1.Paint
With e.Graphics
'draw background fit to window
Using bmpScene As Bitmap = New Bitmap(PictureBox1.ClientSize.Width, PictureBox1.ClientSize.Height)
Using g As Graphics = Graphics.FromImage(bmpScene)
'make temp image, fit to window
g.DrawImage(bmpBack, 0, 0, bmpScene.Width, bmpScene.Height)
'copy temp image to background
If CheckBox2.Checked Then
'add fuzzy
Dim t As Integer = NumericUpDown7.Value + 1
If t > 1 Then
For y = 0 To bmpScene.Height - 1
For x = 0 To bmpScene.Width - 1
If x Mod t = 0 And y Mod t = 0 Then
bmpScene.SetPixel(x, y, Color.White)
End If
Next
Next
End If
.DrawImage(bmpScene, 0, 0)
End If
End Using
End Using
'draw each slice path with inner bitmap
'set translate for global scene
.SmoothingMode = SmoothingMode.AntiAlias
.TranslateTransform(OffsetX - SliceWidth, OffsetY - SliceStep)
For i = 0 To bmpPointList.Count - 1
Using tbmp As Bitmap = bmpPointList(i).bmp.Clone
'setup coordinate origin for this slice
.TranslateTransform(SliceWidth, SliceStep)
'fade slice border edge
If NumericUpDown8.Value > 0 Then
Dim fadewidth As Integer = NumericUpDown8.Value * 10
'calc local coordinate of upper left slice on inner movable bitmap
Dim x2 As Single = path1.PathPoints(3).X - bmpPointList(i).x
Dim y2 As Single = path1.PathPoints(3).Y - bmpPointList(i).y
'calc angle of slice
Dim dx As Single = path1.PathPoints(0).X - path1.PathPoints(3).X
Dim dy As Single = path1.PathPoints(0).Y - path1.PathPoints(3).Y
Dim x1, y1, x3 As Integer
Dim oldClr, newClr As Color
'add fade to temp inner bitmap along edges of path
For y1 = y2 To y2 + dy
x2 += dx / dy
For z = 0 To fadewidth
x1 = Math.Floor(x2) + z
If x1 > 0 And x1 < tbmp.Width And y1 > 0 And y1 < tbmp.Height Then
'left side
oldClr = tbmp.GetPixel(x1, y1)
newClr = Color.FromArgb((255 \ fadewidth) * z, oldClr.R, oldClr.G, oldClr.B)
tbmp.SetPixel(x1, y1, newClr)
x3 = x1 + SliceWidth - (2 * z)
If x3 > 0 And x3 < tbmp.Width Then
'right side
oldClr = tbmp.GetPixel(x3, y1)
newClr = Color.FromArgb((255 \ fadewidth) * z, oldClr.R, oldClr.G, oldClr.B)
tbmp.SetPixel(x3, y1, newClr)
End If
End If
Next
Next
End If
'draw the image slice using the path clipping
.SetClip(path1)
.DrawImage(tbmp, bmpPointList(i).x, bmpPointList(i).y, tbmp.Width, tbmp.Height)
.ResetClip()
'draw border outline path
If CheckBox1.Checked Then .DrawPath(New Pen(BorderColor, 2), path1)
End Using
Next
If CheckBox2.Checked Then
.ResetTransform()
.DrawString("tommytwotrain", New Font("Rockwell Extra Bold", 12), New SolidBrush(BorderColor), 0, PictureBox1.Height - 30)
End If
End With
End Sub
Private Sub PictureBox1_MouseDown(sender As Object, e As MouseEventArgs) Handles PictureBox1.MouseDown
'determine which slice was clicked
Using path2 As Drawing2D.GraphicsPath = path1.Clone
Dim Matrix1, matrix2 As New Matrix
MouseDownIndex = -1
Matrix1.Translate(OffsetX - SliceWidth, OffsetY - SliceStep)
path2.Transform(Matrix1)
matrix2.Translate(SliceWidth, SliceStep)
For i = 0 To bmpPointList.Count - 1
path2.Transform(matrix2)
If path2.IsVisible(e.X, e.Y) Then
MouseDownIndex = i
MouseDownX = e.X
MouseDownY = e.Y
MouseDownBmpX = bmpPointList(MouseDownIndex).x
MouseDownBmpY = bmpPointList(MouseDownIndex).y
Exit Sub
End If
Next
End Using
End Sub
Private Sub PictureBox1_MouseMove(sender As Object, e As MouseEventArgs) Handles PictureBox1.MouseMove
If MouseDownIndex >= 0 Then
'move the image if dragging
Dim thisbmptom As New bmpPoint
thisbmptom = bmpPointList(MouseDownIndex)
thisbmptom.x = MouseDownBmpX - (MouseDownX - e.X)
thisbmptom.y = MouseDownBmpY - (MouseDownY - e.Y)
bmpPointList(MouseDownIndex) = thisbmptom
thisbmptom = Nothing
PictureBox1.Invalidate()
End If
End Sub
Private Sub PictureBox1_MouseUp(sender As Object, e As MouseEventArgs) Handles PictureBox1.MouseUp
MouseDownIndex = -1
End Sub
Private Sub Form5_Resize(sender As Object, e As EventArgs) Handles MyBase.Resize
Dim t As Integer = Me.ClientSize.Height - Panel1.Height
If t > 100 Then PictureBox1.Height = t Else PictureBox1.Height = 100
OffsetX = NumericUpDown3.Value * 10
OffsetY = NumericUpDown4.Value * 10
SliceWidth = NumericUpDown6.Value * 10
SliceStep = NumericUpDown5.Value * 5
'create the slice outline path geometry
Dim w1 As Single = PictureBox1.ClientSize.Width
Dim h1 As Single = 0.7 * PictureBox1.ClientSize.Height
Dim x1 As Single = 0.1 * w1
Dim a As Single = NumericUpDown2.Value * 10 / 57.3
Dim x As Single = Math.Cos(a) * h1 / Math.Sin(a)
Dim thePolygon() As PointF = {New PointF(x1, h1), _
New PointF(x1 + SliceWidth, h1), _
New PointF(x1 + SliceWidth + x, 0), _
New PointF(x1 + x, 0), _
New PointF(x1, h1)}
path1.Reset()
path1.AddLines(thePolygon)
PictureBox1.Invalidate()
End Sub
Private Sub NumericUpDown1_ValueChanged(sender As Object, e As EventArgs) Handles NumericUpDown1.ValueChanged
'create images for number of slices
bmpPointList.Clear()
Dim thisbmpTom As New bmpPoint
For i = 0 To NumericUpDown1.Value - 1
thisbmpTom.bmp = bmpSlice
bmpPointList.Add(thisbmpTom)
Next
Form5_Resize(0, Nothing)
PictureBox1.Invalidate()
End Sub
Private Sub NumericUpDowns_ValueChanged(sender As Object, e As EventArgs) Handles NumericUpDown2.ValueChanged, NumericUpDown3.ValueChanged, NumericUpDown4.ValueChanged, NumericUpDown5.ValueChanged, NumericUpDown6.ValueChanged, NumericUpDown7.ValueChanged, NumericUpDown8.ValueChanged
'general settings
Form5_Resize(0, Nothing)
PictureBox1.Invalidate()
End Sub
Private Sub PictureBox2_Click(sender As Object, e As EventArgs) Handles PictureBox2.Click
Dim cd As New ColorDialog
If cd.ShowDialog Then
BorderColor = cd.Color
PictureBox2.BackColor = BorderColor
End If
PictureBox1.Invalidate()
End Sub
Private Sub CheckBox1_CheckedChanged(sender As Object, e As EventArgs) Handles CheckBox1.CheckedChanged, CheckBox2.CheckedChanged
'border, background
PictureBox1.Invalidate()
End Sub
Private Sub InitilizeControls()
PictureBox1.BackColor = Color.Black
PictureBox1.Dock = DockStyle.Bottom
PictureBox2.BackColor = BorderColor
Panel1.Dock = DockStyle.Top
CheckBox1.Checked = True
CheckBox2.Checked = True
NumericUpDown1.Value = 4 'slices
NumericUpDown1.Maximum = 7
NumericUpDown1.Minimum = 1
NumericUpDown2.Value = 6 'angle
NumericUpDown2.Maximum = 9
NumericUpDown2.Minimum = 1
NumericUpDown3.Value = -6 'offsetx
NumericUpDown3.Maximum = 30
NumericUpDown3.Minimum = -30
NumericUpDown4.Value = 3 'offsety
NumericUpDown4.Maximum = 30
NumericUpDown4.Minimum = -30
NumericUpDown5.Value = 2 'slice dy
NumericUpDown5.Maximum = 30
NumericUpDown5.Minimum = 0
NumericUpDown6.Value = 8 'slicewidth
NumericUpDown6.Maximum = 30
NumericUpDown6.Minimum = 1
NumericUpDown7.Value = 5 'fuzzy
NumericUpDown7.Maximum = 9
NumericUpDown7.Minimum = 0
NumericUpDown8.Maximum = 9 'fade
NumericUpDown8.Minimum = 0
NumericUpDown8.Value = 0
End Sub
End Class