Internal table size - short dump

Question

Hi all,
I am getting following error:
'Following a SELECT statement, the data read could not be placed in AN
the output area.                                                     
A conversion may have been intended that is not supported by the     
system, or the output area may be too small.'                      
Actually I am extracting data into an internal table. I have implemented my own logic to fetch data in packets. And after each packet, I am freeing the internal table using FREE command. After fetching 16 data packets, it gives me this error.
Please help me with this.
Thanks and regards,
Ridhima

Answer 1

It gives short dump in selecting data from ETXDCJ
*--  Local Data
  DATA:  t_etxdch  TYPE STANDARD TABLE OF tp_etxdch,
         t_etxdci  TYPE STANDARD TABLE OF tp_etxdci,
         t_etxdcj  TYPE STANDARD TABLE OF tp_etxdcj,
         t_docnr   TYPE STANDARD TABLE OF tp_docnr,
         wa_etxdch TYPE tp_etxdch,
         wa_etxdci TYPE tp_etxdci,
         wa_etxdcj TYPE tp_etxdcj,
         wa_docnr  TYPE tp_docnr,
         wa_data   TYPE zoxdev0388,
         l_lines   TYPE sy-tabix,
         l_line1   TYPE sy-tabix,
         l_times   TYPE sy-index,
         l_div     TYPE sy-index,
         l_cnt1    TYPE sy-tabix,
         l_cnt2    TYPE sy-tabix.
*--  Clean Up
  CLEAR: t_etxdch[],
         t_etxdci[],
         t_etxdcj[],
         t_docnr[].
*--  Get the document numbers selected in extraction
  LOOP AT c_t_data.
    CLEAR wa_docnr.
    wa_docnr = c_t_data-docnr.
    APPEND wa_docnr TO t_docnr.
  ENDLOOP.
  DATA: t_doc TYPE STANDARD TABLE OF tp_docnr,
        wa_doc TYPE tp_docnr.
  DESCRIBE TABLE t_docnr LINES l_lines.
  CHECK l_lines IS NOT INITIAL.
  WHILE l_cnt2 LE l_lines.
    l_cnt1 = l_cnt2 + 1.
    l_cnt2 = l_cnt1 + 200.
    APPEND LINES OF t_docnr FROM l_cnt1 TO l_cnt2 TO t_doc.
    SORT t_doc BY docnr.
    DELETE ADJACENT DUPLICATES FROM t_doc COMPARING docnr.
*--  Get Header data
    SELECT    docnr
              client
              currency
              gl_currency
      FROM    etxdch
      INTO    TABLE t_etxdch
      FOR     ALL ENTRIES IN t_doc
      WHERE   docnr = t_doc-docnr.
*--  Success
    IF sy-subrc IS INITIAL.
      SORT t_etxdch BY docnr.
    ENDIF.
*--  Get Item data
    SELECT    docnr
              itemnr
              quantity
              unit
              amount
              gross_amount
              freight_am
              exempt_amt
              taxpcov
              taxamov
              gl_taxpcov
              gl_taxamov
      FROM    etxdci
      INTO    TABLE t_etxdci
      FOR     ALL ENTRIES IN t_doc
      WHERE   docnr = t_doc-docnr.
*--  Success
    IF sy-subrc IS INITIAL.
      SORT t_etxdci BY docnr
                       itemnr.
    ENDIF.
*--  Get Jurisdiction data
    SELECT    docnr
              itemnr
              txjlv
              taxpct
              taxamt
              taxbas
              examt
              gl_taxpct
              gl_taxamt
              gl_taxbas
      FROM    etxdcj
      INTO    TABLE t_etxdcj
      FOR     ALL ENTRIES IN t_doc
      WHERE   docnr = t_doc-docnr.
*--  Success
    IF sy-subrc IS INITIAL.
      SORT t_etxdcj BY docnr
                       itemnr
                       txjlv.
    ENDIF.
*--  Populate the enhanced fields
    CLEAR wa_data.
    LOOP AT c_t_data INTO wa_data FROM l_cnt1 TO l_cnt2.
*--  Populate Header fields
      CLEAR wa_etxdch.
      READ TABLE t_etxdch INTO wa_etxdch WITH KEY docnr = wa_data-docnr
                                         BINARY SEARCH.
      IF sy-subrc IS INITIAL.
        wa_data-yyclient      = wa_etxdch-client.
        wa_data-yycurrency    = wa_etxdch-currency.
        wa_data-yygl_currency = wa_etxdch-gl_currency.
      ENDIF.
*--  Populate Item fields
      CLEAR wa_etxdci.
     READ TABLE t_etxdci INTO wa_etxdci WITH KEY docnr  = wa_data-docnr
                                                itemnr = wa_data-itemnr
                                        BINARY SEARCH.
      IF sy-subrc IS INITIAL.
        wa_data-yyquantity     = wa_etxdci-quantity.
        wa_data-yyunit         = wa_etxdci-unit.
        wa_data-yyamount       = wa_etxdci-amount.
        wa_data-yygross_amount = wa_etxdci-gross_amount.
        wa_data-yyfreight_am   = wa_etxdci-freight_am.
        wa_data-yyexempt_amt   = wa_etxdci-exempt_amt.
        wa_data-yytaxpcov      = wa_etxdci-taxpcov.
        wa_data-yytaxamov      = wa_etxdci-taxamov.
        wa_data-yygl_taxpcov   = wa_etxdci-gl_taxpcov.
        wa_data-yygl_taxamov   = wa_etxdci-gl_taxamov.
      ENDIF.
*--  Populate Jurisdiction fields
      CLEAR wa_etxdcj.
     READ TABLE t_etxdcj INTO wa_etxdcj WITH KEY docnr  = wa_data-docnr
                                                itemnr = wa_data-itemnr
                                                 txjlv  = wa_data-txjlv
                                        BINARY SEARCH.
      IF sy-subrc IS INITIAL.
        wa_data-yytaxpct    = wa_etxdcj-taxpct.
        wa_data-yytaxamt    = wa_etxdcj-taxamt.
        wa_data-yytaxbas    = wa_etxdcj-taxbas.
        wa_data-yyexamt     = wa_etxdcj-examt.
        wa_data-yygl_taxpct = wa_etxdcj-gl_taxpct.
        wa_data-yygl_taxamt = wa_etxdcj-gl_taxamt.
        wa_data-yygl_taxbas = wa_etxdcj-gl_taxbas.
      ENDIF.
*--  Update values in Extract structure
      MODIFY c_t_data FROM wa_data.
      CLEAR wa_data.
    ENDLOOP.
    CLEAR: t_doc[].
    FREE : t_etxdch,
    t_etxdci,
    t_etxdcj.
  ENDWHILE.