Painful error trying to convert to/from decimal minutes

Question

So I have a timecard application and I am trying to design a popup window that allows a user to apply for additional pay.
The user supplies an hour time, minutes time and AM/PM (all from drop-downs). Then they supply a length of time in hours and minutes (two different fields) and a reason (also from drop-down).
I am using collections and that part appears to be working fine with one glitch: it only works if I put in a number of minutes divisible by 3. I anticipate that this is because I have to record the decimal time in another field, and for some reason the conversion I am using is dying. Oracle throws up an error "ORA-06502: PL/SQL: numeric or value error: character to number conversion error" if I try to use say 22 as the number of minutes.
In the background, I am trying to store these as three fields: the JOB_START_TIME (date), the JOB_END_TIME (date) and TASK_HRS (number 5,2).
Can someone help me look at my database write query and help me correct this?
declare
  v_tc       NUMBER   := :P12_TC_ID;
  tc_dy      VARCHAR2(12);
  tc_st      DATE;
  tc_ed      DATE;
  tc_shft    VARCHAR2(3);
  beg_dt     DATE;
  ed_dt      DATE;
  tsk_hrs    NUMBER   := 0;
  tsk_min    NUMBER   := 0;
  tsk_ttl    NUMBER   := 0;
  v_loc      NUMBER;
  v_pycd     VARCHAR2(8);
  v_jbcd     VARCHAR2(8);
begin
  select to_char(DATE_INDEX,'MM/DD/YYYY'), TC_START_TIME, TC_END_TIME, SHIFT
    into tc_dy, tc_st, tc_ed, tc_shft
    from TC where TC_ID = v_tc;
  for cu in (select TO_NUMBER(c001) u_id, c002 st_hrs, c003 st_min, c004 st_am,
             c005 ed_hrs, c006 ed_min, c007 ed_am,
             TO_NUMBER(c009) ttl_hrs, TO_NUMBER(c010) ttl_min,
             TO_NUMBER(c011) rsn_id
           FROM APEX_COLLECTIONS
           WHERE COLLECTION_NAME = 'SUPP_PAY_REQ') loop
    IF cu.u_id = 0 and cu.rsn_id > 0 THEN     -- new row
      select to_date(tc_dy||' '||cu.st_hrs||':'||cu.st_min||' '||cu.st_am,'MM/DD/YYYY HH:MI AM')
        into beg_dt from dual;
      IF beg_dt < tc_st THEN
        beg_dt   := beg_dt + 1;
      END IF;
      tsk_hrs    := cu.ttl_hrs;
      tsk_min    := ROUND(cu.ttl_min*10/6,2);
      tsk_ttl    := to_number(tsk_hrs||'.'||tsk_min);     <---  This is the problem line
      ed_dt      := beg_dt + tsk_ttl/24;
      select LOCATION_ID, PAY_CODE, OLD_CODE into v_loc, v_pycd, v_jbcd
        from OTHR_RATES where OTHR_RATE_ID = cu.rsn_id;
      INSERT INTO TC_OTHR_JOBS (OTHR_HRLY_JOB_ID, TC_ID,
           JOB_START_TIME, JOB_END_TIME, TASK_HRS, HRLY_RATE_ID, PAY_AMT,
           LOCATION_ID, PAY_CODE, OLD_CODE, JOB_COMMENTS, JOB_ENTRY_FLAG)
       VALUES (SEQ_TC_JOBS.nextval, v_tc,
           beg_dt, ed_dt, tsk_ttl, cu.rsn_id, 0,
           v_loc, v_pycd, v_jbcd, 'Submitted by Employee', 3);
    ------ existing row
    ELSIF cu.u_id > 0 THEN
      select to_date(tc_dy||' '||cu.st_hrs||':'||cu.st_min||' '||cu.st_am,'MM/DD/YYYY HH:MI AM')
        into beg_dt from dual;
      IF beg_dt < tc_st THEN
        beg_dt   := beg_dt + 1;
      END IF;
      tsk_hrs    := cu.ttl_hrs;
      tsk_min    := ROUND(cu.ttl_min*10/6,2);
      tsk_ttl    := to_number(tsk_hrs||'.'||tsk_min);     <---  This is the problem line
      ed_dt      := beg_dt + tsk_ttl/24;
      select LOCATION_ID, PAY_CODE, OLD_CODE into v_loc, v_pycd, v_jbcd
        from OTHR_RATES where OTHR_RATE_ID = cu.rsn_id;
      UPDATE TC_OTHR_JOBS SET JOB_START_TIME = beg_dt, JOB_END_TIME = ed_dt,
           TASK_HRS = tsk_ttl, HRLY_RATE_ID = cu.rsn_id,
           LOCATION_ID = v_loc, PAY_CODE = v_pycd, OLD_CODE = v_jbcd,
           JOB_COMMENTS = 'Submitted by Employee',
           JOB_ENTRY_FLAG = 3, PAY_AMT = 0
       WHERE OTHR_HRLY_JOB_ID = cu.u_id;
      UPDATE TC set PROCESS_FLAG = 30 where TC_ID = v_tc;
    END IF;
  end loop;
