Request against is running?

Question

Hi,
I am using the following SQL to determine whether a program is runniing or not:
  select  count(*)
  into    l_Cnt
  from    FND_Concurrent_Programs     fcp
         ,FND_Concurrent_Requests     fcr
  where   fcp.Application_ID          = 20003
  and     fcr.Concurrent_Program_ID   = fcp.Concurrent_Program_ID
  and     fcr.Argument1               = cp_sob_id
  and     fcr.Phase_Code              in ('R', 'P') -- 'P' refers to "PENDING" and 'R' to "RUNNING"
  and     fcp.Concurrent_Program_Name = 'GLLEZL' ;How can I determine if a request set is running or not?

Answer 1

thx for the help Hussein,
I have a much more complex problem now, and I'm hoping you can shed some light on the matter!!
I think the SQL that I need is something like this:
select  count(*)
  into    l_Cnt
  from    FND_Run_Requests            frr
         ,FND_Concurrent_Requests     fcr
         ,fnd_request_sets            frs
  where   frs.request_set_name        ='RBSGLIMPJNLSSOB'
  and     frs.Request_Set_ID          = fcr.Request_Set_ID
  and     frr.Parent_Request_ID       = fcr.Parent_Request_ID
  and     fcr.Argument1               = cp_sob_id
  and     fcr.Phase_Code              in ('R', 'P')However, the request set, which I created using the code in Appendix A below, is made up of two spawned programs, GLLEZL & GLPPOS, both of which require the "Set of Books ID" (SOB ID) as a parameter. GLLEZL takes SOB ID as the 2nd argument whilst GLPPOS takes SOB ID as the 1st argument.
I am aware one can setup a shared parameter within a request set using the following built in proc;
fnd_set.program_parameter (program                in varchar2
                          ,program_application    in varchar2
                          ,request_set            in varchar2
                          ,set_application        in varchar2
                          ,stage                  in varchar2
                          ,program_sequence       in number
                          ,parameter              in varchar2
                          ,display                in varchar2 default 'y'
                          ,modify                 in varchar2 default 'y'
                          ,shared_parameter       in varchar2 default null
                          ,default_type           in varchar2 default null
                          ,default_value          in varchar2 default null);
The questions I have are;
1. How will the SQL above change if I create two such shared parameters? Bear in mind I would like to check if a request set is running against a specific SOB ID
2. How will the two calls to FND_SUBMIT.SIBMIT_PROGRAM, listed in APPENDIX B, change if I introduce a shared parameter ?
3. I do not fully understand the following Oracle documentation on FND_SUBMIT.PROGRAM_PARAMETER
>
This procedure registers shared parameter information and
the request set level overrides of program parameter
attributes.
>
I realise that I have posted a lot of code, and I hope it does not seem too overwhelming. The purpose of what of I am attempting is to run the import/post from the backend in parallel per each SOB ID, hence I have created a request set.
Any help would be much appreciated!
P;
APPENDIX A
set serveroutput on
declare
  l_App                 varchar2(10) := 'SQLGL';
  l_Req_Set_Name        varchar2(20) := 'RBSGL_AUTO_IMP_POST';
  l_Req_Set_Short_Name  varchar2(20) := 'RBSGL_AUTO_IP';
  l_Imp_Prg             varchar2(20) := 'GLLEZL';
  l_Post_Prg            varchar2(20) := 'GLPPOS';
  l_Continue            boolean := true;
