Stack type from oracle website

Question

I am trying to create the stack type from oracle's site:
http://download.oracle.com/docs/cd/B10500_01/appdev.920/a96624/10_objs.htm#4139
However, I don't know how to use it exactly as it yields NULL SELF error every time I try to initialize it! How do I pop and push?
CREATE TYPE Stack AS OBJECT (
max_size INTEGER,
top INTEGER,
position IntArray,
MEMBER PROCEDURE initialize,
MEMBER FUNCTION full RETURN BOOLEAN,
MEMBER FUNCTION empty RETURN BOOLEAN,
MEMBER PROCEDURE push (n IN INTEGER),
MEMBER PROCEDURE pop (n OUT INTEGER)
Finally, you write the object type body:
CREATE TYPE BODY Stack AS
MEMBER PROCEDURE initialize IS
BEGIN
top := 0;
/* Call constructor for varray and set element 1 to NULL. */
position := IntArray(NULL);
max_size := position.LIMIT; -- get varray size constraint
position.EXTEND(max_size - 1, 1); -- copy element 1 into 2..25
END initialize;
MEMBER FUNCTION full RETURN BOOLEAN IS
BEGIN
RETURN (top = max_size); -- return TRUE if stack is full
END full;
MEMBER FUNCTION empty RETURN BOOLEAN IS
BEGIN
RETURN (top = 0); -- return TRUE if stack is empty
END empty;
MEMBER PROCEDURE push (n IN INTEGER) IS
BEGIN
IF NOT full THEN
top := top + 1; -- push integer onto stack
position(top) := n;
ELSE -- stack is full
RAISE_APPLICATION_ERROR(-20101, 'stack overflow');
END IF;
END push;
MEMBER PROCEDURE pop (n OUT INTEGER) IS
BEGIN
IF NOT empty THEN
n := position(top);
top := top - 1; -- pop integer off stack
ELSE -- stack is empty
RAISE_APPLICATION_ERROR(-20102, 'stack underflow');
END IF;
END pop;
END;

Answer 1

I would write it using a collection rather than a varray myself:
SQL> create type IntArray AS table of integer
  2  /
Type created.
SQL>
SQL> CREATE TYPE Stack AS OBJECT (
  2    max_size INTEGER,
  3    top INTEGER,
  4    position IntArray,
  5    MEMBER PROCEDURE initialize(p_max_size IN INTEGER),
  6    MEMBER FUNCTION full RETURN BOOLEAN,
  7    MEMBER FUNCTION empty RETURN BOOLEAN,
  8    MEMBER PROCEDURE push (n IN INTEGER),
  9    MEMBER PROCEDURE pop (n OUT INTEGER)
10    );
11  /
Type created.
SQL>
SQL> CREATE TYPE BODY Stack AS
  2    MEMBER PROCEDURE initialize(p_max_size IN INTEGER) IS
  3    BEGIN
  4      max_size := p_max_size;
  5      top := 0;
  6      position := IntArray(NULL);
  7      position.EXTEND(max_size - 1, 1);
  8    END initialize;
  9    --
10    MEMBER FUNCTION full RETURN BOOLEAN IS
11    BEGIN
12      RETURN (top = max_size); -- return TRUE if stack is full
13    END full;
14    --
15    MEMBER FUNCTION empty RETURN BOOLEAN IS
16    BEGIN
17      RETURN (top = 0); -- return TRUE if stack is empty
18    END empty;
19    --
20    MEMBER PROCEDURE push (n IN INTEGER) IS
21    BEGIN
22      IF NOT full THEN
23        top := top + 1; -- push integer onto stack
24        position(top) := n;
25      ELSE -- stack is full
26        RAISE_APPLICATION_ERROR(-20101, 'stack overflow');
27      END IF;
28    END push;
29    --
30    MEMBER PROCEDURE pop (n OUT INTEGER) IS
31    BEGIN
32      IF NOT empty THEN
33        n := position(top);
34        top := top - 1; -- pop integer off stack
35      ELSE -- stack is empty
36        RAISE_APPLICATION_ERROR(-20102, 'stack underflow');
37      END IF;
38    END pop;
39  END;
40  /
Type body created.
SQL>
SQL> DECLARE
  2    v_stack Stack := Stack(null,null,null);
  3    v_n INTEGER;
  4  BEGIN
  5    v_stack.initialize(10);
  6    FOR i in 1..20
  7    LOOP
  8      IF NOT v_stack.full THEN
  9        v_stack.push(i);
10        dbms_output.put_line('Pushed: '||i);
11      ELSE
12        dbms_output.put_line('Stack Full: '||i);
13      END IF;
14    END LOOP;
15    FOR i in 1..20
16    LOOP
17      v_stack.pop(v_n);
18      dbms_output.put_line('Popped: '||i||' : '||v_n);
19    END LOOP;
20  END;
21  /
Pushed: 1
Pushed: 2
Pushed: 3
Pushed: 4
Pushed: 5
Pushed: 6
Pushed: 7
Pushed: 8
Pushed: 9
Pushed: 10
Stack Full: 11
Stack Full: 12
Stack Full: 13
Stack Full: 14
Stack Full: 15
Stack Full: 16
Stack Full: 17
Stack Full: 18
Stack Full: 19
Stack Full: 20
Popped: 1 : 10
Popped: 2 : 9
Popped: 3 : 8
Popped: 4 : 7
Popped: 5 : 6
Popped: 6 : 5
Popped: 7 : 4
Popped: 8 : 3
Popped: 9 : 2
Popped: 10 : 1
DECLARE
ERROR at line 1:
ORA-20102: stack underflow
ORA-06512: at "SCOTT.STACK", line 36
ORA-06512: at line 17
SQL>When you instantiate the object, you have to supply values for the object attributes, but those values can simply be null. This is the nature of object instantiation because, without values, it wouldn't be an object, it would just be a null declaration of the object class. You don't have to declare variables outside of the object and pass those in, as you did for your varray.