Quick & dirty OO ALV, supress info icon on toolbar, how

Question

Hello all,
This is an example of a program template I use to create quick ALVs.
I create a selection-screen 1001 and display the ALV grid on that screen.  I use this technique when my users just want to display data.  When the ALV is presented on screen 1001, clicking on the back, exit, or cancel buttons on the application toolbar exits the program.  Now I have been asked to go to screen 1000 (standard selection-screen) when exiting the ALV.
How can I back out to selection-screen 1000, versus leaving the program?
Thanks
Bruce
include rsdbc1xx.      " selection screen stuff
parameters: p_nuthin(20) default 'Does nothing' lower case.
selection-screen begin of screen 1001.
selection-screen end of screen 1001.
data: w_alv      type ref to   cl_gui_alv_grid,      " ALV grid
      i_t001 type table of t001.                 " ALV data table
data: w_lvc_s_layo type lvc_s_layo.                  " ALV layout
* Global table of function codes to disable
data: lt_exclude type ui_functions.   " itab
data ls_exclude  type ui_func.        " structure
*>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
* events at selection-screen output.
*>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
at selection-screen output.
  if sy-dynnr = '1001'.
    current_scr-mode = 'S'.
*                                        disable functions:
    append 'SPOS' to current_scr-excl.
    append 'SCRH' to current_scr-excl.
    append 'ONLI' to current_scr-excl.    "Online execution
*  append 'PRIN' to current_scr-excl.   "Execute and print
  endif.
*>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
start-of-selection.
*>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
  select * from t001 into table i_t001.
* Creation of the ALV object, when we use cl_gui_container=>screen0
* as parent, the ALVGrid control will automatically use the
* full screen to display the grid, NO CONTAINER DEFINITION IS REQUIRED !
  create object w_alv exporting i_parent = cl_gui_container=>screen0.
  w_lvc_s_layo-grid_title =
       'Grid title - 60 characters maximum'.
  data: w_is_variant type disvariant.
  w_is_variant-report = sy-cprog.
  call method w_alv->set_table_for_first_display
    exporting
      i_structure_name     = 'T001'
      is_layout            = w_lvc_s_layo
      it_toolbar_excluding = lt_exclude
      is_variant           = w_is_variant
      i_save               = 'A'
    changing
      it_outtab            = i_t001.
  call selection-screen 1001.

Answer 1

Since you are creating the ALV on the Selection-screen, you would not have better control. But, you can try to remove the standard button BACK button and replace it with Selection button. Handle this button and LEAVE TO Transaction or SUBMIT to program.
include rsdbc1xx.      " selection screen stuff
* ADD
TYPE-POOLS icon.
TABLES sscrfields.
DATA functxt TYPE smp_dyntxt.
parameters: p_nuthin(20) default 'Does nothing' lower case.
selection-screen begin of screen 1001.
SELECTION-SCREEN: FUNCTION KEY 1,   " ADD
                  FUNCTION KEY 2.   " ADD
selection-screen end of screen 1001.
data: w_alv      type ref to   cl_gui_alv_grid,      " ALV grid
      i_t001 type table of t001.                 " ALV data table
data: w_lvc_s_layo type lvc_s_layo.                  " ALV layout
* Global table of function codes to disable
data: lt_exclude type ui_functions.   " itab
data ls_exclude  type ui_func.        " structure
*>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
* events at selection-screen output.
*>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
INITIALIZATION.
load-OF-PROGRAM.
at selection-screen output.
  if sy-dynnr = '1001'.
    current_scr-mode = 'S'.
*                                        disable functions:
    append 'SPOS' to current_scr-excl.
    append 'SCRH' to current_scr-excl.
    append 'ONLI' to current_scr-excl.    "Online execution
    append 'E' to current_scr-excl.     "ADD - Back
*  append 'PRIN' to current_scr-excl.   "Execute and print
* ADD
    functxt-icon_id   = ICON_SYSTEM_BACK.
    functxt-quickinfo = 'Back'.
    sscrfields-functxt_01 = functxt.
  endif.
* ADD
AT SELECTION-SCREEN.
  CASE sscrfields-ucomm.
    when 'FC01'.
*      leave to TRANSACTION.
      SUBMIT ztest_np VIA SELECTION-SCREEN.
  ENDCASE.
*>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
start-of-selection.
*>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
  select * from t001 into table i_t001.
* Creation of the ALV object, when we use cl_gui_container=>screen0
* as parent, the ALVGrid control will automatically use the
* full screen to display the grid, NO CONTAINER DEFINITION IS REQUIRED !
  create object w_alv exporting i_parent = cl_gui_container=>screen0.
  w_lvc_s_layo-grid_title =
       'Grid title - 60 characters maximum'.
  data: w_is_variant type disvariant.
  w_is_variant-report = sy-cprog.
  call method w_alv->set_table_for_first_display
    exporting
      i_structure_name     = 'T001'
      is_layout            = w_lvc_s_layo
      it_toolbar_excluding = lt_exclude
      is_variant           = w_is_variant
      i_save               = 'A'
    changing
      it_outtab            = i_t001.
  call selection-screen 1001.
Alternatively, you can use the selection screen 1000 and generate the ALV on top of that. Check the example, [Display ALV report output in the SAME Selection Screen|http://help-abap.blogspot.com/2008/10/dispaly-alv-report-output-in-same.html]. This example uses the SALV, but you can very well use the ALV grid for the same purpose. In this case, you don't have to worry about the Std buttons at all!
Regards,
Naimesh Patel