Lists, groups and selected item

Question

I'm trying to learn how to work with lists and I'm just not getting it. I've been working on this for days now to no avail.
My first problem is eachItem is returning only last entry of groupsList instead of the selected specifiedGroup. Then what I would like to do which I'm not too keen on either is, take that selection and match it to one of the choice groups which would contain files or something that the user has preselected previously. Thanks so much! I'm learning a lot of Applescript lately but these lists get the best of me still as I don't fully understand how they work yet. Hoping this will clear my head on things.
property groupsList : {"List1", "List2", "List3", "List4", "List5"}
property specifiedGroup : {}
property choiceOne : {}
property choiceTwo : {}
property choiceThree : {}
property choiceFour : {}
property choiceFive : {}
choose from list groupsList
copy result to specifiedGroup
log specifiedGroup
set results to (every item of groupsList)
repeat with eachItem in results
          if eachItem = specifiedGroup then
                    exit repeat
          end if
end repeat
log eachItem

Answer 1

AppleScript doesn't support variable variables, so you can't refer to variable names like that (at least not in regular AppleScript).  Using a record isn't that much better, because you can't use variables to refer to property keys, either. There are a couple of cheats that use run script, but usually those are more of a pain that they are worth.
One way that is similar to what you are thinking about would be to create a list of lists, then use your choice to index into that list, for example:
property groupsList : {"List1", "List2", "List3", "List4", "List5"}
property choiceOne : {"choiceOne", "this is list 1"}
property choiceTwo : {"choiceTwo", "this is list 2"}
property choiceThree : {"choiceThree", "this is list 3"}
property choiceFour : {"choiceFour", "this is list 4"}
property choiceFive : {"choiceFive", "this is list 5"}
set listOfLists to {choiceOne, choiceTwo, choiceThree, choiceFour, choiceFive}
set theChoice to (choose from list groupsList) as text
if theChoice is "false" then error number -128 -- cancel
set specifiedGroup to missing value
repeat with i from 1 to (count groupsList)
  if item i of groupsList = theChoice then
    set specifiedGroup to item i of listOfLists
    exit repeat
  end if
end repeat
log specifiedGroup