end;

Answer 1

Okay, got it. It turns out that you have to go one-way on your conversions or the decimal minutes get you hung up. Here's the corrected version that works:
declare
  v_tc       NUMBER   := :P12_TC_ID;
  tc_dy      VARCHAR2(12);
  tc_st      DATE;
  tc_ed      DATE;
  tc_shft    VARCHAR2(3);
  beg_dt     DATE;
  ed_dt      DATE;
  tsk_hrs    NUMBER   := 0;
  tsk_min    NUMBER   := 0;
  tsk_ttl    NUMBER   := 0;
  min_tst    NUMBER   := 0;
  v_loc      NUMBER;
  v_pycd     VARCHAR2(8);
  v_jbcd     VARCHAR2(8);
begin
  select to_char(DATE_INDEX,'MM/DD/YYYY'), TC_START_TIME, TC_END_TIME, SHIFT
    into tc_dy, tc_st, tc_ed, tc_shft
    from TC where TC_ID = v_tc;
  for cu in (select TO_NUMBER(c001) u_id, c002 st_hrs, c003 st_min, c004 st_am,
             c005 ed_hrs, c006 ed_min, c007 ed_am,
             TO_NUMBER(c009) ttl_hrs, TO_NUMBER(c010) ttl_min,
             TO_NUMBER(c011) rsn_id
           FROM APEX_COLLECTIONS
           WHERE COLLECTION_NAME = 'SUPP_PAY_REQ') loop
    IF cu.u_id = 0 and cu.rsn_id > 0 THEN     -- new row
      select to_date(tc_dy||' '||cu.st_hrs||':'||cu.st_min||' '||cu.st_am,'MM/DD/YYYY HH:MI AM')
        into beg_dt from dual;
      IF beg_dt < tc_st THEN
        beg_dt   := beg_dt + 1;
      END IF;
      tsk_hrs    := cu.ttl_hrs;
      min_tst    := (tsk_hrs*60 + to_number(cu.ttl_min))/60;
      ed_dt      := beg_dt + min_tst/24;
      select LOCATION_ID, PAY_CODE, OLD_CODE into v_loc, v_pycd, v_jbcd
        from OTHR_RATES where OTHR_RATE_ID = cu.rsn_id;
      INSERT INTO TC_OTHR_JOBS (OTHR_HRLY_JOB_ID, TC_ID,
           JOB_START_TIME, JOB_END_TIME, TASK_HRS, HRLY_RATE_ID, PAY_AMT,
           LOCATION_ID, PAY_CODE, OLD_CODE, JOB_COMMENTS, JOB_ENTRY_FLAG)
       VALUES (SEQ_TC_JOBS.nextval, v_tc,
           beg_dt, ed_dt, min_tst, cu.rsn_id, 0,
           v_loc, v_pycd, v_jbcd, 'Submitted by Employee', 3);
      UPDATE TC set PROCESS_FLAG = 30 where TC_ID = v_tc;
    ------ existing row
    ELSIF cu.u_id > 0 THEN
      select to_date(tc_dy||' '||cu.st_hrs||':'||cu.st_min||' '||cu.st_am,'MM/DD/YYYY HH:MI AM')
        into beg_dt from dual;
      IF beg_dt < tc_st THEN
        beg_dt   := beg_dt + 1;
      END IF;
      tsk_hrs    := cu.ttl_hrs;
      min_tst    := (tsk_hrs*60 + to_number(cu.ttl_min))/60;
      ed_dt      := beg_dt + min_tst/24;
      select LOCATION_ID, PAY_CODE, OLD_CODE into v_loc, v_pycd, v_jbcd
        from OTHR_RATES where OTHR_RATE_ID = cu.rsn_id;
      UPDATE TC_OTHR_JOBS SET JOB_START_TIME = beg_dt, JOB_END_TIME = ed_dt,
           TASK_HRS = min_tst, HRLY_RATE_ID = cu.rsn_id,
           LOCATION_ID = v_loc, PAY_CODE = v_pycd, OLD_CODE = v_jbcd,
           JOB_COMMENTS = 'Submitted by Employee',
           JOB_ENTRY_FLAG = 3, PAY_AMT = 0
       WHERE OTHR_HRLY_JOB_ID = cu.u_id;
      UPDATE TC set PROCESS_FLAG = 30 where TC_ID = v_tc;
    END IF;
  end loop;
end;