Need to send my spool in HTML format as Email attachment

Question

Hi All,
    Can anyone let me know how to send a HTML attachment in a mail.
I have a ALV Report, when i execute, my report should pick the ALV Report output from spool, and should send a mail with spool output as HTML attachment.
Please explain me how i need to do the above.
Regards
Nanda

Answer 1

Hi Nanda,
You can use 2 reports for this.
In one report just display the ALV..
and in the second report submit this first report  to memory and get it html format and then send it as an email.
Just check this code (instead of alv...this is a normal report that is sent as HTML attachment)
*--Tables
TABLES: VBRK.
                 TYPES DECLARATION                                   *
TYPES: BEGIN OF TY_VBRK,
        KUNAG TYPE KUNAG," Payer Id
       END OF TY_VBRK,
*-- customer details
       BEGIN OF TY_KNA1,
        KUNNR TYPE KUNNR," Customer Id
        NAME1 TYPE NAME1," Customer Name
        ADRNR TYPE ADRNR," Address No
       END OF TY_KNA1,
*-- Mailing details
       BEGIN OF TY_ADDR,
        ADDRNUMBER TYPE AD_ADDRNUM, " Address No
        MAIL_ID TYPE AD_SMTPADR,    " Email Address
       END OF TY_ADDR,
*-- Log details
       BEGIN OF TY_MSG,
        STR1 TYPE AD_SMTPADR, " Email Address
        STR2 TYPE KUNNR,      " Payer Id
        STR3 TYPE NAME1,      " Payer Name
        STR4 TYPE D,          " Date
        STR5 TYPE T,          " Time
       END OF TY_MSG.
             I N T E R N A L  T A B L E S                            *
DATA: RECEPIENTS TYPE TABLE OF AD_SMTPADR, "table for email id's
      LISTOBJECT TYPE TABLE OF ABAPLIST,   "table with displayed list
      HTML TYPE TABLE OF W3HTML,           "html container
      RETURN TYPE TABLE_OF_STRINGS,        "message table
      IT_VBRK TYPE TABLE OF TY_VBRK,       "Billing Details
      IT_KNA1 TYPE TABLE OF TY_KNA1,       "Customer Details
      IT_ADDR TYPE TABLE OF TY_ADDR,       "Mail id
      IT_MSG TYPE TABLE OF TY_MSG.         "Log Details
*-- Structure Declarations
DATA: WA_REC TYPE AD_SMTPADR,
      WA_KNA1 TYPE TY_KNA1,
      WA_ADDR TYPE TY_ADDR,
      WA_MSG TYPE TY_MSG.
      Declarations for Sending mail                                  *
*-- To Create link and add recepients address
DATA: SEND_REQUEST TYPE REF TO CL_BCS.
*-- To Create HTML document
DATA: DOCUMENT TYPE REF TO CL_DOCUMENT_BCS.
*-- To Create Sender Id
DATA: SENDER_ID TYPE REF TO IF_SENDER_BCS.
*-- To Create recepient address
DATA: RECIPIENT TYPE REF TO IF_RECIPIENT_BCS.
*-- To Handle Exceptions
DATA: BCS_EXCEPTION TYPE REF TO CX_BCS.
*-- To check if the mail is sent to all recepients
DATA: SENT_TO_ALL TYPE OS_BOOLEAN.
DATA: CONLENGTHS TYPE SO_OBJ_LEN . "To calculate length of the HTML file
              V A R I A B L E S                                      *
DATA: REPORT TYPE PROGRAMM,    "Report name
      SENDER TYPE AD_SMTPADR,  "Sender Address
      SUBJECT TYPE SO_OBJ_DES. "Subject
DATA: BCS_MESSAGE TYPE STRING ."String to store exceptions
DATA: V_KUNAG TYPE KUNAG.      "Payer Id
DATA: V_MAIL TYPE AD_SMTPADR,  "Mail Address
      V_DATE TYPE ZZBCDATE.    "To Validate Entered Date
             S E L C T I O N - S C R E E N                           *
SELECTION-SCREEN BEGIN OF BLOCK B1 WITH FRAME TITLE TEXT-001.
SELECT-OPTIONS: S_ZZBCDA FOR VBRK-ZZBCDAT. "Billing Complete Date
PARAMETERS:     P_MAILFT TYPE AD_SMTPADR,  "Mail id
                P_MAILSC TYPE AD_SMTPADR.  "Mail id
