Solver VBA SolverAdd constraints with decimals not possible

Question

This issue is related to the German versions of Excel, it tried all from XL2002 up to XL2013.
I can add a constrain with decimals to the solver manually and it works as expected:
When I record a macro the recorded constrain line is this:
SolverAdd CellRef:="$A$1", Relation:=3, FormulaText:="0,001"
But when I run that line the constrain is always ">= 1", the decimal part is missing! I tried all variations that I can think of, but nothing works. When I run this macro:
Sub Makro1()
SolverReset
SolverAdd CellRef:="$A$1", Relation:=3, FormulaText:=0.001
SolverAdd CellRef:="$A$1", Relation:=3, FormulaText:="0.001"
SolverAdd CellRef:="$A$1", Relation:=3, FormulaText:="0,001"
End Sub
The result is this:
How can I set a constrain with decimals into the Solver?
Andreas.

Answer 1

The answer for this from Frontline Systems Inc. is:
This is an old VBA bug.
Just use:
FormulaText:="=1"
Rather than
FormulaText:="1"
That sounds strange... "old VBA bug"?? VBA is able to detect and work with the language depended decimal delimiters and such things!
So I went a little into the depths and have looked more closely at SOLVER.XLAM and there I found the bug:
If "." <> Application.International(xlDecimalSeparator) Then
dummy = InStr(FormulaText, Application.International(xlDecimalSeparator))
Do While dummy <> 0
Mid(FormulaText, dummy, 1) = "."
dummy = InStr(FormulaText, Application.International(xlDecimalSeparator))
Loop
End If
If Not IsNumeric(FormulaText) Then
On Error Resume Next
If TypeName(FormulaText) = "Range" And Not IsCellReference(Stylecheck(CStr(FormulaText))) Then
FormulaText = FormulaText.Address
End If
FormulaText = CStr(FormulaText)
FormulaText = Stylecheck(FormulaText)
On Error GoTo mainerror
Else
FormulaText = CDbl(FormulaText)
End If
They replace the "," with a "." and then they call CDBL (and not VAL), that is the reason.
In Germany (Europe) the "." is the thousand delimiter and the "," is the decimal delimiter. And CDBL knows that!
Okay, so why does "=0,0001" work? Obvious the CBDL line isn't executed in this case.
The solver routines creates hidden names in the sheet and store anything there. If you like to see them execute this:
Sub ShowNames()
Dim N As Name
For Each N In Names
N.Visible = True
Next
End Sub
And names are also language depended, but when we want to store values into a name we have to "speak" English.
The code changes "=0,0001" to "=0.0001" and stores that into the name manager. So when we look into the names we can see "=0,0001" at screen (in Europe).
And the Solve routines grabs that values... what a mess. :-)
If you want to write language-independent programs therefore this syntax is recommended:
  SolverAdd "A1", 3, "=" & 0.0001
Andreas.