IPhoto current selected albums (Plural)

Question

In iPhoto, when you have selected photos, how do you capture which albums are selected?
(especially those children in Library)
TIA
G4 powerbook   Mac OS X (10.4.9)  

Answer 1

Geoffrey:
I hope I have understood your request. In order to find which album(s) a selected photo, or group of selected photos are found, you have to go about it a little backwards, by first sorting through all the albums in the Library, and generating a list of what is there. You then must go through each photo in the selection to see if that photo is in one of the albums, grab the album name, and move to the next album. This script will work, although it is probably slow on large collections:
set selected_Data to {} --This will hold all the data of the selected images
set album_Collection to {} --This will hold all the individual iPhoto album data
tell application "iPhoto"
set all_albums to name of albums 2 thru -2 --Excludes Library and Trash
repeat with an_album in all_albums
set end of album_Collection to {an_album as string, (id of every photo in album an_album)} --Creates a list of each album, and a list of the id of every photo in that album
end repeat
set a to selection --Whatever is selected in iPhoto
repeat with b in a
set dummy to {} --Temporary list
repeat with album_set in album_Collection
if b's id is in (item 2 of album_set) then set end of dummy to (item 1 of album_set) --Cycle through each album and see if the selected photo is in that album and if so, add that album's name to the list
end repeat
if dummy = {} then set dummy to {"Not in any album"}
set end of selected_Data to {b's name, dummy} --Builds the final list, which holds the name of each selected photo, and a list of all albums where that photo is found.
end repeat
end tell
selected_Data
In my test Library, I have 1191 photos, 37 movies, and 10 albums. I am working on an Intel Mac running 10.4.8 and got these results for 10 randomly selected photos:
{{"map", {"Last 12 Months"}}, {"DSC02923.JPG", {"Rob's Chicks"}}, {"DSC_0194.JPG", {"Last 12 Months", "Orlando"}}, {"DSC02593.JPG", {"Last 12 Months", "Orlando"}}, {"DSC02576.JPG", {"Last 12 Months", "Previous Prints", "4x6 White Borders", "Orlando"}}, {"DSC02463.JPG", {"Last 12 Months"}}, {"DSC02446.JPG", {"Last 12 Months"}}, {"DSC02421.JPG", {"Last 12 Months", "Previous Prints", "4x6 White Borders"}}, {"DSC02405.JPG", {"Last 12 Months", "Previous Prints", "4x6 White Borders", "James"}}, {"DSC02362.JPG", {"Last 12 Months", "Veterinary"}}}
It took about 9 seconds.
Good luck, hope this helps