SELECTION-SCREEN END OF BLOCK B1.
                  At Selection Screen                                *
AT SELECTION-SCREEN.
*-- Validate the dates entered
  SELECT ZZBCDAT UP TO 1 ROWS
          FROM VBRK
          INTO V_DATE
          WHERE ZZBCDAT IN S_ZZBCDA.
  ENDSELECT.
  IF SY-SUBRC <> 0.
    MESSAGE E002 WITH 'Dates Not Found In The Given Range'(002).
  ENDIF.
             S T A R T - O F - S E L E C T I O N                     *
  CONCATENATE SY-UNAME '@YAHOO.COM'(003) INTO SENDER.
*-- Populating the Subject Line
  MOVE 'Invoice Due Date Details'(004) TO SUBJECT.
*-- Selecting the Payer Details Based on Input Dates
  SELECT KUNAG
          FROM VBRK
          INTO TABLE IT_VBRK
               WHERE ZZBCDAT IN S_ZZBCDA.
*-- Selecting the Address Number from Customer Master
  SELECT KUNNR
         NAME1
         ADRNR
          FROM KNA1
          INTO TABLE IT_KNA1
               FOR ALL ENTRIES IN IT_VBRK
               WHERE KUNNR = IT_VBRK-KUNAG.
*-- Selecting the Mail Id's
  SELECT ADDRNUMBER
         SMTP_ADDR
          FROM ADR6
          INTO TABLE IT_ADDR
               FOR ALL ENTRIES IN IT_KNA1
               WHERE ADDRNUMBER = IT_KNA1-ADRNR.
*-- Getting all the selected mail Id's
  RECEPIENTS = IT_ADDR[].
  MOVE (your first report name) TO REPORT.
  IF NOT RECEPIENTS[] IS INITIAL .
    LOOP AT IT_KNA1 INTO WA_KNA1.
      AT NEW KUNNR.
        READ TABLE IT_KNA1 INTO WA_KNA1 WITH KEY KUNNR = WA_KNA1-KUNNR
                                                          BINARY SEARCH.
        REFRESH RECEPIENTS.
*-- Populating the Recepients Mail Id's for the Particular Kunnr
        LOOP AT IT_ADDR INTO WA_ADDR WHERE ADDRNUMBER = WA_KNA1-ADRNR.
          IF NOT WA_ADDR IS INITIAL.
            TRANSLATE WA_ADDR-MAIL_ID TO UPPER CASE.
            APPEND WA_ADDR-MAIL_ID TO RECEPIENTS.
          ENDIF.
        ENDLOOP.
*-- Appending the mail id's from the input fields when not initial
        IF NOT P_MAILFT IS INITIAL.
          TRANSLATE P_MAILFT TO UPPER CASE.
          APPEND P_MAILFT TO RECEPIENTS.
        ENDIF.
        IF NOT P_MAILSC IS INITIAL.
          TRANSLATE P_MAILSC TO UPPER CASE.
          APPEND P_MAILSC TO RECEPIENTS.
        ENDIF.
*-- Sending the Kunnr while Submitting the Report
        V_KUNAG = WA_KNA1-KUNNR.
        TRANSLATE REPORT TO UPPER CASE .
*--Submitting the Report Exporting the List to Memory
        SUBMIT (REPORT) WITH S_ZZBCDA IN S_ZZBCDA
                        WITH P_KUNAG = V_KUNAG
                         EXPORTING LIST TO MEMORY AND RETURN.
        CLEAR: LISTOBJECT , HTML .
        REFRESH : LISTOBJECT, HTML .
*-- Calling the Fn Module to get the list from the Memory
        CALL FUNCTION 'LIST_FROM_MEMORY'
          TABLES
            LISTOBJECT = LISTOBJECT.
*-- Calling Fn Module to get the List in HTML Format
        CALL FUNCTION 'WWW_HTML_FROM_LISTOBJECT'
          EXPORTING
            REPORT_NAME = REPORT
          TABLES
            HTML        = HTML
            LISTOBJECT  = LISTOBJECT.
*-- Getting the Size of the Html Document
        DATA: V_LINES TYPE I.
        DESCRIBE TABLE HTML LINES V_LINES.
        CLEAR CONLENGTHS .
        CONLENGTHS = V_LINES * 255.
        TRY.
            CLEAR SEND_REQUEST .
            SEND_REQUEST = CL_BCS=>CREATE_PERSISTENT( ).
            CLEAR DOCUMENT .
