Sending PDF forms (created using SFP) as Email Attachment

Question

Hi,
     I have created bunch of ADOBE forms using SFP. They are not interactive forms. created using ADOBE Live cycle designer.
I have the Function module and by executing I can view the PDF form in print preview mode. But I have to save this in backend and attach to email.
I have a program that have to send one of the forms created in SFP as email attachment to outside SAP.
Please advice how to achieve this.
Thanks,
Sanjeev

Answer 1

Hi ,
Please find below a code sample for your requirement
*& Report  ZENVOI_PDF_MAIL
REPORT  zenvoi_pdf_mail MESSAGE-ID ad.
TYPE-POOLS : abap .
DATA : data_for_update TYPE zdemopdf ,
       hexa            TYPE solix_tab.
DATA : fm_name   TYPE funcname ,
       param     TYPE sfpoutputparams,
       doc_param TYPE sfpdocparams ,
       output    TYPE fpformoutput .
param-nodialog = abap_true. " suppress printer dialog popup
param-getpdf = abap_true.
doc_param-langu = sy-langu.
doc_param-country = 'FR'.
doc_param-fillable = abap_true.
doc_param-dynamic = abap_true.
CALL FUNCTION 'FP_FUNCTION_MODULE_NAME'
  EXPORTING
    i_name     = 'ZDEMO_PDF'
  IMPORTING
    e_funcname = fm_name.
CALL FUNCTION 'FP_JOB_OPEN'
  CHANGING
    ie_outputparams = param
  EXCEPTIONS
    cancel          = 1
    usage_error     = 2
    system_error    = 3
    internal_error  = 4.
CHECK sy-subrc EQ 0.
CALL FUNCTION fm_name
  EXPORTING
    /1bcdwb/docparams  = doc_param
    data_for_update    = data_for_update
  IMPORTING
    /1bcdwb/formoutput = output
  EXCEPTIONS
    usage_error        = 1
    system_error       = 2
    internal_error     = 3.
CALL FUNCTION 'FP_JOB_CLOSE'
  EXCEPTIONS
    usage_error    = 1
    system_error   = 2
    internal_error = 3
    OTHERS         = 4.
CALL FUNCTION 'SCMS_XSTRING_TO_BINARY'
  EXPORTING
    buffer     = output-pdf "PDF file from function module
  TABLES
    binary_tab = hexa.
* Envoi du mail
** CLASS-DEFINITIONS
DATA: send_request       TYPE REF TO cl_bcs.
DATA: document           TYPE REF TO cl_document_bcs.
*DATA: sender             TYPE REF TO cl_sapuser_bcs.
data: sender            TYPE REF TO if_sender_bcs.
DATA: recipient          TYPE REF TO if_recipient_bcs.
** INTERNAL TABLES
DATA: l_mailtext TYPE soli_tab.
DATA: iaddsmtp   TYPE TABLE OF bapiadsmtp.
DATA: ireturn    TYPE TABLE OF bapiret2.
** VARIABLES
DATA: mail_line  LIKE LINE OF l_mailtext.
DATA: bapiadsmtp         TYPE bapiadsmtp.
DATA: subject    TYPE so_obj_des.
DATA : att_subject TYPE so_obj_des.
DATA : w_except TYPE REF TO cx_root .
CONSTANTS : c_defmail TYPE ad_smtpadr VALUE
                 '[email protected]' .
FIELD-SYMBOLS : <smtp> TYPE bapiadsmtp.
*Set subject of the mail
subject = 'Exemple de PDF interactif'.
* Set text of the mail
mail_line = 'Merci de remplir le formulaire et nous le retourner'.
APPEND mail_line TO l_mailtext .
att_subject = 'Template du PDF'.
TRY.
* Create persistent send request
    send_request = cl_bcs=>create_persistent( ).
* Get sender object
    sender = cl_sapuser_bcs=>create( sy-uname ).
*    sender =
*      cl_cam_address_bcs=>create_internet_address( '[email protected]' ) .
* Add sender
    CALL METHOD send_request->set_sender
      EXPORTING
        i_sender = sender.
* Read the E-Mail address for the user
*    CALL FUNCTION 'BAPI_USER_GET_DETAIL'
*      EXPORTING
*        username = sy-uname
*      TABLES
*        return   = ireturn
*        addsmtp  = iaddsmtp.
*    LOOP AT iaddsmtp ASSIGNING <smtp> WHERE std_no = 'X'.
*      CLEAR bapiadsmtp.
*      MOVE <smtp> TO bapiadsmtp.
*    ENDLOOP.
*    CASE bapiadsmtp-e_mail.
*      WHEN space.
        recipient =
     cl_cam_address_bcs=>create_internet_address( c_defmail ).
*      WHEN OTHERS.
*        recipient =
*     cl_cam_address_bcs=>create_internet_address( bapiadsmtp-e_mail ).
*    ENDCASE.
* Add recipient with its respective attributes to send request
    CALL METHOD send_request->add_recipient
      EXPORTING
        i_recipient  = recipient
        i_express    = 'X'
        i_copy       = space
        i_blind_copy = space
        i_no_forward = space.
* Set that you don't need a Return Status E-mail
    CALL METHOD send_request->set_status_attributes
      EXPORTING
        i_requested_status = 'E'
        i_status_mail      = 'E'.
* set send immediately flag
    send_request->set_send_immediately( 'X' ).
*Build Document
    document = cl_document_bcs=>create_document(
                        i_type    = 'RAW'
                        i_text    = l_mailtext
                        i_subject = subject ).
*     add attachment to document
    CALL METHOD document->add_attachment
      EXPORTING
        i_attachment_type    = 'PDF'
        i_attachment_subject = att_subject
        i_att_content_hex    = hexa.
* Add document to send request
    CALL METHOD send_request->set_document( document ).
* Send document
    CALL METHOD send_request->send( ).
    COMMIT WORK.
  CATCH cx_send_req_bcs INTO w_except.
  CATCH cx_address_bcs INTO w_except.
  CATCH cx_document_bcs INTO w_except.
ENDTRY.
Hope this help you .
Best regards