Script to move .MOV videos off Canon EOS_Digital CF card on mount?

Question

I use Adobe Lightroom as an integral part of my digital photography workflow, and I recently acquired a Canon EOS 5D Mark-II digital camera, which is capable of capturing 1920x1080 HD video.
The problem I am having is that Lightroom does not provide support for importing video, so every time I insert my compact flash card containing images and video captured using the 5D MKII, I am notified of videos on the card that cannot be transferred into my Lightroom database...I then have to click OK to dismiss this notification message, then I have to manually browse the card to find the movies and copy them to my computer manually...
While this might not seem like that big of an issue, I've become accustomed to this process being a completely automated, so to go back to having to perform a number of steps manually seems a bit too much like backtracking to me, so I was hoping that someone here might be able to help me automate this process via AppleScript...
*• Ideally, a script that could be executed on my "EOS_Digital" volume (my CF card's name, which will always remain the same), and will scour the contents of that volume for .MOV files, and upon finding such files, it would copy them all to my ~/Movies/ directory before then removing (deleting) them from the card completely...*
*• The CF card will also contain .THM files that correspond to the .MOV files to provide thumbnails of the .MOV files for Windows users...I would ideally like to have these moved along with the .MOV files to the ~/Movies/ directory (or trashed completely), because Lightroom give me a notification warning that they cannot be imported into the image database*
*• I would trigger the script via QuickSilver (or FastScripts, QuicKeys, etc), which I could do manually after inserting my CF card...*
I know it's a long shot that someone would be willing to help me out with this task, but any help at all would be greatly appreciated!!
Thanks so much, and I look forward to your responses!

Answer 1

Hello
If you are going to call the script manually when the target volume is mounted, try something like SCRIPT1.
--SCRIPT1
main()
on main()
set srcPath to "EOS_Digital:" -- # HFS path of source directory
set dstPath to (path to movies folder from user domain as Unicode text) -- # HFS path of destination directory
try
set src to quoted form of ((POSIX path of (srcPath as alias))'s text 1 thru -2)
set dst to quoted form of (POSIX path of (dstPath as alias))
on error errs number errn
display dialog errs & " " & errn with icon 2
error number -128
end try
set sh to "find " & src & " -type f \\(-iname '*.mov' -or -iname '*.thm' \\) -print0 | xargs -0 -J % mv % " & dst
do shell script sh
end main
--END OF SCRIPT1
If you want the script to be called automatically when the target volume gets mounted, try something like SCRIPT2.
You need to set up it as a Folder Action attached to /Volumes directory.
--SCRIPT2
Usage -
(1) Save this script as compiled script or script bundle in either of -
/Library/Scripts/Folder Action Scripts/
~/Library/Scripts/Folder Action Scripts/
(2) Using /Application/AppleScript/Folder Actions Setup,
enable Folder Actions for /Volumes directory and attach this script (saved in (1)) to it.
cf.
ASLG > Folder Actions Reference
http://developer.apple.com/documentation/applescript/Conceptual/AppleScriptLangG uide/
on adding folder items to da after receiving aa
set srcPath to "EOS_Digital:" -- # HFS path of source directory
set dstPath to (path to movies folder from user domain as Unicode text) -- # HFS path of destination directory
repeat with a in aa
set a to a's contents
if (a as Unicode text) = srcPath then
set src to quoted form of ((POSIX path of a)'s text 1 thru -2)
set dst to quoted form of (POSIX path of (dstPath as alias))
set sh to "find " & src & " -type f \\(-iname '*.mov' -or -iname '*.thm' \\) -print0 | xargs -0 -J % mv % " & dst
do shell script sh
end if
end repeat
end adding folder items to
--END OF SCRIPT2
Hope this may help,
H
PS. Please copy code from this web page, not from subscribed email text, for I escaped some characters for posting.
Message was edited by: Hiroto (fixed the link)