Question related with loop exception

Question

Hello
I got 4 database , i am using dblinks to check some tables and write the results to one table. I created also  one table to hold instance names so my loop check it and execute my procedure.
declare
  sql_string1   VARCHAR2(4000);
  sql_string2   VARCHAR2(100);
begin
sql_string2:='truncate table  Backup';
execute immediate sql_string2;
   for r in (select INSTANCE_NAME,HOST_NAME from del)
   loop
sql_string1:= 'insert into Backup 
SELECT '''||r.HOST_NAME||'''  '||', '''||r.INSTANCE_NAME||'''  '||' ,
INPUT_TYPE,STATUS,START_TIME,END_TIME FROM V$RMAN_BACKUP_JOB_DETAILS@'||r.INSTANCE_NAME;
          execute immediate sql_string1;
       COMMIT;
   end loop;
   exception
  WHEN OTHERS THEN
    NULL;
end;
If all listeners are working or dbs are working this procedure work without any problem but if one of them is closed it is just insert the values until it gets error but i want that if it gets error to goes other value.How can i do that?
I changed values of del table
SYS@crofxd01:WSTORED: >select instance_name from del;
INSTANCE_NAM
BLABLA
BLABLA
BLABLA
BLABLA
FPT
only FPT is real instance after i execute procedure , i wanna see that FPT values inserted to db.
Thanks

Answer 1

Hi,
When control passes to an EXCEPTION section, it can not return to the block where the error occurred.  If you want to continue execution, the code to be executed after the exception is handled must be in a separate block.
Use a nested BEGIN block, like this:
declare
    sql_string1   VARCHAR2(4000);
    sql_string2   VARCHAR2(100);
    err_code   NUMBER;
begin
    sql_string2 := 'truncate table  Backup';
    execute immediate sql_string2;
    for r in (select INSTANCE_NAME,HOST_NAME from del)
    loop
        sql_string1 := 'insert into Backup 
                        SELECT ''' || r.HOST_NAME || '''  , ''' || r.INSTANCE_NAME ||
                        '''   , INPUT_TYPE,STATUS,START_TIME,END_TIME FROM V$RMAN_BACKUP_JOB_DETAILS@' ||
                        r.INSTANCE_NAME;
        BEGIN
              execute immediate sql_string1;
        EXCEPTION
            WHEN OTHERS THEN
                err_code := SQLCODE;
                IF  err_code  IN (-1234, -1236, ...) -- Find out actual numbers
                THEN
                    NULL;
                ELSE
                    RAISE;
        END;
       COMMIT;
   end loop;
end;
"EXCEPTION WHEN OTHERS THEN NULL" is usually a terrible idea.  Find out exactly what error codes will be generated for the routine problems that you want to ignore (I just made up numbers -1234 and -1236 above) and test specifically for them.