OUT Params in Procedure. Oracle 9

Question

I am new to PL/SQl, and im doing an asp .net site connectin to oracle using ODP
I have written an procedure to take in Params and add a record to a DB, however I now want to use an OUT Param which will return a value to detemine whether the record already exists, this is my procedure, as you can see i have added an INOUT var called pv_exists, i want to check for the input records in my DB, is they exist i want the pv_exists to return a Zero to be site, any ideeas, im at a loss?
CREATE OR REPLACE PROCEDURE HR_USER."SP_ADDPR" (pv_prtype varchar2, pv_team number,pv_year varchar2, pv_month varchar2, pv_alert date, pv_exists IN OUT number )
IS
pv_rowCount number;
pv_tblid number;
pv_text number;
BEGIN
select Count(*) Into pv_rowCount from TBLPR;
if pv_rowCount > 0 then
select Max(ID) + 1 into pv_tblid from TBLPR;
Insert into TBLPR(id,PRType,PRTeamid,PRYEAR,PRMONTH,PRALERTDATE) Values (pv_tblid,pv_prtype,pv_team,pv_year,pv_month,pv_alert);
else
Insert into TBLPR(id,PRType,PRTeamid,PRYEAR,PRMONTH,PRALERTDATE) Values (1,pv_prtype,pv_team,pv_year,pv_month,pv_alert);
end if;
EXCEPTION
WHEN NO_DATA_FOUND THEN
NULL;
WHEN OTHERS THEN
RAISE;
END sp_AddPR;

Answer 1

Cheer up, Hughesie
create table tblpr(id          number(10)   not null
                  ,prtype      varchar2(10) not null
                  ,prteamid    varchar2(10) not null
                  ,pryear      number(4)    not null
                  ,prmonth     varchar2(12) not null
                  ,pralertdate date         not null
                  ,constraint tblpr_pk primary key (id));
/* Not sure about the natural key, but use this to tell "if record exists" */
create unique index tblrpr_ux1 on tblpr(prtype, prteamid);             
create sequence tblpr_id_seq;
create or replace package tblpr_te
as
   subtype tblpr_rt is tblpr%rowtype;  
   subtype prtype_t is tblpr.prtype%type;
   subtype prteamid_t is tblpr.prteamid%type;
   subtype pryear_t is tblpr.pryear%type;
   subtype prmonth_t is tblpr.prmonth%type;
   subtype pralertdate_t is tblpr.pralertdate%type;
   procedure add(po_exists out pls_integer
                ,pi_prtype in  prtype_t 
                ,pi_team   in  prteamid_t
                ,pi_year   in  pryear_t
                ,pi_month  in  prmonth_t
                ,pi_alert  in  pralertdate_t);
end tblpr_te;
create or replace package body tblpr_te
as
   procedure add(po_exists out pls_integer
                ,pi_prtype in  prtype_t 
                ,pi_team   in  prteamid_t
                ,pi_year   in  pryear_t
                ,pi_month  in  prmonth_t
                ,pi_alert  in  pralertdate_t)
   is
   begin
      insert into tblpr(id
                       ,prtype
                       ,prteamid
                       ,pryear
                       ,prmonth
                       ,pralertdate)
               values (tblpr_id_seq.nextval
                      ,pi_prtype
                      ,pi_team
                      ,pi_year
                      ,pi_month
                      ,pi_alert);
      po_exists := 0;
   exception
   when dup_val_on_index
   then
      po_exists := 1;
   end add;   
end tblpr_te;
select * from tblpr;
set serveroutput on
declare
  l_exists pls_integer;
begin
   tblpr_te.add(l_exists, 'A_Type', 'Some_Team', 2008, 'January', sysdate +12);
   commit;  
   dbms_output.put_line('l_exists: ' || l_exists);
end;
select * from tblpr;
drop package tblpr_te;
drop sequence tblpr_id_seq;
drop table tblpr purge
/Regards
Peter