Need to apply dragging event on Columns and Rows on TableLayoutPanel during runtime in user defined IDE

Question

Environment: -
OS: - Windows 7 32 bit
IDE: - Visual Studio IDE 2008
Language: - VB .Net
Application Type: - Exe Application
Application Name: - Designer.exe
Requirement Type: -
Critical
Product Description: - We have exe project, which creates
Designer.exe.  Designer.exe is an IDE for designing form on run time. We received a requirement from client to add another component on Panel. In Panel we have already added following components like (Text
Box, Label, Combo Box, List, Grid etc)
Now we had to add another component “TableLayoutPanel”, and we have added it properly in it, and tried to provide required properties of TableLayoutPanel
in Designer.exe.
Requirement Description: -
We have stuck at a point, where we need inputs for further development. We are not able to drag rows and columns for adjusting Table layout on run time.
We need to know, what kind of event, we will have to write, so that we can hold particular row or column and drag it to the required position in Table Layout Panel.
E.g.

Answer 1

Here is the example of how you can do this.  Try it in a new Form project first by following these steps.
 First create your Form project and on the VB menu click (Project) and select (Add Class).  Name the class (TableLayoutPanelEx.vb). Now copy the class code below and paste it into the new class you just added.
Public Class TableLayoutPanelEx
Inherits TableLayoutPanel
Private Const WM_NCHITTEST As Integer = &H84
Private Const WM_MOUSEMOVE As Integer = &H200
Private Const WM_LBUTTONDOWN As Integer = &H201
Private Const WM_LBUTTONUP As Integer = &H202
Private Const MK_LBUTTON As Integer = &H1
Private VBorders As New List(Of Integer)
Private HBorders As New List(Of Integer)
Private selColumn As Integer = -1
Private selRow As Integer = -1
Public Sub New()
Me.DoubleBuffered = True
Me.CellBorderStyle = TableLayoutPanelCellBorderStyle.Single
End Sub
Protected Overrides Sub OnHandleCreated(ByVal e As System.EventArgs)
MyBase.OnHandleCreated(e)
If Not Me.DesignMode Then ResetSizeAndSizeTypes()
End Sub
Public Shadows Property ColumnCount() As Integer
Get
Return MyBase.ColumnCount
End Get
Set(ByVal value As Integer)
MyBase.ColumnCount = value
If Me.Created And Not Me.DesignMode Then ResetSizeAndSizeTypes()
End Set
End Property
Public Shadows Property RowCount() As Integer
Get
Return MyBase.RowCount
End Get
Set(ByVal value As Integer)
MyBase.RowCount = value
If Me.Created And Not Me.DesignMode Then ResetSizeAndSizeTypes()
End Set
End Property
Public Sub ResetSizeAndSizeTypes()
Dim cW As Single = CSng((Me.ClientSize.Width \ Me.GetColumnWidths.Length) - 1)
For c As Integer = 0 To Me.GetColumnWidths.Length - 1
Me.ColumnStyles(c).SizeType = SizeType.Absolute
Me.ColumnStyles(c).Width = cW
Next
Dim cH As Single = CSng((Me.ClientSize.Height \ Me.GetRowHeights.Length) - 1)
For r As Integer = 0 To Me.GetRowHeights.Length - 1
Me.RowStyles(r).SizeType = SizeType.Absolute
Me.RowStyles(r).Height = cH
Next
End Sub
Protected Overrides Sub WndProc(ByRef m As System.Windows.Forms.Message)
MyBase.WndProc(m)
If Me.Created And Not Me.Disposing Then
If m.Msg = WM_NCHITTEST Then
Dim loc As Point = Me.PointToClient(MousePosition)
VBorders.Clear()
HBorders.Clear()
If Me.ColumnCount > 1 Then
For w As Integer = 0 To Me.GetColumnWidths.Length - 2
If w = 0 Then
VBorders.Add(Me.GetColumnWidths(w))
Else
VBorders.Add(VBorders(VBorders.Count - 1) + Me.GetColumnWidths(w))
End If
Next
End If
If Me.RowCount > 1 Then
For h As Integer = 0 To Me.GetRowHeights.Length - 2
If h = 0 Then
HBorders.Add(Me.GetRowHeights(h))
Else
HBorders.Add(HBorders(HBorders.Count - 1) + Me.GetRowHeights(h))
End If
Next
End If
Dim onV As Boolean = (VBorders.Contains(loc.X) Or VBorders.Contains(loc.X - 1) Or VBorders.Contains(loc.X + 1))
Dim onH As Boolean = (HBorders.Contains(loc.Y) Or HBorders.Contains(loc.Y - 1) Or HBorders.Contains(loc.Y + 1))
If onV And onH Then
Me.Cursor = Cursors.SizeAll
ElseIf onV Then
Me.Cursor = Cursors.VSplit
ElseIf onH Then
Me.Cursor = Cursors.HSplit
Else
Me.Cursor = Cursors.Default
End If
ElseIf m.Msg = WM_LBUTTONDOWN And Me.Cursor <> Cursors.Default Then
Dim loc As Point = Me.PointToClient(MousePosition)
selColumn = -1
selRow = -1
For c As Integer = 0 To VBorders.Count - 1
If VBorders(c) >= loc.X - 1 And VBorders(c) <= loc.X + 1 Then
selColumn = c
Exit For
End If
Next
For r As Integer = 0 To HBorders.Count - 1
If HBorders(r) >= loc.Y - 1 And HBorders(r) <= loc.Y + 1 Then
selRow = r
Exit For
End If
Next
ElseIf m.Msg = WM_MOUSEMOVE And m.WParam.ToInt32 = MK_LBUTTON Then
Dim loc As Point = Me.PointToClient(MousePosition)
If Me.Cursor <> Cursors.Default Then
If selRow > -1 And loc.Y >= 1 And loc.Y <= Me.ClientSize.Height - 2 Then
Me.RowStyles(selRow).SizeType = SizeType.Absolute
Dim ref As Single = loc.Y - Me.RowStyles(selRow).Height
If selRow > 0 Then ref -= HBorders(selRow - 1)
If Me.RowStyles(selRow).Height + ref > 0 Then
If Me.RowCount > selRow + 1 Then
If Me.RowStyles(selRow + 1).Height - ref < 1 Then Exit Sub
Me.RowStyles(selRow + 1).Height -= ref
End If
Me.RowStyles(selRow).Height += ref
End If
End If
If selColumn > -1 And loc.X >= 1 And loc.X <= Me.ClientSize.Width - 2 Then
Me.ColumnStyles(selColumn).SizeType = SizeType.Absolute
Dim ref As Single = loc.X - Me.ColumnStyles(selColumn).Width
If selColumn > 0 Then ref -= VBorders(selColumn - 1)
If Me.ColumnStyles(selColumn).Width + ref > 0 Then
If Me.ColumnCount > selColumn + 1 Then
If Me.ColumnStyles(selColumn + 1).Width - ref < 1 Then Exit Sub
Me.ColumnStyles(selColumn + 1).Width -= ref
End If
Me.ColumnStyles(selColumn).Width += ref
End If
End If
End If
ElseIf m.Msg = WM_LBUTTONUP Then
selColumn = -1
selRow = -1
End If
End If
End Sub
End Class
 Now you need to build the project.  Go to the VB menu and click (Build) and then select (Build
NameOfYourProject).   After it builds you can go to the Form`s [Design] tab and drag one from the top of the Toolbox onto your Form. 
IMPORTANT - Then set the RowCount and
ColumnCount to the maximum number of rows and columns you want to let the user add. 
That has to be done at design time.
 Next you need to add 2 NumericUpDown controls to the Form and name them (NUD_Rows) and (NUD_Columns).  Then you can add the code below to the Form`s code.
