Stuck with exception syntax .

Question

Hi,
got code like that
declare
in_use exception;
  pragma exception_init(in_use, -54);
l_when date default sysdate ;
l_stoptime date default sysdate + 1/(24*60);
begin
while l_when <= l_stoptime
loop
for rec in (select indeX_name from dba_indexes where owner = 'USER' and table_name = 'TEST1')
loop
   dbms_output.put_line('in1' || l_when);
   dbms_output.put_line('in2' || l_stoptime);
   execute immediate 'alter index ' || rec.index_name  || ' rebuild ' ;
   exception
     when in_use then null;
end loop;
dbms_output.put_line('outside');
l_when := sysdate ;
dbms_lock.sleep(3);
end loop;
end ;
/But when trying to run getting exception
   exception
ERROR at line 14:
ORA-06550: line 14, column 4:
PLS-00103: Encountered the symbol "EXCEPTION" when expecting one of the following:
( begin case declare end exit for goto if loop mod null
pragma raise return select update while with <an identifier>
<a double-quoted delimited-identifier> <a bind variable> <<
continue close current delete fetch lock insert open rollback
savepoint set sql execute commit forall merge pipe purge
ORA-06550: line 17, column 1:
PLS-00103: Encountered the symbol "DBMS_OUTPUT" when expecting one of the following:
end not pragma final instantiable order overriding static
member constructor map
ORA-06550: line 17, column 32:
PLS-00103: Encountered the symbol ";" when expecting one of the following:
. ( , * % & - + / at mod remainder rem <an identifier>
<a double-quoted delimited-identifier> <an exponent (**)> as
from into || multiset bulkBasically I want to continue loop in case of resource busy exception .
Regards
GregG

Answer 1

Try this:
declare
  in_use exception;
  pragma exception_init(in_use
                       ,-54);
  l_when     date default sysdate;
  l_stoptime date default sysdate + 1 /(24 * 60);
begin
  while l_when <= l_stoptime loop
    for rec in (select index_name
                  from dba_indexes
                 where owner = 'USER'
                   and table_name = 'TEST1') loop
      begin
        dbms_output.put_line('in1' || l_when);
        dbms_output.put_line('in2' || l_stoptime);
        execute immediate 'alter index ' || rec.index_name || ' rebuild ';
      exception
        when in_use then
          null;
      end;
    end loop;
    dbms_output.put_line('outside');
    l_when := sysdate;
    dbms_lock.sleep(3);
  end loop;
end;
/Though I'm not sure why you're looping around with the stoptime. The inner loop will
rebuild all your indexes for the table specified, then you wait 3 seconds and then build them all again
(if stoptime hasn't been reached).
Edited by: Paul Horth on Jan 18, 2013 10:43 AM