Updated Table Name Changes Applescript Operation in Numbers 3.5

Question

I've been using Applescript in Numbers for some time to copy/paste data (set cell values) from one sheet table to another sheet table.
My original script was heavily cribbed from something Yvan Koenig had posted 2-3 years ago.
I recently updated to Yosemite and Numbers 3.5 after testing to ensure my original script remained functional (and it did).
I subsequently updated my source data table by duplicating my old table and editing this new source.
I then updated my Applescript to to reference the new source table.
Testing yielded a good functional result, but Numbers changed its behavior by displaying its work while setting values in the target sheet table.
This obviously slows the script down and adds measurable processing time given the amount of data being moved.
Does anyone know how I can prevent this behavior from occurring?
I don't believe I changed anything material in my original script so I'm really not sure why Numbers changed its behavior.
I have included my script below.  Thanks very much for any help!
property the_goods : {}
property patient_name : {}
property patient_count : {}
property run_date : {}
on run
  set sheet_source to "1500 EXPORT"
  set table_source to "OA Data"
  set column_source to 1
  set row_source to 2
  set sheet_destination to "CLEARING HOUSE EXPORT"
  set table_destination to "Export Table"
  set column_destination to 1
  set nb_rows to 0
  set nb_columns to 244
  set patient_sheet to "SESSION DB"
  set patient_source to "User Input Table"
  set patient_tracker to "Tracking Table"
  set source_column to 3
  set source_row to 2
  set destination_column to 2
  set date_column to 3
  set patient_count_column to 3
  set patient_count_row to 3
  set run_date_row to 5
  tell application "Numbers"
  set document_source to name of front document as string
  set document_destination to name of front document as string
  end tell
  tell application "Numbers"
  tell document document_source to tell sheet patient_sheet to tell table patient_source
  set patient_count to value of cell patient_count_column of row patient_count_row
  set run_date to value of cell patient_count_column of row run_date_row
  end tell
  end tell
  set row_destination to patient_count
  tell application "Numbers"
  tell document document_source to tell sheet sheet_source to tell table table_source
  set the_goods to value of cells column_source thru (column_source + nb_columns) of rows row_source thru (row_source + nb_rows)
  end tell
  tell document document_destination to tell sheet sheet_destination to tell table table_destination
  set r to 0
  repeat with one_row in the_goods
  tell row (row_destination + r)
  set c to 0
  repeat with one_value in one_row
  set value of cell (column_destination + c - 0) to one_value
  set c to c + 1
  end repeat
  end tell
  set r to r + 1
  end repeat
  end tell
  tell document document_destination to tell sheet patient_sheet to tell table patient_source
  activate
  end tell
  tell document document_destination to tell sheet patient_sheet to tell table patient_source
  set patient_name to value of cell source_column of row source_row
  end tell
  tell document document_destination to tell sheet patient_sheet to tell table patient_tracker
  set value of cell destination_column of row row_destination to patient_name
  set value of cell date_column of row row_destination to run_date
  end tell
  end tell
  set the_goods to {}
  set patient_name to {}
  set patient_count to {}
  set run_date to {}
end run

Answer 1

Here is a simple example that copies values from a source row 3 in Table 1 to a target row 5 in Table 2.
On my aging MBA it was very fast (about a second) with 150 columns.
In addition to speed, an advantage of this approach is that you don't have to code table dimensions;  the target table will expand automatically if needed.
Save the script in a script folder (in my case ~/Library/Scripts/Applications/Numbers) and run it from there by choosing it from the script menu. (Running it from Script Editor will paste the values into Script Editor instead of into Numbers as you want).
If keeping the original number format is important, substitute 'formatted value'  for 'value' in the script.
SG
property src : {d:1, s:"Sheet 1", t:"Table 1", r:3}
property tgt : {d:1, s:1, t:"Table 2", r:5}
tell application "Numbers"
  tell document (src's d)
  tell sheet (src's s)
  tell table (src's t)
  tell row (src's r)
  set vv to cells's value -- makes AppleScript list
  set the clipboard to my makeTSV(vv)
  end tell
  end tell
  end tell
  end tell
  tell document (tgt's d)
  tell sheet (tgt's s)
  tell table (tgt's t)
  set the selection range to row (tgt's r)'s cell 1
  tell application "Numbers" to activate
  tell application "System Events" to keystroke "v" using {option down, shift down, command down}
  end tell
  end tell
  end tell
end tell
to makeTSV(aLst) -- turns AppleScript list into tab-delimited string
  set oTID to AppleScript's text item delimiters
  set AppleScript's text item delimiters to tab
  set tsvStr to aLst as text
  set AppleScript's text item delimiters to oTID
  return tsvStr
end makeTSV