Urgent: Problem in making Link b/w MKPF and BKPF

Question

Hi,
I am making a report in which i have to make a relationship b/w BKPF and MKPF through AWKEY present in the BKPF with the MBLNR field in MKPF.
Plzzz help me how to do dis as i am having the select statement like dis: -
SELECT AMBLNR AXBLNR BBELNR BBUDAT BGJAHR BAWKEY FROM MKPF AS A  INNER JOIN BKPF AS B ON BXBLNR = AXBLNR INTO TABLE ITBSAK WHERE AXBLNR > 0 AND BBELNR IN P_BELNR.
plzz help me out how to reterive data as in dis statement i am not using the AWKEY concept .plzz help me how do i do this as help will be definately rewarded.

Answer 1

Hi check this sample code:
form get_data.
*************----------- VARIABLES ---------------**************
data: vl_addrnum type t499s-addrnum,
vl_city1 type adrc-city1.
*************----------- Constants ---------------------**************
constants:cl_ca01(4) value 'CA01'.
***********---------Field symbols ----------------------************
field-symbols: <fs_mseg> type t_mseg.
select a~mblnr a~mjahr a~zeile a~werks a~matnr a~bwart
a~lifnr a~menge a~meins a~lgort a~grund a~sakto
a~ps_psp_pnr a~ablad a~rsnum a~rspos a~kostl
a~umlgo a~wempf a~ebeln a~ebelp a~bukrs a~belnr
a~buzei a~sobkz
b~budat b~xblnr b~bktxt b~xabln b~frbnr b~cputm
c~matkl a~kzvbr a~shkzg
from mseg as a
join mkpf as b
on a~mblnr = b~mblnr and
a~mjahr = b~mjahr
join mara as c
on c~matnr = a~matnr
into table i_mseg
where a~werks in s_werks and
a~bwart in s_bwart and
a~lifnr in s_lifnr and
a~umwrk in s_umwrk and
a~wempf in s_scar and
a~ablad in s_ablad and
a~ebeln in s_ebeln and
a~sjahr in s_yyyy and
b~budat in s_date and
b~cputm in s_time and
b~mjahr in s_yyyy.
if not i_mseg[] is initial.
select pspnr fkokr fkstl posid stort
from prps
into table i_prps
for all entries in i_mseg
where pspnr eq i_mseg-ps_psp_pnr.
select bwart sobkz btext from t156t
into table i_text
for all entries in i_mseg
where bwart eq i_mseg-bwart
and spras eq v_lan
and sobkz eq i_mseg-sobkz
and kzvbr eq i_mseg-kzvbr.
select lifnr name1 from lfa1
into table i_lfa1
for all entries in i_mseg
where lifnr eq i_mseg-lifnr.
endif.
*Awkey is the combination of MBLNR and MJAHR
loop at i_mseg assigning <fs_mseg>.
concatenate <fs_mseg>-mblnr <fs_mseg>-mjahr into <fs_mseg>-awkey.
*To get the Vertex Catagory
move <fs_mseg>-matnr to w_ztfi_product-matnr.
move <fs_mseg>-matkl to w_ztfi_product-matkl.
select single prdtc
from ztfi_product
into w_ztfi_product-prdtc
where matkl eq w_ztfi_product-matkl.
append w_ztfi_product to i_ztfi_product.
endloop.
if not i_mseg[] is initial.
select bukrs belnr gjahr awkey waers
from bkpf
into table i_bkpf
for all entries in i_mseg
where gjahr = i_mseg-mjahr
and bukrs = i_mseg-bukrs
and budat = i_mseg-budat
and awkey = i_mseg-awkey.
select matnr maktx from makt
into table i_makt
for all entries in i_mseg
where matnr = i_mseg-matnr
and spras = v_lan.
endif.
if not i_bkpf[] is initial.
select bukrs " Company Code
belnr " Document Number
gjahr " Fiscal Year
buzei " Line Item
shkzg " Debit / Credit indicator
wrbtr " Amount
sgtxt " Line Item Text
vbund " Trading Partner
kostl " Cost Center
hkont " Account
matnr " Material Number
werks " Plants
txjcd " Tax Jurisdiction
projk " WBS Element
into table i_bseg
from bseg
for all entries in i_bkpf
where bukrs eq i_bkpf-bukrs and
belnr eq i_bkpf-belnr and
gjahr eq i_bkpf-gjahr.
endif.
sort: i_prps by pspnr,
i_bkpf by bukrs awkey gjahr,
i_makt by matnr,
i_bseg by bukrs belnr gjahr,
i_text by bwart sobkz.
*Move to output table
loop at i_mseg into w_mseg.
move-corresponding w_mseg to w_output.
if not w_mseg-lifnr is initial.
select single name1 from lfa1
into w_output-name1
where lifnr = w_mseg-lifnr.
endif.
read table i_prps into w_prps with key pspnr = w_mseg-ps_psp_pnr
binary search.
if sy-subrc eq 0.
move-corresponding w_prps to w_output.
if not w_prps-fkstl is initial and not w_prps-fkokr is initial.
select single ktext from cskt
into w_output-ktext
where spras = sy-langu
and kokrs = w_prps-fkokr
and kostl = w_prps-fkstl
and datbi ge sy-datum.
endif.
select single addrnum from t499s into vl_addrnum
where stand = w_prps-stort.
select single city1 from adrc into vl_city1
where addrnumber = vl_addrnum
and addr_group = cl_ca01.
w_output-city1 = vl_city1.
endif.
read table i_text into w_text with key bwart = w_mseg-bwart
sobkz = w_mseg-sobkz
binary search.
if sy-subrc eq 0.
w_output-btext = w_text-btext.
endif.
read table i_makt into w_makt with key matnr = w_mseg-matnr
binary search.
if sy-subrc eq 0.
w_output-maktx = w_makt-maktx.
endif.
read table i_bkpf into w_bkpf with key bukrs = w_mseg-bukrs
awkey = w_mseg-awkey
gjahr = w_mseg-mjahr
binary search.
if sy-subrc eq 0.
move-corresponding w_bkpf to w_output.
read table i_bseg into w_bseg with key bukrs = w_bkpf-bukrs
belnr = w_bkpf-belnr
gjahr = w_bkpf-gjahr
binary search.
if sy-subrc eq 0.
move-corresponding w_bseg to w_output.
w_output-matnr = w_mseg-matnr.
w_output-werks = w_mseg-werks.
if w_mseg-shkzg = 'H'. " checking the mseg value.
w_output-wrbtr = - w_bseg-wrbtr.
w_output-menge = - w_output-menge.
endif.
perform cal_vertex_tax using w_bseg changing w_output-wmwst.
endif.
endif.
perform format_output using w_output-matnr
w_output-wrbtr w_output-budat
w_output-rsnum w_output-rspos.
append w_output to i_output.
clear: w_output, vl_city1, w_prps,vl_addrnum, w_text, w_makt,
w_bkpf, w_bseg.
endloop.
endform. " get_data