Populate CL_GUI_TEXTEDIT editor with text for user to modify

Question

Hi, What method of class CL_GUI_TEXTEDIT can I use to prepopulate the onscreen editor for someone to modify?  Also, an example would be greatly appreciated!
Thanks
I am using this program to maintain a string field URL in a table.  If you have a better way it would be greatly appreciated!
REPORT  ZDW_1ST_RX_LINK_MAINT.
DATA: DOCKINGLEFT TYPE REF TO CL_GUI_DOCKING_CONTAINER.
DATA: TEXT_EDITOR TYPE REF TO CL_GUI_TEXTEDIT.
DATA: REPID       TYPE SYREPID.
DATA: TEXTLINES   TYPE TABLE OF TLINE-TDLINE.
DATA: WA_TEXT     TYPE TLINE-TDLINE.
DATA: REPORT_URL  TYPE STRING.
DATA: TEXT_ITAB   TYPE TABLE OF SOLISTI1.
DATA: TEXT_ITAB2  LIKE LINE OF TEXT_ITAB.
PARAMETERS: P_REPGRP TYPE ZDWRPTGRP.         " Report
PARAMETERS: P_SFORCE TYPE /BIC/OIZDWSFORCE.  " Report Qualifier
PARAMETERS: P_REPDES TYPE C LENGTH 60.
PARAMETERS: P_ACTION TYPE C.                 " Action
AT SELECTION-SCREEN OUTPUT.
  REPID = SY-REPID.
  CREATE OBJECT DOCKINGLEFT
     EXPORTING REPID = REPID
     DYNNR           = SY-DYNNR
     SIDE            = DOCKINGLEFT->DOCK_AT_BOTTOM
     EXTENSION       = 280.
  CREATE OBJECT TEXT_EDITOR
     EXPORTING PARENT     = DOCKINGLEFT.
START-OF-SELECTION.
  CALL METHOD TEXT_EDITOR->GET_TEXT_AS_STREAM
    IMPORTING
      TEXT   = TEXT_ITAB
    EXCEPTIONS
      OTHERS = 1.
  LOOP AT TEXT_ITAB INTO TEXT_ITAB2.
    CONCATENATE REPORT_URL TEXT_ITAB2-LINE INTO REPORT_URL.
  ENDLOOP.
  DATA: S_SFURL TYPE ZDW_SFURL.
  S_SFURL-REPORT_GROUP = P_REPGRP.
  S_SFURL-SALES_FORCE  = P_SFORCE.
  S_SFURL-REPORT_URL   = REPORT_URL.
  CASE P_ACTION.
    WHEN 'I'.
      INSERT ZDW_SFURL FROM S_SFURL.
    WHEN 'D'.
      DELETE FROM ZDW_SFURL
         WHERE REPORT_GROUP = P_REPGRP
           AND SALES_FORCE  = P_SFORCE.
    WHEN 'U'.
      UPDATE ZDW_SFURL FROM S_SFURL.
  ENDCASE.

Answer 1

Or you can use the methods in this example.
report zrich_0001 .
data:
      dockingleft  type ref to cl_gui_docking_container,
      text_editor    type ref to cl_gui_textedit,
      repid type syrepid.
data: itext type table of tline-tdline,
      xtext type tline-tdline.
parameters: p_check.
at selection-screen output.
  repid = sy-repid.
  create object dockingleft
              exporting repid     = repid
                        dynnr     = sy-dynnr
                        side      = dockingleft->dock_at_left
                        extension = 1070.
  create object text_editor
              exporting
                   parent     = dockingleft.
  xtext = 'http:\www.sap.com'.
  append xtext to itext.
  call method text_editor->set_text_as_r3table
     exporting
           table              = itext
     exceptions
           others             = 1.
start-of-selection.
  call method text_editor->get_text_as_r3table
     importing
           table              = itext
     exceptions
           others             = 1.
  loop at itext into xtext.
    write:/ xtext.
  endloop.
Regards,
RIch Heilman