ORA-22160: element at index name does not exist

Question

hi
i have a procedure which insert values from a VARRAY type in a table. My question is how can i verify the existence of nth element before inserting to avoid ORA-22160: element at index name does not exist
Here is my code:
CREATE OR REPLACE PACKAGE BODY CANDIDE.PE_CL IS
PROCEDURE p_proc(Id_clt IN P_CLIENT.id_client%TYPE,
nameClt IN P_CLIENT.nameclient%TYPE,
--VARRAY type
priceItem IN price_array,
--VARRAY type
nameItem IN item_array) IS
BEGIN
INSERT INTO P_CLIENT VALUES (Id_clt, nameClt);
FORALL i IN nameItem.FIRST .. nameItem.LAST
INSERT INTO P_ITEMS VALUES (Id_clt, nameItem(i), priceItem(i));
END;
end PE_CL;
Product version: Oracle9i Enterprise Edition Release 9.2.0.1.0
Peter

Answer 1

I see the problem now. If there are more values in one varray or the other, how do you want to handle it? Below I have demonstrated, first the solution that I previous offered, that would only insert the rows where there are values from both varrays. In the second example below, I have inserted a null value in place of the missing value from the varray that has fewer values.
scott@ORA92> CREATE TABLE p_client
  2    (id_client  NUMBER,
  3       nameclient VARCHAR2(15))
  4  /
Table created.
scott@ORA92> CREATE TABLE p_items
  2    (id_client  NUMBER,
  3       name_item  VARCHAR2(10),
  4       price_item NUMBER)
  5  /
Table created.
scott@ORA92> CREATE OR REPLACE PACKAGE PE_CL
  2  IS
  3    TYPE item_array IS ARRAY(10) OF VARCHAR2(10);
  4    TYPE price_array IS ARRAY(10) OF number;
  5    PROCEDURE p_proc
  6        (Id_clt    IN P_CLIENT.id_client%TYPE,
  7         nameClt   IN P_CLIENT.nameclient%TYPE,
  8         priceItem IN price_array,
  9         nameItem  IN item_array);
10  end PE_CL;
11  /
Package created.
scott@ORA92> show errors
No errors.
-- first method:
scott@ORA92> CREATE OR REPLACE PACKAGE BODY PE_CL
  2  IS
  3    PROCEDURE p_proc
  4        (Id_clt    IN P_CLIENT.id_client%TYPE,
  5         nameClt   IN P_CLIENT.nameclient%TYPE,
  6         priceItem IN price_array,
  7         nameItem  IN item_array)
  8    IS
  9    BEGIN
10        INSERT INTO P_CLIENT VALUES (Id_clt, nameClt);
11  --    FORALL i IN nameItem.FIRST .. nameItem.LAST
12  --      INSERT INTO P_ITEMS VALUES (Id_clt, nameItem(i), priceItem(i));
13        FOR i IN nameItem.FIRST .. nameItem.LAST LOOP
14          IF nameItem.EXISTS(i) AND priceItem.EXISTS(i) THEN
15            INSERT INTO P_ITEMS VALUES (Id_clt, nameItem(i), priceItem(i));
16          END IF;
17        END LOOP;
18    END;
19  end PE_CL;
20  /
Package body created.
scott@ORA92> show errors
No errors.
scott@ORA92> declare
  2    priceitem pe_cl.price_array := pe_cl.price_array(2, 5);
  3    nameitem pe_cl.item_array := pe_cl.item_array('item a', 'item b', 'item c');
  4  begin
  5    pe_cl.p_proc
  6        (id_clt    => 900,
  7         nameclt   => 'MIKE',
  8         priceitem => priceitem,
  9         nameitem  => nameitem);
10    COMMIT;
11  end;
12  /
PL/SQL procedure successfully completed.
scott@ORA92> SELECT * FROM p_client
  2  /
ID_CLIENT NAMECLIENT
       900 MIKE
scott@ORA92> SELECT * FROM p_items
  2  /
ID_CLIENT NAME_ITEM  PRICE_ITEM
       900 item a              2
       900 item b              5
scott@ORA92> TRUNCATE TABLE p_client
  2  /
Table truncated.
scott@ORA92> TRUNCATE TABLE p_items
  2  /
Table truncated.
-- second method:
scott@ORA92> CREATE OR REPLACE PACKAGE BODY PE_CL
  2  IS
  3    PROCEDURE p_proc
  4        (Id_clt    IN P_CLIENT.id_client%TYPE,
  5         nameClt   IN P_CLIENT.nameclient%TYPE,
  6         priceItem IN price_array,
  7         nameItem  IN item_array)
  8    IS
  9    BEGIN
10        INSERT INTO P_CLIENT VALUES (Id_clt, nameClt);
11  --    FORALL i IN nameItem.FIRST .. nameItem.LAST
12  --      INSERT INTO P_ITEMS VALUES (Id_clt, nameItem(i), priceItem(i));
13        FOR i IN nameItem.FIRST .. nameItem.LAST LOOP
14          IF nameItem.EXISTS(i) AND priceItem.EXISTS(i) THEN
15            INSERT INTO P_ITEMS VALUES (Id_clt, nameItem(i), priceItem(i));
16          ELSIF nameItem.EXISTS(i) THEN
17            INSERT INTO P_ITEMS VALUES (Id_clt, nameItem(i), null);
18          ELSIF priceItem.EXISTS(i) THEN
19            INSERT INTO P_ITEMS VALUES (Id_clt, null, priceItem(i));
20          END IF;
21        END LOOP;
22    END;
23  end PE_CL;
24  /
Package body created.
scott@ORA92> show errors
No errors.
scott@ORA92> declare
  2    priceitem pe_cl.price_array := pe_cl.price_array(2, 5);
  3    nameitem pe_cl.item_array := pe_cl.item_array('item a', 'item b', 'item c');
  4  begin
  5    pe_cl.p_proc
  6        (id_clt    => 900,
  7         nameclt   => 'MIKE',
  8         priceitem => priceitem,
  9         nameitem  => nameitem);
10    COMMIT;
11  end;
12  /
PL/SQL procedure successfully completed.
scott@ORA92> SELECT * FROM p_client
  2  /
ID_CLIENT NAMECLIENT
       900 MIKE
scott@ORA92> SELECT * FROM p_items
  2  /
ID_CLIENT NAME_ITEM  PRICE_ITEM
       900 item a              2
       900 item b              5
       900 item c