Mass-change address format in address book

Question

Hi Guys,
I've recently changed from pc to mac (yay) and have imported all my contacts into address book.
I have several hundred contacts that have mailing address in the US, and several hundred that have mailing addresses in the Netherlands and some in other parts of the world.
I'd like to change the address formats to the appropriate ones, but so far have only been figure out how to do that one at a time, or all together.
I can use smart groups to group the addresses I want to change together, but after that I'm stuck.
Is there a way to change the address format from selected cards? or will I have to do this one at a time?
Thanks for your help.
mac mini Mac OS X (10.4.8)
mac mini Mac OS X (10.4.8)

Answer 1

Here is an Applescript you can run that will do what you want:
property CountryCode : {missing value:"us", USA:"us", Netherlands:"nl", UK:"uk"}
tell application "Address Book"
repeat with aPerson in people
set theAddresses to addresses of aPerson
if theAddresses is not {} then
repeat with anAddress in theAddresses
set theCountry to country of anAddress
set the country code of anAddress to my getCC(theCountry)
end repeat
end if
end repeat
end tell
on getCC(aCountry)
set s to "on run {CountryCode}" & return
set s to s & "get " & aCountry & " of CountryCode" & return
set s to s & "end"
try
run script s with parameters {CountryCode}
on error
return text returned of (display dialog aCountry & " not found. Enter a country code:" default answer "us" buttons {"Ok"})
end try
end getCC
In the property statement, change the "us" for missing value to your default country code. Add any other countries you have to the CountryCode list. The first part, before the colon, is the Name of the country as found in your address book. The second part is the ISO country code (two characters). I found a list of ISO country codes here. That list was upper case, but the address book uses lower. If you have variants of the same country name, you can just add them all to the list.
Note: the name of the country cannot be more than one word--I didn't want to work out another way of getting codes. However, if the script runs across a country name that is not in the list, it will ask you to enter the correct value. You can change the "us" in the getCC handler to the country code of multi-name countries in your address book to make it the default answer.
Need help with Applescript? Just copy the code into a new Script Editor document and hit the Run (green right arrow) button. It will open the Address Book and start looking through your contacts, finding ones with addresses, and setting the country code to what you say it should be in the property CountryCode list.
If it fails with any other errors, check the Event Log History window which may give you a clue as to what was wrong with the address it failed on. You may be able to fix the address so it continues. Otherwise, post back with the error and I may be able to figure it out.