Posting date calculation

Question

If a transaction attempts to post in SAP on the Wed. through Sat. of a financial period close, the SAP posting date should be set to the first day of the next financial period
pl. provide details of teh FM that can be used to solve the above mentioned scnerio.
I only have SY_DATUM as input.

Answer 1

Try this code. There is no easy way to do this. Let me know if my understanding is wrong.
Please close the thread if answered.
REPORT zreport NO STANDARD PAGE HEADING MESSAGE-ID zfi
                                        LINE-COUNT 65
                                        LINE-SIZE 120.
DATA: v_poper                      LIKE t009b-poper,
      v_bdatj                      LIKE t009b-bdatj,
      v_next_poper                 LIKE t009b-poper,
      v_next_bdatj                 LIKE t009b-bdatj,
      v_first_day_of_next_period   LIKE sy-datum,
      v_last_day_of_current_period LIKE sy-datum,
      v_monday                     LIKE sy-datum,
      v_tuesday                    LIKE sy-datum,
      v_sunday                     LIKE sy-datum,
      v_wotnr                      TYPE p,
      v_posting_date               LIKE sy-datum.
PARAMETERS: p_date  LIKE sy-datum DEFAULT sy-datum,
            p_periv LIKE t009b-periv.
START-OF-SELECTION.
*-- get the current date's period and year
  CALL FUNCTION 'DATE_TO_PERIOD_CONVERT'
       EXPORTING
            i_date               = p_date
*           I_MONMIT             = 00
            i_periv              = p_periv
       IMPORTING
            e_buper              = v_poper
            e_gjahr              = v_bdatj
       EXCEPTIONS
            input_false          = 1
            t009_notfound        = 2
            t009b_notfound       = 3
            OTHERS               = 4.
  IF sy-subrc <> 0.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
            WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.
*-- get the last day in the current period
  CALL FUNCTION 'LAST_DAY_IN_PERIOD_GET'
       EXPORTING
            i_gjahr        = v_bdatj
            i_monmit       = '00'
            i_periv        = p_periv
            i_poper        = v_poper
       IMPORTING
            e_date         = v_last_day_of_current_period
       EXCEPTIONS
            input_false    = 1
            t009_notfound  = 2
            t009b_notfound = 3
            OTHERS         = 4.
  IF sy-subrc <> 0.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
            WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.
*-- Get week info of the last day of the current period
  CALL FUNCTION 'GET_WEEK_INFO_BASED_ON_DATE'
       EXPORTING
            date   = v_last_day_of_current_period
       IMPORTING
*           week   =
            monday = v_monday       " First day of period closing week
            sunday = v_sunday.      " Last day of period closing week
  v_tuesday = v_monday + 1.
  IF p_date <= v_tuesday.
*-- entered date is before or equal to the tuesday of the week of
*   current period's last date, allow posting to the current period
    v_posting_date = p_date.
  ELSE.
*-- get the next period
    CALL FUNCTION 'CKML_F_GET_NEXT_PERIOD'
         EXPORTING
              input_period = v_poper
              input_year   = v_bdatj
              input_periv  = p_periv
         IMPORTING
              next_period  = v_next_poper
              next_year    = v_next_bdatj.
*-- get the first day in next period get
    CALL FUNCTION 'FIRST_DAY_IN_PERIOD_GET'
         EXPORTING
              i_gjahr        = v_next_bdatj
              i_monmit       = '00'
              i_periv        = p_periv
              i_poper        = v_next_poper
         IMPORTING
              e_date         = v_first_day_of_next_period
         EXCEPTIONS
              input_false    = 1
              t009_notfound  = 2
              t009b_notfound = 3
              OTHERS         = 4.
    IF sy-subrc <> 0.
      MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
              WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
    ENDIF.
    v_posting_date = v_first_day_of_next_period.
  ENDIF.
  WRITE:/ v_posting_date.