SO_NEW_DOCUMENT_ATT_SEND_API1 Error (Email not received)

Question

Hi all,<br><br>
I am using following code just to send out an email to Users Notifying that Directory is Not empty. No attachment is required.
<br><br><pre>
data: p_file type salfile-longname.
data: ifile type table of  salfldir with header line.
data: lt_mailrecipients  type standard table of somlrec90 with header line,
      lt_mailtxt         type standard table of soli      with header line,
      lt_attachment      type standard table of solisti1  with header line,
      lt_mailsubject     type sodocchgi1,
      lt_packing_list    type standard table of sopcklsti1 with header line,
      gv_cnt             type i.
data: v_spool          like tsp01-rqident.
p_file = '/usr/sap/tmp'.
call function 'RZL_READ_DIR_LOCAL'
  exporting
    name            = p_file
  tables
    file_tbl        = ifile
  exceptions
         argument_error = 1
         not_found      = 2
         others         = 3.
if ifile[] is initial.
  write: 'Empty'.
elseif ifile[] is not initial.
  lt_mailrecipients-rec_type  = 'U'.
  lt_mailrecipients-com_type  = 'INT'.
  lt_mailrecipients-receiver  = '*******''.
  append lt_mailrecipients.
  clear lt_mailrecipients.
  lt_mailtxt = 'Hi How are you'.
  append lt_mailtxt. clear lt_mailtxt.
  lt_mailtxt = 'direcory not empty'.
  append lt_mailtxt. clear lt_mailtxt.
  lt_mailsubject-obj_name     = 'MAILATTCH'.
  lt_mailsubject-obj_langu    = sy-langu.
  lt_mailsubject-obj_descr    = 'You have got mail'.
  lt_mailsubject-sensitivty   = 'F'.
  call function 'SO_NEW_DOCUMENT_ATT_SEND_API1'
    exporting
      document_data              = lt_mailsubject
      put_in_outbox              = 'X'
      commit_work                = 'X'
    tables
      packing_list               = lt_packing_list
      contents_bin               = lt_attachment
      contents_txt               = lt_mailtxt
      receivers                  = lt_mailrecipients
    exceptions
      too_many_receivers         = 1
      document_not_sent          = 2
      document_type_not_exist    = 3
      operation_no_authorization = 4
      parameter_error            = 5
      x_error                    = 6
      enqueue_error              = 7
      others                     = 8.
  if sy-subrc eq 0.
    commit work.
    write: 'Non Empty'.
    submit rsconn01 with mode = 'INT' and return.
  endif.
endif.</pre><br><br>
The code runs fine without any error and writes "Non empty" as output but no email is received. We also have "INT - Internet" configured in SCOT, which shows no request.<br>
Please let me know if anything more needs to be configured.<br><br>
Thanks<br><br>
Diksha.<br><br>
<br><br><br><br> Edited by: Matt on Nov 4, 2009 7:58 AM - fixed formatting

Answer 1

Hi all,
Thanks for your help. I really appreciate it.
Here is my code which works.
*& Report  ZBW_KHALIX_BI_CHECK_PRG
report  zbw_khalix_bi_check_prg.
data: p_file type epsf-epsdirnam.
data: ifile type table of epsfili with header line.
data: lt_mailrecipients  type standard table of somlrec90 with header line,
      lt_mailtxt         type standard table of soli      with header line,
      lt_attachment      type standard table of solisti1  with header line,
      lt_mailsubject     type sodocchgi1,
      lt_packing_list    type standard table of sopcklsti1 with header line,
      gv_cnt             type i.
data: v_spool          like tsp01-rqident.
data: oref type ref to cx_root.
data text type string.
p_file = '/userdata/home/bw_outbound1/temp'.
try.
    call function 'EPS_GET_DIRECTORY_LISTING'
      exporting
        dir_name               = p_file
      tables
        dir_list               = ifile
      exceptions
        invalid_eps_subdir     = 1
        sapgparam_failed       = 2
        build_directory_failed = 3
        no_authorization       = 4
        read_directory_failed  = 5
        too_many_read_errors   = 6
        empty_directory_list   = 7
        others                 = 8.
  catch cx_root into oref.
    text = oref->get_text( ).
endtry.
if ifile[] is initial.
  write: 'Empty'.
elseif ifile[] is not initial.
  lt_mailrecipients-rec_type  = 'U'.
  lt_mailrecipients-com_type  = 'INT'.
  lt_mailrecipients-receiver  = '*****'.
  append lt_mailrecipients.
  clear lt_mailrecipients.
  lt_mailtxt = 'Hi How are you'.
  append lt_mailtxt. clear lt_mailtxt.
  lt_mailtxt = 'direcory is not empty'.
  append lt_mailtxt. clear lt_mailtxt.
  lt_mailsubject-obj_name     = 'MAILATTCH'.
  lt_mailsubject-obj_langu    = sy-langu.
  lt_mailsubject-obj_descr    = 'You have got mail'.
  lt_mailsubject-sensitivty   = 'F'.
  lt_packing_list-transf_bin  = space.
  lt_packing_list-head_start  = 1.
  lt_packing_list-head_num    = 0.
  lt_packing_list-body_start  = 1.
  lt_packing_list-body_num    = lines( lt_mailtxt ).
  lt_packing_list-doc_type    = 'RAW'.
  append lt_packing_list. clear lt_packing_list.
  call function 'SO_NEW_DOCUMENT_ATT_SEND_API1'
    exporting
      document_data              = lt_mailsubject
      put_in_outbox              = 'X'
      commit_work                = 'X'
    tables
      packing_list               = lt_packing_list
      contents_bin               = lt_attachment
      contents_txt               = lt_mailtxt
      receivers                  = lt_mailrecipients
    exceptions
      too_many_receivers         = 1
      document_not_sent          = 2
      document_type_not_exist    = 3
      operation_no_authorization = 4
      parameter_error            = 5
      x_error                    = 6
      enqueue_error              = 7
      others                     = 8.
  case sy-subrc.
    when 1.
      write: / 'No authorization for sending to the specified number',
      'of recipients'.
    when 2.
      write: / 'Document could not be sent to any recipient'.
    when 4.
      write: / 'No send authorization'.
    when 5.
      write: / 'Parameter error'.
    when 6.
      write: / 'x_error'.
    when 7.
      write: / 'enqueue error'.
    when 8.
      write: / 'Error occurred while sending'.
  endcase.
endif.
Can anyone tell me if we can create a .txt file through ABAP?
Thanks
Diksha
Edited by: Diksha Chopra on Nov 4, 2009 8:08 PM