Importing jpeg cover art into itunes

Question

does anybody know how to do this with a script?
(background: all my covers are in jpeg files that were automatically downloaded by windows media player when i ripped the cd's; now I would like to select one track after the other in itunes, get the correct jpg file and then add it as cover art to the track).
finding the file is not a problem but when I set the artwork data it doesn't show the picture stored in the jpg file but sets the cover to a seemingly blank image.
is jpg not supported by itunes or what is the problem?
thanks a lot for any ideas,
Chris

Answer 1

'solution 2 is much shorter, however it does not import the picture correctly ... maybe it is really a matter of versions of applescript and/or itunes, who knows?' - no; I simply lost focus of the subject 'importing JPEG's.
Below are revisions:
AppleScript script:
set temp_File to (((path to desktop folder from user domain) as string) & "_temp.pict")
tell application "iTunes" to set tSelection to selection
if (not (tSelection is {})) then
set tFile to choose file with prompt "Select a picture:"
try
tell application "Image Events"
launch
set fRef to open (tFile)
save fRef as PICT in temp_File
close fRef
end tell
tell application "iTunes" to set data of artwork 1 of (item 1 of tSelection) to (read file temp_File from 513)
tell application "Finder" to delete file temp_File
tell application "Finder" to empty trash
end try
end if
AppleScript applet (save code as an 'Application'):
property temp_File : (((path to desktop folder from user domain) as string) & "_temp.pict")
on open dragged_Items
if (not (dragged_Items is {})) then
tell application "iTunes" to set tSelection to selection
if (not (tSelection is {})) then
try
tell application "Image Events"
launch
set fRef to open (item 1 of dragged_Items)
save fRef as PICT in temp_File
close fRef
end tell
tell application "iTunes" to set data of artwork 1 of (item 1 of tSelection) to (read file temp_File from 513)
tell application "Finder" to delete file temp_File
tell application "Finder" to empty trash
end try
end if
end if
end open
01. Select a song, in 'iTunes'.
02. In 'Finder' drag a file (of the formats listed below) onto the applet (of the above code).
As per 'Framed and Exposed: Better Image Automation Through Scripting' ... 'Image Events can open and save JPEG, JPEG2, TIFF, GIF, Photoshop, PICT, BMP, and PNG files.'
  Mac OS X (10.4.4)