Public Class Form1
Public Sub New()
InitializeComponent()
'Set the minimum of the 2 NumericUpDown controls for the rows and columns to 1
'Set the maximum of the 2 NumericUpDown controls to the number of rows and columns you have set in the [Design] tab properties
NUD_Rows.Minimum = 1
NUD_Rows.Maximum = TableLayoutPanelEx1.RowCount
NUD_Columns.Minimum = 1
NUD_Columns.Maximum = TableLayoutPanelEx1.ColumnCount
'Set to the rows and columns counts back to what you want for the default
TableLayoutPanelEx1.ColumnCount = 4
TableLayoutPanelEx1.RowCount = 4
'Set the 2 NumericUpDown control values to the current count of rows and columns
NUD_Rows.Value = TableLayoutPanelEx1.RowCount
NUD_Columns.Value = TableLayoutPanelEx1.ColumnCount
End Sub
Private Sub NUD_Rows_ValueChanged(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles NUD_Rows.ValueChanged
If Me.Created Then TableLayoutPanelEx1.RowCount = CInt(NUD_Rows.Value)
End Sub
Private Sub NUD_Columns_ValueChanged(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles NUD_Columns.ValueChanged
If Me.Created Then TableLayoutPanelEx1.ColumnCount = CInt(NUD_Columns.Value)
End Sub
End Class
 You can now run the app and test it out.  You should be able to set the number of rows and columns with the 2 NumericUpDown controls and adjust the widths and heights of them with the mouse just like i did in the animated gif image i posted in
my first post.
If you say it can`t be done then i`ll try it