Script to export Rating to external xmp sidecar

Question

Hi all,
I did this quick script to be able to update Ratings on referenced and online master files. It uses exiftool, so that should be installed. Also, it creates an empty xmp file if none exists, with only the rating in it, or it updates an already existing one with the rating. Aperture 3 doesn't export this by itself.
let me know if it works for you, it comes with no guarantee to work or do anything useful. careful with the line breaks, posting here chops things up a little sometimes.
cheers,
j
--script to create sidecar xmp files for referenced files without having to export masters. parts of the script (finding the file name) are by brett gross
--this script needs exiftool to work. http://www.sno.phy.queensu.ca/~phil/exiftool/ to get it
--it should create an empty xmp file with the aperture's rating, or update an already existing xmp file in place
property p_sql : "/usr/bin/sqlite3 "
property p_exiftool : "usr/bin/exiftool "
global g_libPath
on run
my getLibPath()
--counter for processed images, reset, just in case
set mastercount to 0
tell application "Aperture"
-- rule out any versions other than 3 of aperture, the database has a different structure
set ap_version to version as rich text
if the first character of ap_version is not "3" then
display dialog "This will only work with Aperture 3" buttons {"OK"} default button 1
return
end if
--get selected images
if not (exists selection) then
display dialog "You have to select at least one image" buttons {"OK"} default button 1
return
else
display dialog "You have selected " & (count of selection) & " images." & return & "Continue?" default button 1
end if
set theSel to selection
--run through the selected images
repeat with currentpic from 1 to count of theSel
tell item currentpic of theSel
-- only apply to referenced and online images
if referenced and online then
set mastercount to mastercount + 1
set curID to id
--use sqlite directly to get master file id of version id
--get master file id from version id
set theScript to p_sql & (quoted form of g_libPath) & " \"select masterUuid from RKVersion where uuid='" & curID & "'\""
set masterfileuid to do shell script theScript
--get master path name from master id
set theScript to p_sql & (quoted form of g_libPath) & " \"select imagePath from RKMaster where uuid='" & masterfileuid & "'\""
set imagepath to do shell script theScript
--get volume id from master id
set theScript to p_sql & (quoted form of g_libPath) & " \"select fileVolumeUuid from RKMaster where uuid='" & masterfileuid & "'\""
set volumeuid to do shell script theScript
--get volume name from volume id
set theScript to p_sql & (quoted form of g_libPath) & " \"select name from RKVolume where uuid='" & volumeuid & "'\""
--put them together
set volumename to do shell script theScript
--strips extension, seems to work for files and paths with more than one period
set oldlim to AppleScript's text item delimiters
set AppleScript's text item delimiters to "."
try --remove last extension only
set contador to text item -1 of imagepath
set noExtension to Unicode text 1 thru -((count of contador) + 2) of imagepath
on error --handle files with no extensions
set noExtension to imagepath
end try
set AppleScript's text item delimiters to oldlim
--create file pointer for editing (if passing on to exiftool, this should not be necessary)
--set xmppath to POSIX file ("/Volumes/" & volumename & "/" & noExtension & ".xmp")
--exiftool version, text passed
set xmppath to ("/Volumes/" & volumename & "/" & noExtension & ".xmp")
end if
--get rating
set rating to value of other tag "MainRating"
set theScript to p_exiftool & (quoted form of xmppath) & " -xmp:Rating=" & rating
do shell script theScript
end tell
end repeat
end tell
end run
-- write xmp sidecar file routine, not being used, because we use exiftool
on writexmpFile(theContents, xmpFileName)
--tell application "Finder"
try
open for access xmpFileName with write permission
set eof of xmpFileName to 0
write (theContents) to xmpFileName starting at eof
close access xmpFileName
on error
try
close access xmpFileName
end try
end try
--end tell
end writexmpFile
--this part copied and adapted from Brett Gross-------------------------------------------------------------------------- --------------------------------
on getLibPath()
tell application "System Events" to set p_libPath to value of property list item "LibraryPath" of property list file ((path to preferences as Unicode text) & "com.apple.aperture.plist")
--add the path to the main Library database to this (added by joost de raeymaeker)
set p_libPath to p_libPath & "/Database/Library.apdb"
if ((offset of "~" in p_libPath) is not 0) then
-- set p_posix to POSIX file p_libPath
set p_script to "/bin/echo $HOME"
set p_homePath to (do shell script p_script)
set p_offset to offset of "~" in p_libPath
set p_path to text (p_offset + 1) thru -1 of p_libPath
set g_libPath to p_homePath & p_path as string
else
set g_libPath to p_libPath as string
end if
end getLibPath
--end brett gross part

