Repetitive information in db fields

Question

I've been using AW6 db for several years. On my forms I insert some of the same information in certian fields, like a name of a business, name, address and/or account nr.
I would like to save some time by being able to put the 1st two letters or numbers in the field and let AW fill in the rest of the field. Like "autofill". I can't recall how to do that.
On an old (Helix) database I once used, I know somehow a list had to be made, but that's as far as I get. Any advise?

Answer 1

Hello
This script may help:
--[SCRIPT item2use]
(* Yvan Koenig
13 février 2007 *)
property english : true (*
false = français, true = english *)
property msg0 : ""
property msg2 : ""
property msg3 : ""
property msg4 : ""
property msg99 : ""
(* adjust this property to fit your needs *)
property myItems : {"item1", "item2", "item3"} & ¬
{"item4", "item5", "item6"} & ¬
{"item7", "item8", "item9"}
on run
if msg0 is "" then my prepareMessages()
try
tell application "AppleWorks 6"
activate
if ("6." is not in (version as text)) then ¬
error msg0 number 8000
if (count each document) = 0 then ¬
error msg2 number 8002
if (document kind of document 1 is not database document) then ¬
error msg3 number 8003
set ma_Base to (file of document 1) as text
select document 1
tell document 1
if ((count records) = 0) then ¬
error msg4 number 8004
try
set verif to (class of selection) as text
on error
set verif to ""
end try
if (verif is not "field") and (verif is not "«class cFld»") then ¬
error msg5 number 8005 (*
Vous n'avez pas sélectionné une rubrique à analyser.
refuse la sélection d'une fiche entière.
• You didn't select a single field to work with.
cancel if the selection is a record. *)
set myItem to choose from list myItems
if myItem is not false then
set the clipboard to myItem's item 1
paste
end if
end tell -- to document 1
end tell -- AppleWorks
on error MsgErr number NroErr
if NroErr is not -128 then
beep 2
tell application (path to frontmost application as string) to ¬
display dialog "" & NroErr & " : " & MsgErr with icon 0 ¬
buttons {msg99} giving up after 20
end if
return
end try --(2)
end run
-- -+-+-+-+- Routines
on prepareMessages()
if english is true then
set msg0 to "This script is not compatible" & return & ¬
"with this version of AppleWorks." & return & ¬
"Please use version 6.x ..."
set msg2 to "No open doc"
set msg3 to "This document is not a database."
set msg4 to "Can't launch this script" & return & ¬
"on an empty DB ..."
set msg5 to "You didn't select" & return & ¬
"a field to work with."
set msg99 to " Oops "
else
set msg0 to "Ce script n'est pas compatible" & return & ¬
"avec cette version d‘AppleWorks." & return & ¬
"Veuillez utiliser une version 6.x …"
set msg2 to "Aucun document ouvert"
set msg3 to "Ce document n'est pas une base de données."
set msg4 to "Impossible de lancer ce script" & return & ¬
"sur une base vide..."
set msg5 to "Vous n'avez pas sélectionné" & return & ¬
"de rubrique à analyser."
set msg99 to " Vu "
end if -- french
end prepareMessages
--[/SCRIPT]
Yvan KOENIG (from FRANCE mardi 13 février 2007 19:06:52)