*-- Creating the Document
            DOCUMENT = CL_DOCUMENT_BCS=>CREATE_DOCUMENT(
            I_TYPE = 'HTM'
            I_TEXT = HTML
            I_LENGTH = CONLENGTHS
            I_SUBJECT = SUBJECT ).
*-- add document to send request
            CALL METHOD SEND_REQUEST->SET_DOCUMENT( DOCUMENT ).
            CLEAR SENDER_ID .
*-- Creating the internet address for the sender id.
      SENDER_ID = CL_CAM_ADDRESS_BCS=>CREATE_INTERNET_ADDRESS( SENDER ).
            CALL METHOD SEND_REQUEST->SET_SENDER
              EXPORTING
                I_SENDER = SENDER_ID.
            CLEAR WA_REC .
*-- Creating the Recepients address
            LOOP AT RECEPIENTS INTO WA_REC .
              CLEAR RECIPIENT .
              RECIPIENT = CL_CAM_ADDRESS_BCS=>CREATE_INTERNET_ADDRESS(
              WA_REC ).
add recipient with its respective attributes to send request
              CALL METHOD SEND_REQUEST->ADD_RECIPIENT
                EXPORTING
                  I_RECIPIENT = RECIPIENT
                  I_EXPRESS   = 'X'.
            ENDLOOP .
            CALL METHOD SEND_REQUEST->SET_STATUS_ATTRIBUTES
              EXPORTING
                I_REQUESTED_STATUS = 'E'
                I_STATUS_MAIL      = 'E'.
            CALL METHOD SEND_REQUEST->SET_SEND_IMMEDIATELY( 'X' ).
*-- Sending the Document
            CALL METHOD SEND_REQUEST->SEND(
            EXPORTING
            I_WITH_ERROR_SCREEN = 'X'
            RECEIVING
            RESULT = SENT_TO_ALL ).
            IF SENT_TO_ALL = 'X'.
*-- Getting the details to display the Job Log
              LOOP AT RECEPIENTS INTO V_MAIL.
                WA_MSG-STR1 = V_MAIL.
                WA_MSG-STR2 = WA_KNA1-KUNNR.
                WA_MSG-STR3 = WA_KNA1-NAME1.
                WA_MSG-STR4 = SY-DATUM.
                WA_MSG-STR5 = SY-UZEIT.
                APPEND WA_MSG TO IT_MSG.
              ENDLOOP.
            ELSE.
              APPEND 'Mail not sent'(005)  TO RETURN.
            ENDIF.
            COMMIT WORK.
          CATCH CX_BCS INTO BCS_EXCEPTION.
            BCS_MESSAGE = BCS_EXCEPTION->GET_TEXT( ).
            APPEND BCS_MESSAGE TO RETURN .
            EXIT.
        ENDTRY.
      ENDAT.
    ENDLOOP.
  ELSE .
    APPEND 'Specify email address for sending'(006) TO RETURN .
  ENDIF .
                 E N D - O F - S E L E C T I O N                     *
END-OF-SELECTION.
*-- Displaying the Job Log
  FORMAT COLOR 1 INTENSIFIED ON.
  WRITE:/        SY-ULINE(121),
            (40) 'Mail Sent to'(007),
                 SY-VLINE,
            (12) 'Payer Id'(008),
                 SY-VLINE,
            (35) 'Payer Name'(009),
                 SY-VLINE,
            (10) 'Sent Date'(010),
                 SY-VLINE,
            (10) 'Sent Time'(011),
                 SY-VLINE,
                 SY-ULINE(121).
  LOOP AT IT_MSG INTO WA_MSG.
    FORMAT COLOR 2 INTENSIFIED ON.
    WRITE:/         SY-ULINE(121),
               (40) WA_MSG-STR1,
                    SY-VLINE,
               (12) WA_MSG-STR2,
                    SY-VLINE,
               (35) WA_MSG-STR3,
                    SY-VLINE,
               (10) WA_MSG-STR4  DD/MM/YYYY,
                    SY-VLINE,
               (10) WA_MSG-STR5  USING EDIT MASK '__:__:__',
                    SY-VLINE,
                    SY-ULINE(121).
  ENDLOOP.