Link invoice with Business Document

Question

Hi all,
I am looking for a way to link my invoices (from R/3 Invoice overview) with the original scanned invoice in TIFF format (business document).
I can see that this is possible using the "Attach Business Document" feature in the change invoice sreen, but I do not want to set this link up manually.
Is there anyway assign a "business document" to an invoice (or the other way around) automatically?
Thanks!

Answer 1

....you can use GOS (generic object serivces) to add attachments.
Here is a SD billing example....
Add this program to an output type in transaction NACE
*& Report  ZZCREATE_ATTACH                                             *
*& Triggered by billing output-type ZRD4                               *
*& Create a "service for object" attachement URL
report  zzcreate_attach.
tables: nast.
data: tmp_vbeln like vbrk-vbeln.
data:
*--Object_a
    p_botype like obl_s_pbor-typeid,
    p_bo_id  like obl_s_pbor-instid,
*--Object_b
    p_docty  like obl_s_pbor-typeid,
    p_msgtyp like sofm-doctp,
    p_url(300),
    p_title(30),
*--Relationship
    p_reltyp  like mdoblrel-reltype.
*-Include for BO macros -*
include : <cntn01>.
types: begin of ty_message_key,
        foltp     type so_fol_tp,
        folyr     type so_fol_yr,
        folno     type so_fol_no,
        doctp     type so_doc_tp,
        docyr     type so_doc_yr,
        docno     type so_doc_no,
        fortp     type so_for_tp,
        foryr     type so_for_yr,
        forno     type so_for_no,
       end of ty_message_key.
data : lv_message_key type ty_message_key.
data : lo_message type swc_object.
data : lt_doc_content type standard table of soli-line with header line.
data : tmp_oblguid16 type oblguid16.
*&      Form  entry
*       text
*      -->RETURN_CODE  text
*      -->US_SCREEN    text
form entry using return_code us_screen.
  perform create_url.
  return_code = 0.
endform.                    "ENTRY
*&      Form  create_url
*       text
*  -->  p1        text
*  <--  p2        text
form create_url .
  if nast-objky+10 ne space.
    nast-objky = nast-objky+16(10).
  else.
    nast-objky = nast-objky.
  endif.
  tmp_vbeln = nast-objky.
*-Load class. -*
  class cl_binary_relation definition load.
  class cl_obl_object      definition load.
*-Set default values -*
  p_botype = 'VBRK'.
  p_bo_id  = tmp_vbeln.
  p_docty  = 'MESSAGE'.
  p_msgtyp = 'URL'.
  p_title  = 'Web Hotel'.
  p_reltyp = 'URL'.
  p_url = 'www.mydoc.tiff'.                   "Here you must add your URL !!!
*-First derive the Attachment's ( MESSAGE )document type. -*
  p_docty = 'MESSAGE'.
  case p_reltyp.
*   In case of URls
    when 'URL'.
      p_msgtyp = 'URL'.
*   In case of Notes / Private Notes
    when 'NOTE' or 'PNOT'.
      p_msgtyp = 'RAW'.
    when 'ATTA'.
      p_msgtyp = 'EXT'.
*   Not implemented as yet...exit
      exit.
    when others.
*    ....exit
      exit.
  endcase.
*-Create an initial instance of BO 'MESSAGE' - to  -*
*-call the instance-independent method 'Create'.   -*
  swc_create_object lo_message 'MESSAGE' lv_message_key.
*-Define container to pass the parameter values -*
*-to the method call in next step.              -*
  swc_container lt_message_container.
*-Populate container with parameters for method-*
  swc_set_element lt_message_container 'DOCUMENTTITLE' p_title.
  swc_set_element lt_message_container 'DOCUMENTLANGU' 'E'.
  swc_set_element lt_message_container 'NO_DIALOG'     'X'.
  swc_set_element lt_message_container 'DOCUMENTNAME' p_docty.
  swc_set_element lt_message_container 'DOCUMENTTYPE'   p_msgtyp.
*-'DocumentContent' is a multi-line element ( itab ). -*
*-In case of URLs..it should be concatenated          -*
*-with &KEY& in the begining.                         -*
  case p_msgtyp.
    when 'URL'.
      concatenate '&KEY&' p_url into lt_doc_content.
      append lt_doc_content.
*-In case of Notes or Private Notes, get the data -*
*-from files on appl server or from wherever ?    -*
*-(remember background).                          -*
    when 'RAW'.
      lt_doc_content = 'Hi How r u?' .
      append lt_doc_content.
*-In case of File attachments upload file -*
    when 'EXT'.
  endcase.
  swc_set_element lt_message_container 'DocumentContent' lt_doc_content.
  swc_call_method lo_message 'CREATE' lt_message_container.
*-Refresh to get the reference of        -*
*-create 'MESSAGE' object for attachment -*
  swc_refresh_object lo_message.
*-Get Key of new object -*
  swc_get_object_key lo_message lv_message_key.
*-Now we have attachment as a business object instance.      -*
*-We can now attach it to our main business object instance. -*
*-Create main BO object_a -*
  data: lo_is_object_a type sibflporb.
  lo_is_object_a-instid = p_bo_id.
  lo_is_object_a-typeid = p_botype.
  lo_is_object_a-catid  = 'BO'.
*-Create attachment BO object_b -*
  data: lo_is_object_b type sibflporb.
  lo_is_object_b-instid = lv_message_key.
  lo_is_object_b-typeid = p_docty.
  lo_is_object_b-catid  = 'BO'.
*-TRY -*
  call method cl_binary_relation=>create_link
    exporting
      is_object_a            = lo_is_object_a
*    IP_LOGSYS_A            =
      is_object_b            = lo_is_object_b
*    IP_LOGSYS_B            =
      ip_reltype             = p_reltyp
*    IP_PROPNAM             =
*    I_PROPERTY             =
     importing
       ep_link_id             = tmp_oblguid16
*    EO_PROPERTY            =
endform.                    " create_url