Question regarding security of "applets"

Question

As a novice "apple scripter", (since 2012) I was wondering if anyone knows how good the security is for an applet saved as "run only" I have read that one would need a decompiler, to penetrate security but the  writer said he had never seen one!
The reason is that I have recently written a script that actually works! and it is a encryption tool to encrypt r.t.f.documents  in "text edit" and of course another to decrypt. (with a password dialog box). figured this would be useful for storing all sensitive info on my computer and in e-mails etc, so security is important to it's function.

Answer 1

If you want to encrypt, why not use openssl?  It's already in OS X.
Here's an Applescript wrapper to openssl-aes I wrote a few years ago:
Encrypt:
on run
          set f to choose file with prompt "Select file to encrypt:" default location alias (the path to desktop folder as text)
          my proceed_(f)
end run
on open f
          if (count of f) is not equal to 1 then
                    display dialog ("More than 1 file was selected") with icon stop buttons {"Cancel"} default button 1 with title "openssl aes-256"
          else
                    my proceed_(f)
          end if
end open
on proceed_(f)
          tell application "System Events" to set finfo to the properties of (f as alias)
          if kind of finfo is "Folder" then
                    display dialog (name of finfo & " is a Folder") with icon stop buttons {"Cancel"} default button 1 with title "openssl aes-256"
          else if kind of finfo is "Alias" then
                    display dialog (name of finfo & " is a an Alias") with icon stop buttons {"Cancel"} default button 1 with title "openssl aes-256"
          end if
          set pass1 to text returned of (display dialog "Please enter your password" default answer "" with title "openssl aes-256" with hidden answer)
          set pass2 to text returned of (display dialog "Please verify your password" default answer "" with title "openssl aes-256" with hidden answer)
          if pass1 is not equal to pass2 then
                    display dialog "Passwords do not match!" with icon stop buttons {"Cancel"} default button 1 with title "openssl aes-256"
          end if
          set encryptedFile to (f as string) & ".aes"
          tell application "Finder"
                    if exists encryptedFile then
                              set answer to the button returned of (display dialog (name of finfo & ".aes exists. Overwrite?") with icon caution buttons {"Yes", "No"} default button 2 with title "openssl aes-256")
                              if answer is "No" then
                                        error number -128 --> Cancel the script
                              end if
                    end if
          end tell
  -- encrypt:
          do shell script "/usr/bin/openssl aes-256-cbc -salt -in " & quoted form of POSIX path of f & " -out " & quoted form of POSIX path of f & ".aes" & " -k " & quoted form of pass1
  activate me
          set answer to the button returned of (display dialog ("Encryted File: " & name of finfo & ".aes" & return & return & "Secure Delete " & name of finfo & "?") buttons {"Yes", "No"} default button 2 with title "openssl aes-256")
          if answer is "Yes" then
                    do shell script "/usr/bin/srm -z " & quoted form of POSIX path of f
  activate me
                    display dialog name of finfo & " deleted" buttons {"Done"} default button 1 with title "openssl aes-256"
          end if
end proceed_
Decrypt:
on run
          set f to choose file of type "aes" with prompt "Select AES file to decrypt:" default location alias (the path to desktop folder as text)
          my proceed_(f)
end run
on open f
          if (count of f) is not equal to 1 then
                    display dialog ("More than 1 file was selected") with icon stop buttons {"Cancel"} default button 1 with title "openssl aes-256"
          else
                    my proceed_(f)
          end if
end open
on proceed_(f)
          tell application "System Events" to set finfo to the properties of (f as alias)
          if kind of finfo is "Folder" then
                    display dialog (name of finfo & " is a Folder") with icon stop buttons {"Cancel"} default button 1 with title "openssl aes-256"
          else if kind of finfo is "Alias" then
                    display dialog (name of finfo & " is a an Alias") with icon stop buttons {"Cancel"} default button 1 with title "openssl aes-256"
          else if type identifier of finfo is not "dyn.age80c3px" then
                    display dialog (name of finfo & " is not an AES Encrypted File") buttons {"Cancel"} with icon stop default button 1 with title "openssl aes-256"
          end if
          set pass1 to text returned of (display dialog "Please enter your password" default answer "" with title "openssl aes-256" with hidden answer)
          set encryptedFile to f as string
          set theReversedFileName to (reverse of (characters of encryptedFile)) as string
          set theOffset to offset of "." in theReversedFileName
          set decryptedFile to (reverse of (characters (theOffset + 1) thru -1 of theReversedFileName)) as string
          set decryptedFileBaseName to do shell script "/usr/bin/basename " & quoted form of POSIX path of decryptedFile
          tell application "Finder"
                    if exists decryptedFile then
                              set answer to the button returned of (display dialog (decryptedFileBaseName & " exists. Overwrite?") with icon caution buttons {"Yes", "No"} default button 2 with title "openssl aes-256")
                              if answer is "No" then
                                        error number -128 --> Cancel the script
                              end if
                    end if
          end tell
  -- decrypt:
          try
                    do shell script "/usr/bin/openssl aes-256-cbc -d -salt -in " & quoted form of POSIX path of encryptedFile & " -out " & quoted form of POSIX path of decryptedFile & " -k " & quoted form of pass1
          on error m number n
                    try
                              do shell script "/bin/rm " & quoted form of POSIX path of decryptedFile
                    end try
  activate me
                    display dialog "Bad decrypt." & return & "Possible incorrect password." & return & return & "Deleting output file " & decryptedFileBaseName & " (if it exists)." with icon stop buttons {"Done"} default button 1 with title "openssl aes-256"
                    error number -128 --> Cancel the script
          end try
  activate me
          display dialog name of finfo & " decrypted" buttons {"Done"} default button 1 with title "openssl aes-256"
end proceed_