begin
  dbms_output.put_line('----------------------------------------------------------------------- ');
  -- CREATE SET FIRST
  begin
    fnd_set.delete_set(request_set => l_Req_Set_Short_Name
                      ,application => l_App);
    dbms_output.put_line(' Request set, ' || l_Req_Set_Name || ', deleted');
    commit;
    exception
      when others then
        dbms_output.put_line(' Request set, ' || l_Req_Set_Name || ', does not exist');
  end;
  begin
    fnd_set.create_set        (name                       => l_Req_Set_Name
                              ,short_name                 => l_Req_Set_Short_Name
                              ,application                => l_App
                              ,description                => 'RBSGL Automatic Import and Posting'
                              ,owner                      => null --
                              ,start_date                 => sysdate
                              ,end_date                   => null
                              ,print_together             => 'N' -- printing specific parameter, which is irrelevant in this context
                              ,incompatibilities_allowed  => 'N'
                              ,language_code              => 'US');
    dbms_output.put_line('Request Set, ' || l_Req_Set_Name || ', created sucessfully ');
    commit;
    exception
      when others then
        l_Continue := false;
        dbms_output.put_line('Request Set, ' || l_Req_Set_Name || ', could not be created; ' || sqlerrm);
  end;
  -- CREATE FIRST STAGE
  dbms_output.put_line('----------------------------------------------------------------------- ');
  if (l_Continue) then
    begin
      fnd_set.remove_stage(request_set      => l_Req_Set_Short_Name
                          ,set_application  => l_App
                          ,stage            => 'STAGE10_IMPORT');
      commit;
      dbms_output.put_line('Stage, STAGE10_IMPORT, removed sucessfully from set, ' || l_Req_Set_Name);
      exception
        when others then
          dbms_output.put_line('Stage, STAGE10_IMPORT, removed sucessfully from set, ' || l_Req_Set_Name);
    end;
    begin
      fnd_set.add_stage         (name                       => 'STAGE10_IMPORT'
                                ,request_set                => l_Req_Set_Short_Name
                                ,set_application            => l_App
                                ,short_name                 => 'STAGE10_IMPORT'
                                ,description                => 'RBSGL Import Stage '
                                ,display_sequence           => 1
                                ,function_short_name        => 'FNDRSSTE' -- This is a standard string that needs to be supplied
                                ,function_application       => 'FND' -- This is a standard string that needs to be supplied
                                ,critical                   => 'Y'
                                ,incompatibilities_allowed  => 'Y'
                                ,start_stage                => 'Y'
                                ,language_code              => 'US');
      dbms_output.put_line('Stage, STAGE10_IMPORT, sucessfully added');
      commit;
      exception
        when others then
          l_Continue := false;
          dbms_output.put_line('Stage, STAGE10_IMPORT, could not be added to request set, ' || sqlerrm);
    end;
  end if;
  if (l_Continue) then
    begin
      fnd_set.add_program       (program                    => l_Imp_Prg
                                ,program_application        => l_App
                                ,request_set                => l_Req_Set_Short_Name
                                ,set_application            => l_App
                                ,stage                      => 'STAGE10_IMPORT'
                                ,program_sequence           => 1
                                ,critical                   => 'Y'
                                ,number_of_copies           => 0
                                ,save_output                => 'Y');
      dbms_output.put_line('Program, ' || l_Imp_Prg || ', added sucessfully to request set, ' || l_Req_Set_Name );
      commit;
      exception
        when others then
          l_Continue := false;
          dbms_output.put_line('Program, ' || l_Imp_Prg || ', could not be added to request set, ' || l_Req_Set_Name || ' ' || sqlerrm );
    end;
  end if;
  -- No need to add parameters, since parameters are defined against the program using fnd_program.add_parameter
  -- Only shared parameters are specified
  -- CREATE SECOND STAGE
  if (l_Continue) then
    dbms_output.put_line('----------------------------------------------------------------------- ');
    begin
      fnd_set.remove_stage(request_set      => l_Req_Set_Short_Name
                          ,set_application  => l_App
                          ,stage            => 'STAGE20_POST');
      commit;
      dbms_output.put_line('Stage, STAGE20_POST, removed sucessfully from request set, ' || l_Req_Set_Name);
      exception
        when others then
          dbms_output.put_line('Stage, STAGE20_POST, removed sucessfully from request set, ' || l_Req_Set_Name);
    end;
    begin
      fnd_set.add_stage         (name                       => 'STAGE20_POST'
                                ,request_set                => l_Req_Set_Short_Name
                                ,set_application            => l_App
                                ,short_name                 => 'STAGE20_POST'
                                ,description                => 'RBSGL Post Stage '
                                ,display_sequence           => 2
                                ,function_short_name        => 'FNDRSSTE' -- This is a standard string that needs to be supplied
                                ,function_application       => 'FND' -- This is a standard string that needs to be supplied
                                ,critical                   => 'Y'
                                ,incompatibilities_allowed  => 'Y'
                                ,start_stage                => 'Y'
                                ,language_code              => 'US');
      commit;
      dbms_output.put_line('Stage, STAGE20_POST, sucessfully added');
      exception
        when others then
          l_Continue := false;
          dbms_output.put_line('Stage, STAGE20_POST, could not be added to request set, ' || sqlerrm);
    end;
  end if;
  if (l_Continue) then
    begin
      fnd_set.add_program       (program                    => l_Post_Prg
                                ,program_application        => l_App
                                ,request_set                => l_Req_Set_Short_Name
                                ,set_application            => l_App
                                ,stage                      => 'STAGE20_POST'
                                ,program_sequence           => 2
                                ,critical                   => 'N'
                                ,number_of_copies           => 0
                                ,save_output                => 'Y');
      commit;
      dbms_output.put_line('Program, ' || l_Post_Prg || ', added sucessfully to request set, ' || l_Req_Set_Name );
      exception
        when others then
          dbms_output.put_line('Program, ' || l_Post_Prg || ', could not be added to request set, ' || l_Req_Set_Name || ' ' || sqlerrm );
          l_Continue := false;
    end;
  end if;
  if (l_Continue) then
    dbms_output.put_line('----------------------------------------------------------------------- ');
    begin
      fnd_set.link_stages(request_set                     => l_Req_Set_Short_Name
                         ,set_application                 => l_App
                         ,from_stage                      => 'STAGE10_IMPORT'
                         ,to_stage                        => 'STAGE20_POST'
                         ,success                         => 'Y'
                         ,warning                         => 'Y');
      commit;
      dbms_output.put_line('Stages for requested set, ' || l_Req_Set_Name || ', linked sucessfully');
      exception
        when others then
          dbms_output.put_line('Stages for requested set, ' || l_Req_Set_Name || ', could not be linked. ' || sqlerrm );
    end;
  end if;
  if (l_Continue) then
    dbms_output.put_line('----------------------------------------------------------------------- ');
    begin
      fnd_set.remove_set_from_group(l_Req_Set_Short_Name, l_App, 'GL Concurrent Program Group', l_App);
      dbms_output.put_line('Request set, ' || l_Req_Set_Name || ' removed from group "GL Concurrent_Group" in ' || l_App);
      commit;
      exception
        when others then
          dbms_output.put_line('Request set, ' || l_Req_Set_Name || ' does not exist within group "GL Concurrent_Group" in ' || l_App);
    end;
    begin
      fnd_set.add_set_to_group(l_Req_Set_Short_Name
                             , l_App
                             , 'GL Concurrent Program Group' -- Request Group Name
                             , l_App); -- Report Group Application
      commit;
      dbms_output.put_line('Request set, ' || l_Req_Set_Name || ' sucessfully added to group "GL Concurrent_Group" in ' || l_App);
      exception
        when others then
          l_Continue := false;
          dbms_output.put_line('Request set, '|| l_Req_Set_Name || ', could not be added to group "GL Concurrent_Group", ' || sqlerrm );
    end;
  end if;
  dbms_output.put_line('----------------------------------------------------------------------- ');
  if (l_Continue) then
    dbms_output.put_line('Set Created sucessfully ');
  else
    dbms_output.put_line('Set was not created sucessfully ');
  end if;
  exception
    when others then
      dbms_output.put_line('Unknown error: ' || sqlerrm);
