PHOTOSHOP - a lot of actions

Question

Hello Mark,
Does anyone else know this issue?
I'm trying to put your script together so I don't have to use the photoshop batch.
Now I get this fault. : Adobe Photoshop got CS wrongly: channel "Cyan" or current document
cannot be granted to current channels or current document.
Do you know how I also can say that the images must be resized to 300DPI?
1- RGB to CMYK
2- I just want to change the magenta and cyaan curves.
3- adjusting to 300 DPI.
4- save as JPG quality 12 ( same folder overwriting the existing image and then just cloose the image)
((We have always backups of the images.))
The script stops after rgb->CMYK
tell application "Finder"
set inputFolder to folder (((desktop as string) & "Test Folder") as string) as alias
set filesList to files in inputFolder
end tell
repeat with aFile in filesList
set fileIndex to 0
tell application "Finder"
set thefile to aFile as alias
set theFileName to name of thefile
end tell
tell application "Adobe Photoshop CS"
activate
set display dialogs to never
open thefile
tell the current document
if (mode is not CMYK) then
change mode to CMYK
end if
set current channels to channel "Cyan"
adjust layers using curves with options ¬
{class:curves, curve points:{{0, 6}, {50, 50}, {128, 128}, {238, 238}, {255, 241}}}
-- To adjust each channel individualy set the current channel
set current channels to channel "Magenta"
adjust layers using curves with options ¬
{class:curves, curve points:{{0, 6}, {50, 50}, {128, 128}, {238, 238}, {255, 238}}}
end tell
save the current document as JPEG with options ¬
{class:JPEG save options, embed color profile:true, quality:12}
end tell
end repeat

Answer 1

Colin, This should do what you want. You can change the input folder to be hard coded if you like, a simple change. Hope this helps.
set inputFolder to choose folder with prompt "Where are your files?"
tell application "Finder"
set filesList to files in inputFolder
end tell
repeat with aFile in filesList
set fileIndex to 0
tell application "Finder"
set theFile to aFile as alias
set theFileName to name of theFile
end tell
tell application "Adobe Photoshop CS"
activate
set display dialogs to never
set ruler units of settings to pixel units
open theFile
set docRef to the current document
tell docRef
if (mode of docRef is not CMYK) then
change mode docRef to CMYK
end if
if (bits per channel of docRef is sixteen) then
set bits per channel of docRef to eight
end if
set docHeight to height of docRef
resize image height docHeight as pixels resolution 300
set current channels to channel "Cyan"
adjust layers using curves with options ¬
{class:curves, curve points:{{0, 0}, {44, 54}, {128, 128}, {191, 208}, {255, 255}}}
set current channels to channel "Magenta"
adjust layers using curves with options ¬
{class:curves, curve points:{{0, 0}, {64, 44}, {128, 128}, {189, 212}, {255, 255}}}
set current channels to component channels
set docName to name of docRef
set docBaseName to getBaseName(docName) of me
set newFileName to (inputFolder as string) & docBaseName
save docRef in file newFileName as JPEG with options ¬
{class:JPEG save options, embed color profile:true, quality:12} appending lowercase extension with copying
end tell
close current document without saving
end tell
end repeat
on getBaseName(fName)
set baseName to fName
repeat with idx from 1 to (length of fName)
if (item idx of fName = ".") then
set baseName to (items 1 thru (idx - 1) of fName) as string
exit repeat
end if
end repeat
return baseName
end getBaseName