Importing long list of photos

Question

Hey all..
I'm trying to figure out a way through a really tedious process.
After i shoot a wedding the bride supplies me with a list of about 150 file names for images that they want for their album. I am having to manually drag and drop each photo into a new album, or input each photo's file name manually into a smart album containing a grouping of the selected photos. This process can take over an hour of just copy and pasting filenames.
Does anyone know of any way to take a whole list of file names and drop them into aperture to create an album based on this file name list automatically?
-Ian

Answer 1

Here we go, but it's only for Aperture 2.1 or above.
1. Copy your file names into a text file, with one name per line.
2. REMOVE any file extensions - the text on each line must match the Version Name in Aperture.
3. Save the text file - as a plain text file, not RTF or anything like that.
4. Paste the following into Script Editor (save for future use if you want).
5. Hit Run and choose the text file at the prompt.
The script should make a new Album at the top level of the Library and add any Versions it can find which match the names on each line of the text file. If there are multiple Versions with the same name in your Library, only the first one will be added to the Album.
Ian
==========
set tfile to (choose file "Pick the text file")
set fref to (open for access tfile) -- now we read the file in
set tSize to (get eof tfile)
set tText to (read fref as string from 1 to tSize)
close access fref
log tText
set tList to every paragraph of tText -- turn the lines into a list
tell application "Aperture"
activate
tell library 1
set this_project to make new album with properties {name:"Results of file name list"} -- you can change this if you want the Album to have another name.
end tell
repeat with i from 1 to the count of the tList
set tName to item i of the tList
set tImgID to "not found"
try
set tImgID to (first image version whose name is tName)
end try
if tImgID is not "not found" then
try
duplicate tImgID to this_project
end try
else
log tName
end if
end repeat
end tell