end;
APPENDIX B
drop type tb_gli
create or replace type ty_gli as object
(SOB_id           number
,Group_ID         number
,Source_Name      varchar2(25)
,Interface_Run_ID number
,Autopost_ID      number
,Req_Set_ID       number
,Error_Msg        varchar2(200))
create or replace type tb_gli as table of ty_gli
-- Extract of code, not full listing!
  update GL_Interface gli
  set    gli.Group_ID  =  Gl_Interface_Control_S.nextval
  where  nvl(gli.Currency_Conversion_Date, gli.Accounting_Date) <= l_Max_Rate_Date
  and    gli.Set_of_Books_ID                                     = v_Set_Of_Books_ID
  returning ty_GLI (gli.Set_Of_Books_ID
                   ,gli.Group_ID
                   ,gli.User_JE_Source_Name
                   ,pkg_GL_Imp_Post.Get_Interface_Run_ID -- function defined within pkg above
                   ,pkg_GL_Imp_Post.Get_Autopost_ID(gli.User_JE_Source_Name) -- function defined within pkg above
                   ,0 -- request ID
                   ,null)
  bulk collect into l_GLI_Tab;
  insert into GL_Interface_Control ( Status
                                    ,JE_Source_Name
                                    ,Group_ID
                                    ,Set_Of_Books_ID
                                    ,Interface_Run_ID)
                         (select    'S' -- no need for an index hint, since data is now in memory
                                    ,gli.Source_Name
                                    ,gli.Group_ID
                                    ,gli.SOB_ID
                                    ,gli.Interface_Run_ID -- obtained from the function pkg_GL_Imp_Post.Get_Interface_Run_ID during the update
                          from       table(l_GLI_Tab) gli);
  r_ISet := Get_Init_Set(v_User, v_Resp);
  fnd_global.apps_initialize(r_ISet.n_User_ID, r_ISet.n_Resp_ID, r_ISet.n_App_ID);
  dbms_session.set_nls(param => 'nls_language'
                      ,value => v_Language);
  -- (1)
  b_Set_NLS := fnd_submit.set_nls_options(v_Language);
  b_Set_Mode := fnd_submit.set_mode (false); -- (2)