Answer 1

Hi all,
I did this quick script to be able to update Ratings on referenced and online master files. It uses exiftool, so that should be installed. Also, it creates an empty xmp file if none exists, with only the rating in it, or it updates an already existing one with the rating. Aperture 3 doesn't export this by itself.
let me know if it works for you, it comes with no guarantee to work or do anything useful. careful with the line breaks, posting here chops things up a little sometimes.
cheers,
j
--script to create sidecar xmp files for referenced files without having to export masters. parts of the script (finding the file name) are by brett gross
--this script needs exiftool to work. http://www.sno.phy.queensu.ca/~phil/exiftool/ to get it
--it should create an empty xmp file with the aperture's rating, or update an already existing xmp file in place
property p_sql : "/usr/bin/sqlite3 "
property p_exiftool : "usr/bin/exiftool "
global g_libPath
on run
my getLibPath()
--counter for processed images, reset, just in case
set mastercount to 0
tell application "Aperture"
-- rule out any versions other than 3 of aperture, the database has a different structure
set ap_version to version as rich text
if the first character of ap_version is not "3" then
display dialog "This will only work with Aperture 3" buttons {"OK"} default button 1
return
end if
--get selected images
if not (exists selection) then
display dialog "You have to select at least one image" buttons {"OK"} default button 1
return
else
display dialog "You have selected " & (count of selection) & " images." & return & "Continue?" default button 1
end if
set theSel to selection
--run through the selected images
repeat with currentpic from 1 to count of theSel
tell item currentpic of theSel
-- only apply to referenced and online images
if referenced and online then
set mastercount to mastercount + 1
set curID to id
--use sqlite directly to get master file id of version id
--get master file id from version id
set theScript to p_sql & (quoted form of g_libPath) & " \"select masterUuid from RKVersion where uuid='" & curID & "'\""
set masterfileuid to do shell script theScript
--get master path name from master id
set theScript to p_sql & (quoted form of g_libPath) & " \"select imagePath from RKMaster where uuid='" & masterfileuid & "'\""
set imagepath to do shell script theScript
--get volume id from master id
set theScript to p_sql & (quoted form of g_libPath) & " \"select fileVolumeUuid from RKMaster where uuid='" & masterfileuid & "'\""
set volumeuid to do shell script theScript
--get volume name from volume id
set theScript to p_sql & (quoted form of g_libPath) & " \"select name from RKVolume where uuid='" & volumeuid & "'\""
--put them together
set volumename to do shell script theScript
--strips extension, seems to work for files and paths with more than one period
set oldlim to AppleScript's text item delimiters
set AppleScript's text item delimiters to "."
try --remove last extension only
set contador to text item -1 of imagepath
set noExtension to Unicode text 1 thru -((count of contador) + 2) of imagepath
on error --handle files with no extensions
set noExtension to imagepath
end try
set AppleScript's text item delimiters to oldlim
--create file pointer for editing (if passing on to exiftool, this should not be necessary)
--set xmppath to POSIX file ("/Volumes/" & volumename & "/" & noExtension & ".xmp")
--exiftool version, text passed
set xmppath to ("/Volumes/" & volumename & "/" & noExtension & ".xmp")
end if
--get rating
set rating to value of other tag "MainRating"
set theScript to p_exiftool & (quoted form of xmppath) & " -xmp:Rating=" & rating
do shell script theScript
end tell
end repeat
end tell
end run
-- write xmp sidecar file routine, not being used, because we use exiftool
on writexmpFile(theContents, xmpFileName)
--tell application "Finder"
try
open for access xmpFileName with write permission
set eof of xmpFileName to 0
write (theContents) to xmpFileName starting at eof
close access xmpFileName
on error
try
close access xmpFileName
end try
end try
--end tell
end writexmpFile
--this part copied and adapted from Brett Gross-------------------------------------------------------------------------- --------------------------------
on getLibPath()
tell application "System Events" to set p_libPath to value of property list item "LibraryPath" of property list file ((path to preferences as Unicode text) & "com.apple.aperture.plist")
--add the path to the main Library database to this (added by joost de raeymaeker)
set p_libPath to p_libPath & "/Database/Library.apdb"
if ((offset of "~" in p_libPath) is not 0) then
-- set p_posix to POSIX file p_libPath
set p_script to "/bin/echo $HOME"
set p_homePath to (do shell script p_script)
set p_offset to offset of "~" in p_libPath
set p_path to text (p_offset + 1) thru -1 of p_libPath
set g_libPath to p_homePath & p_path as string
else
set g_libPath to p_libPath as string
end if
end getLibPath
--end brett gross part