Problems with dbms_aq.listen

Question

I am having problem trying to listen to a set of queues.
I have tried it with Single Consumer queues and it works fine.
But with Multi Consumer queues dbms_aq.listen does not detect a new message enqueued and just waits until the time out then returns with the normal "No message" exception.
Can any one tell me what I am doing wrong?
Thanks
Rick Laird
code
CREATE OR REPLACE TYPE message_type AS OBJECT (xml_message CLOB);
exec dbms_aqadm.create_queue_table('testqueue_qtable','message_type',Null,Null,true);
exec dbms_aqadm.create_queue('testqueue', 'testqueue_qtable');
exec dbms_aqadm.start_queue('testqueue');
exec dbms_aqadm.add_subscriber('testqueue',sys.aq$_agent('testqueue_subscriber',NULL,NULL));
exec DBMS_AQADM.SCHEDULE_PROPAGATION('testqueue');
CREATE OR REPLACE PROCEDURE MONITOR_STATUS_QUEUE(time IN NUMBER)
IS
pragma autonomous_transaction;
agent_w_message sys.aq$_agent;
agent_list dbms_aq.aq$_agent_list_t;
wait_time INTEGER := 10;
no_message EXCEPTION;
pragma EXCEPTION_INIT(no_message, -25254);
new_status VARCHAR2(30);
monitor BOOLEAN := TRUE;
begin_time number;
end_time number;
v_dequeue_options dbms_aq.dequeue_options_t;
v_message_properties dbms_aq.message_properties_t;
v_message_type message_type;
v_dequeue_msg_id RAW(40);
v_xml_message CLOB;
v_message_text varchar2(2000);
v_amount number;
BEGIN
begin_time := dbms_utility.get_time;
WHILE (monitor)
LOOP
BEGIN
-- agent_list(1) := sys.aq$_agent('testqueue_agent', 'testqueue', NULL);
agent_list(1) := sys.aq$_agent('agent1', 'testqueue', NULL);
/* wait for order status messages */
dbms_aq.listen(agent_list, 0, agent_w_message);
dbms_output.put_line('Agent' || agent_w_message.name || ' Address '|| agent_w_message.address);
/* dequeue the message from the queue */
v_dequeue_options.consumer_name := 'testqueue_subscriber';
v_dequeue_options.wait := 0.5;
-- v_dequeue_options.wait := dbms_aq.NO_WAIT;
dbms_aq.dequeue('testqueue',v_dequeue_options, v_message_properties,
v_message_type,v_dequeue_msg_id);
v_amount := dbms_lob.getlength(v_message_type.xml_message);
dbms_lob.read(v_message_type.xml_message,v_amount,1,v_message_text);
dbms_output.put_line('New Message :'||v_message_text);
/* exit if we have been working long enough */
end_time := dbms_utility.get_time;
IF (end_time - begin_time > time) THEN
EXIT;
END IF;
EXCEPTION
WHEN no_message THEN
dbms_output.put_line('No messages so far');
end_time := dbms_utility.get_time;
--exit if we have done enough work
IF (end_time - begin_time > time) THEN
EXIT;
END IF;
END;
END LOOP;
commit;
END;
create or replace procedure enqueue is
v_enqueue_options dbms_aq.enqueue_options_t;
v_messages_properties dbms_aq.message_properties_t;
v_message_type message_type;
v_message_locator CLOB;
v_enqueue_msg_id RAW(40);
v_select_sql varchar2(2000);
v_xml_message varchar2(2000);
v_temp_clob CLOB;
begin
v_xml_message := '<TESTING><TEST>'||to_char(sysdate,'HH:MI:SS')||'</TEST></TESTING>';
dbms_lob.createtemporary(v_temp_clob,true);
dbms_lob.write(v_temp_clob,length(v_xml_message),1,v_xml_message);
v_message_type := message_type(empty_clob());
dbms_aq.enqueue(
queue_name => 'testqueue',
enqueue_options => v_enqueue_options,
message_properties => v_messages_properties,
payload => v_message_type,
msgid => v_enqueue_msg_id);
v_select_sql := ' select t.user_data.xml_message from testqueue_qtable t where t.msgid = :MSG_ID';
execute immediate v_select_sql INTO v_message_locator using v_enqueue_msg_id;
dbms_lob.copy( dest_lob => v_message_locator,
src_lob => v_temp_clob,
amount => dbms_lob.getlength(v_temp_clob));
COMMIT;
end enqueue;

Answer 1

Hi,
Your subscriber is called testqueue_subscriber. You must use the same consumer name in the agent list for dbms_aq.listen
Change
agent_list(1) := sys.aq$_agent('agent1', 'testqueue', NULL);
to
agent_list(1) := sys.aq$_agent('testqueue_subscriber', 'testqueue', NULL);