Mail Applescript?

Question

Is there an AppleScript or other way to designate certain emails as spam?
I don't want them deleted I just want them to be added to a Rule so they'll automatically get put in a certain folder.
Thanks for your help.

Answer 1

dnucks wrote:
Is there an AppleScript or other way to designate certain emails as spam?
If it's just a specific email, then just create a Rule: Mail->Preferences->Rules->Add Rule
Also, turn on Apple Mail's built-in spam filter: Mail->Preferences->Junk Mail->Enable junk mail
For a more complex Blacklist/Whitelist filter to catch those sneaky spam emails, here's what I use:
First turn on Apple Mail's built-in spam filter: Mail->Preferences->Junk Mail->Enable junk mail filtering
Then set a Mail Rule as:
If any [ Message type ] is [ Mail ]
Perform the following actions:
[ Move message ] to mailbox [ inbox ]
[ Run Applescript ] ~/Documents/Scripts/Junkfilter.scpt
Then create Junkfilter.scpt:
<pre style="
font-family: Monaco, 'Courier New', Courier, monospace;
font-size: 10px;
font-weight: normal;
margin: 0px;
padding: 5px;
border: 1px solid #000000;
width: 720px; height: 340px;
color: #000000;
background-color: #E6E6EE;
overflow: auto;">
using terms from application "Mail"
on perform mail action with messages theMessages
tell application "Mail"
repeat with theMessage in theMessages
set theSender to (sender of theMessage)
set theReplyto to (reply to of theMessage)
set theSubject to (subject of theMessage)
set theHeader to (all headers of theMessage)
set theContent to (source of theMessage as string)
if my blacklist(theSender, theReplyto, theSubject, theHeader, theContent) ¬
and not my whitelist(theSender) then
my moveToJunkFolder(theMessage)
end if
end repeat
end tell
end perform mail action with messages
end using terms from
on blacklist(f, r, s, h, c)
if f contains "registrationchecks.com" or ¬
f contains "busenetwork.net" or ¬
r contains "1105service.com" or ¬
s contains "Codeine" or ¬
h contains "X-YahooFilteredBulk" or ¬
h contains "Received-SPF: fail" or ¬
h contains "Received-SPF: softfail" or ¬
h contains "Received-SPF: error" or ¬
h contains "Received-SPF: permerror" or ¬
h contains "Received-SPF: temperror" then
return true
else
try -- Check Content of Message:
do shell script "echo " & quoted form of c & " | egrep -qs 'http://.*\.ru|http://.*\.ly|http://.*\.in|http://trk.cp.*\.com|<div id="hidden">|http://a\.nf/'  "
on error -- non-zero exit status: grep retuns 1 if not found or 2 if error
return false
end try
return true -- zero exit status: grep retuns 0 if selected lines are found 
end if
end blacklist
on whitelist(f)
if f contains "aicpa" or ¬
f contains "iLounge.com" or ¬
f contains "wikimedia.org" then
return true
else
return false
end if
end whitelist
on moveToJunkFolder(m)
tell application "Mail"
try
-- set the junk mail status of m to true -- DO NOT USE!! Causes "*** Assertion failure"
set read status of m to true
set the background color of m to orange
end try
try
set theAccount to (account of mailbox of m)
set mailbox of m to (mailbox "Junk" of theAccount) --  Move to "Junk"
end try
end tell
end moveToJunkFolder
</pre>