Selecting files of same color label in Applescript

Question

I am trying to write a script that will move files to a new folder based on the color label of the files.  So basically I want all files with a Red label to go to one folder, all Orange label files to go to a different folder etc.  I am having a problem figuring out how to select files by their color label.  I want this to be automated and not require any user input.  I have searched forums and even bought a couple books on Applescript but haven't been able to find my answer.
Any information would be very helpful,
Thanks
Charles

Answer 1

racinrandall wrote:
However when I move the files to the remote folders, the original file is still in the original folder.
The move command does the same thing as drag and drop
Drag a file and drop it in another partition copy the file, you must press the Command key to move the file.
But there is no command in the AppleScript Finder Dictionary to do this.
First solution : the mv command in a do shell script :
tell application "Finder"
      my moveFiles((files in folder "myfolder" whose label index is 1) as alias list, folder orangeFolder)
      my moveFiles((files in folder "myfolder" whose label index is 2) as alias list, folder anotherFolder)
end tell
on moveFiles(tFiles, destFolder)
      set tDir to quoted form of POSIX path of (destFolder as string)
      repeat with i in tFiles
            do shell script "/bin/mv -n " & (quoted form of POSIX path of i) & " " & tDir
      end repeat
end moveFiles
-- the -n option after /bin/mv equal  (Do not overwrite an existing file and the original file will not be moved)
-- use -f option to replace an existing file
Second solution : copy, delete and empty the trash
tell application "Finder"
      with timeout of 0 seconds
            set orangeFiles to files in folder "myfolder" whose label index is 1
            if orangeFiles is not {} then
                  duplicate orangeFiles to folder orangeFolder without replacing -- or with replacing
                  delete orangeFiles -- move files to trash
                  empty the trash
            end if
      end timeout
end tell