Possible to get variable name?

Question

Is it possible to get the name that you have used in your code of a variable?
ie.
procedure main_procedure
is
   l_var varchar2(10) := 'Hello';
begin
   dbms_output.put_line(get_var_name(l_var));
end;
function get_var_name(p_var in varchar2)
return varchar2
is
begin
   -- insert magic here
end;
-- End code; Now call the procedure
exec main_procedure;-- Needed output:
"variable passed had name l_var and value Hello"

Answer 1

Hi Sam,
OK, this is definitely for fun only and NOT recommended for any production database!!
With that out of the way, this has been adapted from Tom Kyte's who_called_me:
SQL> create or replace procedure get_var_name (
  2     p_var in varchar2
  3  )
  4  as
  5     call_stack   varchar2(4096) default dbms_utility.format_call_stack;
  6     n            number;
  7     found_stack  boolean default false;
  8     l_line       varchar2(255);
  9     cnt          number := 0;
10     l_owner      varchar2(255);
11     l_name       varchar2(255);
12     lineno       number;
13     caller_t     varchar2(255);
14     calling_line varchar2(4000);
15     var_name     varchar2(1000);
16  begin
17     loop
18        n := instr( call_stack, chr(10) );
19        exit when ( cnt = 3 or n is null or n = 0 );
20        l_line := substr( call_stack, 1, n-1 );
21        call_stack := substr( call_stack, n+1 );
22        if ( not found_stack ) then
23           if ( l_line like '%handle%number%name%' ) then
24              found_stack := true;
25           end if;
26        else
27           cnt := cnt + 1;
28           -- cnt = 1 is ME
29           -- cnt = 2 is MY Caller
30           -- cnt = 3 is Their Caller
31           if ( cnt = 2 ) then
32              lineno := to_number(substr( l_line, 13, 6 ));
33              l_line   := substr( l_line, 21 );
34              if ( l_line like 'pr%' ) then
35                 n := length( 'procedure ' );
36              elsif ( l_line like 'fun%' ) then
37                 n := length( 'function ' );
38              elsif ( l_line like 'package body%' ) then
39                 n := length( 'package body ' );
40              elsif ( l_line like 'pack%' ) then
41                 n := length( 'package ' );
42              elsif ( l_line like 'anonymous%' ) then
43                 n := length( 'anonymous block ' );
44              else
45                 n := null;
46              end if;
47              if ( n is not null ) then
48                 caller_t := ltrim(rtrim(upper(substr( l_line, 1, n-1 ))));
49              else
50                 caller_t := 'TRIGGER';
51              end if;
52 
53              l_line := substr( l_line, nvl(n,1) );
54              n := instr( l_line, '.' );
55              l_owner := ltrim(rtrim(substr( l_line, 1, n-1 )));
56              l_name  := ltrim(rtrim(substr( l_line, n+1 )));
57           end if;
58        end if;
59     end loop;
60     select text
61     into calling_line
62     from all_source
63     where line = lineno
64     and type = caller_t
65     and name = l_name
66     and owner = l_owner;
67     var_name := trim ( substr (
68        calling_line
69        , instr(calling_line, '(') + 1
70        , instr(calling_line, ')') - instr(calling_line, '(') - 1
71     ));
72     dbms_output.put_line('variable passed had name '||var_name||' and value '||p_var);
73  end;
74  /
Procedure created.
SQL> create or replace procedure main_procedure
  2  is
  3     l_var varchar2(10) := 'Hello';
  4  begin
  5     get_var_name(l_var);
  6  end;
  7  /
Procedure created.
SQL> exec main_procedure;
variable passed had name l_var and value Hello
PL/SQL procedure successfully completed.cheers,
Anthony