Registered callback does not dequeue messages in order

Question

PROCEDURE notifycb(
CONTEXT IN RAW,
reginfo IN SYS.aq$_reg_info,
descr IN SYS.aq$_descriptor,
payload IN RAW,
payloadl IN NUMBER )
AS
no_messages EXCEPTION;
PRAGMA exception_init( no_messages, -25228 );
dequeue_options dbms_aq.dequeue_options_t;
message_properties dbms_aq.message_properties_t;
msgid RAW( 16 );
message XMLTYPE;
BEGIN
dequeue_options.consumer_name := descr.consumer_name;
dequeue_options.msgid := descr.msg_id;
dbms_aq.dequeue(
descr.queue_name,
dequeue_options, message_properties,
message, msgid );
INSERT INTO xmltest
( create_ts, enqueue_time, xml )
VALUES
( systimestamp, message_properties.enqueue_time, message );
EXCEPTION
WHEN no_messages
THEN NULL;
END;
BEGIN
dbms_aq.REGISTER(
SYS.aq$_reg_info_list(
SYS.aq$_reg_info(
'Q_TEST:QUEUE_SUBSCRIBER',
dbms_aq.namespace_aq,
'plsql://QUEUE_OWNER.NOTIFYCB?PR=1',
HEXTORAW( 'FF' )
, 1 );
END;
DECLARE
v_enqueue_options dbms_aq.enqueue_options_t;
v_message_properties dbms_aq.message_properties_t;
v_message_handle RAW( 16 );
xml XMLTYPE;
BEGIN
FOR x IN 1 .. 10 LOOP
SELECT XMLELEMENT( "x", x ) INTO xml FROM dual;
dbms_aq.enqueue(
queue_name => 'QUEUE_OWNER.Q_TEST',
enqueue_options => v_enqueue_options,
message_properties => v_message_properties,
payload => xml,
msgid => v_message_handle );
END LOOP;
COMMIT;
END;
select * from xmltest
order by create_ts;
16-JUN-08 04.04.27.065311000 PM 06/16/2008 08:04:20 PM <x>4</x>
16-JUN-08 04.04.27.078027000 PM 06/16/2008 08:04:20 PM <x>3</x>
16-JUN-08 04.04.27.155730000 PM 06/16/2008 08:04:20 PM <x>5</x>
16-JUN-08 04.04.27.268137000 PM 06/16/2008 08:04:20 PM <x>6</x>
16-JUN-08 04.04.27.357706000 PM 06/16/2008 08:04:20 PM <x>7</x>
16-JUN-08 04.04.27.479633000 PM 06/16/2008 08:04:20 PM <x>8</x>
16-JUN-08 04.04.27.577086000 PM 06/16/2008 08:04:20 PM <x>9</x>
16-JUN-08 04.04.27.612511000 PM 06/16/2008 08:04:20 PM <x>10</x>
16-JUN-08 04.04.27.979631000 PM 06/16/2008 08:04:20 PM <x>2</x>
16-JUN-08 04.04.28.084615000 PM 06/16/2008 08:04:20 PM <x>1</x>

Answer 1

The solution I found is to use a loop to dequeue messages in order, rather than by the supplied msgid, and to use DBMS_LOCK to prevent the callbacks from processing messages in parallel.
create or replace PROCEDURE notifycb(
context IN RAW,
reginfo IN SYS.aq$_reg_info,
descr IN SYS.aq$_descriptor,
payload IN RAW,
payloadl IN NUMBER )
AS
no_messages EXCEPTION;
PRAGMA exception_init( no_messages, -25228 );
dequeue_options dbms_aq.dequeue_options_t;
message_properties dbms_aq.message_properties_t;
msgid RAW( 16 );
message XMLTYPE;
lockhandle VARCHAR2(128) := NULL;
lockstatus NUMBER;
BEGIN
dequeue_options.consumer_name := descr.consumer_name;
dequeue_options.wait := dbms_aq.no_wait;
dbms_lock.allocate_unique( 'NOTIFYCB_LOCK', lockhandle );
lockstatus := dbms_lock.request( lockhandle, DBMS_LOCK.X_MODE, release_on_commit => TRUE );
IF lockstatus != 0 AND lockstatus != 4
THEN
RETURN;
END IF;
BEGIN
LOOP
dbms_aq.dequeue(
descr.queue_name,
dequeue_options, message_properties,
message, msgid );
INSERT INTO xmltest
( create_ts, enqueue_time, xml )
VALUES
( systimestamp, message_properties.enqueue_time, message );
END LOOP;
EXCEPTION
WHEN no_messages
THEN NULL;
END;
COMMIT;
END;