-- (3) submit a request against the set
  b_Req_Set := fnd_submit.set_request_set (v_App_Name, v_Set_Code);
  if (b_Req_Set) and (b_Set_Mode) then
    for i in 1..l_GLI_Tab.count loop
     -- submit each stage/prg individually
      b_Run_Stg_Prg := fnd_submit.submit_program(v_App_Name
                                                ,v_Stage1_P1 -- "GLLEZL"
                                                ,v_Stage1_Code
                                                ,l_GLI_Tab(i).Interface_Run_ID
                                                ,l_GLI_Tab(i).SOB_ID
                                                ,'N'
                                                ,null
                                                ,null
                                                ,'N'
                                                ,'O');
      -- Determine if the submission of the program was sucessful
      if (not b_Run_Stg_Prg) then
        v_Stg_Prg := v_Stage1_P1;
        raise SET_PRG_EXC;
      end if;
      b_Run_Stg_Prg := fnd_submit.submit_program(v_App_Name
                                                ,v_Stage2_P1  -- "GLPPOS"
                                                ,v_Stage2_Code
                                                ,l_GLI_Tab(i).SOB_ID
                                                ,l_GLI_Tab(i).Autopost_ID);
      -- Determine if the submission of the program was sucessful
      if (not b_Run_Stg_Prg) then
        v_Stg_Prg := v_Stage2_P1;
        raise SET_PRG_EXC;
      end if;
      -- Now the Set can be submitted
      n_Submit_Set := fnd_submit.submit_set;
      l_GLI_Tab(i).Req_Set_ID := n_Submit_Set; -- Update the iteration with
    end loop;
  else
    v_Stg_Prg := 'SET_REQUEST_EXC';
    raise SET_PRG_EXC;
  end if;
  -- check further using the WAIT_FOR_REQUEST, code not included!Edited by: bluefrog on Feb 3, 2010 10:21 AM