Move mail attachment to specified folder - problem

Question

Hi,
I am busy making a script that downloads the mail attachments to a specified folder so that Hazel can work further on the files.
Here is what i am trying to achive:
Only Jpg, Tiff, Doc, Docx, mp3's and PDF's are moved to a folder called: Mail Attachments in the downloads folder and renamed with a prefix to the the date email was send. For Hazel to work correctly i also want to add the senders headers to the spotlight comment.
So far all went well and i got a script working that does all these things.
Only problem that is occuring now that images are duplicate twice in the folder:
first file as i want: i.e. 20130711_RTP_1846.jpg and the second file is only named 2013 with no extension aswell.
This happens only with the images, not with for example an PDF.
Here is my script, by the way this is my first script and i copied, paste things i found online tweaking it to my wishes.
using terms from application "Mail"
          on perform mail action with messages theMessages for rule theRule
  -- set up the attachment folder path
                    tell application "Finder"
                              set folderName to "Downloads:Mail Attachments"
                              set homePath to (path to home folder as text) as text
                              set attachmentsFolder to (homePath & folderName) as text
                    end tell
                    tell application "Mail"
                              repeat with eachMessage in theMessages
  -- set up the folder name for this mail message's attachments. We use the time stamp of the date received time stamp
                                        set {year:y, month:m, day:d, hours:h, minutes:min} to eachMessage's date received
                                        set timeStamp to (y & my pad(m as integer) & my pad(d)) as string
  -- get all headers from email and store in _Comment
                                        set _sel to get selection
                                        set _links to {}
                                        repeat with _msg in _sel
                                                  set _messageURL to _msg's all headers
                                                  set end of _links to _messageURL
                                        end repeat
                                        set AppleScript's text item delimiters to return
                                        set _Comment to (_links as rich text)
                                        try
  -- Save the attachment
                                                  repeat with theAttachment in eachMessage's mail attachments
                                                            set originalName to timeStamp & "_" & name of theAttachment
  --set originalName to name of theAttachment
                                                            set savePath to attachmentsFolder & ":" & originalName
                                                            try
  --save theAttachment in file (savePath) for only these files all other are excluded
                                                                      if originalName contains "jpg" then save theAttachment in file (savePath)
                                                                      if originalName contains "jpeg" then save theAttachment in file (savePath)
                                                                      if originalName contains "tif" then save theAttachment in file (savePath)
                                                                      if originalName contains "tiff" then save theAttachment in file (savePath)
                                                                      if originalName contains "pdf" then save theAttachment in file (savePath)
                                                                      if originalName contains "doc" then save theAttachment in file (savePath)
                                                                      if originalName contains "docx" then save theAttachment in file (savePath)
                                                                      if originalName contains "mp3" then save theAttachment in file (savePath)
  -- insert _Comment in spotlight search
                                                                      tell application "Finder"
                                                                                set theFile to savePath
                                                                                set the comment of file theFile to _Comment
                                                                      end tell
                                                            end try
                                                  end repeat
                                        on error msg
  display dialog msg
                                        end try
                              end repeat
                    end tell
          end perform mail action with messages
end using terms from
on pad(n)
          return text -2 thru -1 of ("0" & n)
end pad
What strange is, that if i take out the part where the comment is filled with the header info, the script works fine producing only 1 file, but when i added this part of the script, i have the two files!
Script is activated by a mail rule when mail has an attachment.
Here a screenshot with the two images:
Hope someone can help me, to tell me what i did wrong.
Grt,
Rob

Answer 1

The problem is subtle, but noticable in your screenshot (that was a stroke of genius).
Look closely at your screenshot. Note the file details below the image and you'll see the Name label:
"2013
07
11_130711RTP_1846.jpg"
Do you see the issue? It's not that the file is called '2013', it's called the entire expected file name, but with returns between the date elements. The problem is that return characters don't show in list view.
So why are the returns there?
That's because in the section of code where you build the comments you include the line:
                                        set AppleScript's text item delimiters to return
Then you build the file name:
                                                            set originalName to timeStamp & "_" & name oftheAttachment
Now the file name is technically a list of components (think of it as {originalName, timeStamp, "_", 130711RTP_1846.jpg} )
When this list is coerced back to a text object, AppleScript inserts the current text item delimiters between each element, which results in your multi-line filename.
The solution is actually a best practice when dealing with text item delimiters - always, always, always reset them when you're done.
In this case you only want to have returns in the comment, so you should restore the TIDs after you've built the comment:
set tid to AppleScript's text item delimiters
set AppleScript's text item delimiters to return
set _Comment to (_links as rich text)
set AppleScript's text item delimiters to tid
Now the TIDs will be set back to the default and you won't have the extraneous returns in the file name.