Pass a rowtype to a function in sql

Question

Hi all,
Oracle Database 10g Enterprise Edition Release 10.2.0.4.0
Can you please tell me if the following is possible:
I have a function that takes a rowtype as one of the parameters and returns a varchar2
function test( pa_text in varchar2,
               pa_emp  in employee%rowtype
  ) return varchar2I had hoped I could use this function in a implicit cursor, something like
begin
  for c in ( select d.deptno
             ,      test(d.deptno, e.*) test
             from   emp  e
             ,      dept d
             where  e.deptno = d.deptno )
  loop
  end loop;
end;But this results in
Error: PL/SQL: ORA-01747: invalid user.table.column, table.column, or column specificationIs something like this even possible?
Thanks!
Rob

Answer 1

What you could do:
declare
    v_deptno dept.deptno%type;
    v_dcur sys_refcursor;
    v_ecur sys_refcursor;
    v_emp emp%rowtype;
begin
    open v_dcur for select  d.deptno,
                            cursor(
                                   select  e.*
                                     from  emp e
                                     where e.deptno = d.deptno
                                  ) e
                      from  dept d;
    loop
      fetch v_dcur
        into v_deptno,
             v_ecur;
        exit when v_dcur%notfound;
      loop
        fetch v_ecur
          into v_emp;
        exit when v_ecur%notfound;
        test(v_deptno,v_emp);
      end loop;
      close v_ecur;
    end loop;
    close v_dcur;
end;
/For example:
SQL> create or replace
  2    function test(
  3                  pa_text in varchar2,
  4                  pa_emp  in emp%rowtype
  5                 )
  6      return varchar2
  7      is
  8      begin
  9          return 'DEPTNO = ' || pa_text || ' ENAME = ' || pa_emp.ename;
10  end;
11  /
Function created.
SQL> set serveroutput on
SQL> declare
  2      v_deptno dept.deptno%type;
  3      v_dcur sys_refcursor;
  4      v_ecur sys_refcursor;
  5      v_emp emp%rowtype;
  6  begin
  7      open v_dcur for select  d.deptno,
  8                              cursor(
  9                                     select  e.*
10                                       from  emp e
11                                       where e.deptno = d.deptno
12                                    ) e
13                        from  dept d;
14      loop
15        fetch v_dcur
16          into v_deptno,
17               v_ecur;
18          exit when v_dcur%notfound;
19        loop
20          fetch v_ecur
21            into v_emp;
22          exit when v_ecur%notfound;
23          dbms_output.put_line(test(v_deptno,v_emp));
24        end loop;
25        close v_ecur;
26      end loop;
27      close v_dcur;
28  end;
29  /
DEPTNO = 10 ENAME = CLARK
DEPTNO = 10 ENAME = KING
DEPTNO = 10 ENAME = MILLER
DEPTNO = 20 ENAME = SMITH
DEPTNO = 20 ENAME = JONES
DEPTNO = 20 ENAME = SCOTT
DEPTNO = 20 ENAME = ADAMS
DEPTNO = 20 ENAME = FORD
DEPTNO = 30 ENAME = ALLEN
DEPTNO = 30 ENAME = WARD
DEPTNO = 30 ENAME = MARTIN
DEPTNO = 30 ENAME = BLAKE
DEPTNO = 30 ENAME = TURNER
DEPTNO = 30 ENAME = JAMES
PL/SQL procedure successfully completed.
SQL> SY.