Performance decission DECODE vs CASE

Question

Hi Gurus,
I have a stored procedure that has to process around 2 million records. The performance is very slow at the moment.
I need advise on the following section :-)
CASE x
WHEN '1' THEN
y := 'A';
WHEN '2' THEN
y := 'B';
WHEN '3' THEN
y := 'C';
WHEN '...'
y := '...';
END CASE;
There are around 25 different cases, of course the values I put here are dummy...
Can I replace it with DECODE as its 1 to 1 comparison / return like
y := DECODE(x, '1', 'A', '2', 'B', '3', 'C', .... '...', '...');
Is it a faster executing code or CASE better? I know, CASE has its own advantages like readability, flexibility etc. but how about performance in my particular expression set?
Best Regards,
Faisal.

Answer 1

You could also consider the following.
declare
  v_dummy VARCHAR2(1);
  v_start timestamp;
  v_end timestamp;
begin
  v_start := systimestamp;
  for i in 1..100 loop
    for j in (select decode(status,'INVALID','I','VALID','V') s
              FROM dba_objects) loop
      v_dummy := j.s;
    END LOOP;
  END LOOP;
  v_end := systimestamp;
  dbms_output.put_line('time : '||to_char(v_end - v_start,'SSSSS.FF'));
END;
time : +000000 00:00:25.454000000
time : +000000 00:00:25.422000000
time : +000000 00:00:25.515000000
===========================================================================
declare
  v_dummy VARCHAR2(1);
  v_start timestamp;
  v_end timestamp;
begin
  v_start := systimestamp;
  for i in 1..100 loop
    for j in (select case status when 'INVALID' then 'I'
                                 when 'VALID' then 'V' end s
              FROM dba_objects) loop
      v_dummy := j.s;
    END LOOP;
  END LOOP;
  v_end := systimestamp;
  dbms_output.put_line('time : '||to_char(v_end - v_start,'SSSSS.FF'));
END;
time : +000000 00:00:25.187000000
time : +000000 00:00:25.031000000
time : +000000 00:00:25.141000000
===========================================================================
declare
  v_dummy VARCHAR2(1);
  v_start timestamp;
  v_end timestamp;
begin
  v_start := systimestamp;
  for i in 1..100 loop
    for j in (select status s
              FROM dba_objects) loop
      SELECT decode(j.s,'INVALID','I','VALID','V')
      into   v_dummy
      FROM   dual;
    END LOOP;
  END LOOP;
  v_end := systimestamp;
  dbms_output.put_line('time : '||to_char(v_end - v_start,'SSSSS.FF'));
END;
time : +000000 00:04:07.688000000
time : +000000 00:04:06.953000000
time : +000000 00:04:07.453000000
===========================================================================
declare
  v_dummy VARCHAR2(1);
  v_start timestamp;
  v_end timestamp;
begin
  v_start := systimestamp;
  for i in 1..100 loop
    for j in (select status s
              FROM dba_objects) loop
      case j.s when 'INVALID' then v_dummy := 'I';
               when 'VALID' then v_dummy := 'V';
               end case;
    END LOOP;
  END LOOP;
  v_end := systimestamp;
  dbms_output.put_line('time : '||to_char(v_end - v_start,'SSSSS.FF'));
END;
time : +000000 00:00:25.187000000
time : +000000 00:00:25.343000000
time : +000000 00:00:25.172000000This on a windows dual core laptop with 10gR2
Regards
Andre