VBA to identify a group of tasks being updated

Question

Good Afternoon,
I have not had much luck with Project questions here, but now that I have dug a little deeper I think I can ask a question that you may be able to help with. If any of you know of a better place to find Project VBA advice, please let me know! 
This question is also gathering dust over at UA. http://www.utteraccess.com/forum/Custom-Macros-Project-20-t2022616.html
First off, I am writing a macro that is triggered when a task is updated in project. I used the code from this page as a starting point.
http://msdn.microsoft.com/en-us/library/ee...fice.12%29.aspx
The macro I wrote works well. I changed the code up a bit so that it runs each time the user sets a task to 100% complete. When the user sets a task to 100% complete, the macro pulls today's date and adds it to the custom date field (Date2).
My next challenge is to warn the user if they update start or finish dates for a task with a specific tag in a text field (Text15). This new functionality will be embedded with the previous functionality I already wrote. Here is the problem. When I need to
update a bunch of tasks, or when I update one task that changes other tasks due to links, the event is triggered for each and every task. This creates lots of message boxes that I don't need.
On the surface this makes sense because I want to know each time a task changes, but from a practicality standpoint I only need to be notified once for each group of tasks that are updated. For example, if I update one date, and linking causes 10 other dates
to change, I only want to be notified once. Similarly, if I highlight and change multiple dates I only want to get warned about it once, not once for each task.
To achieve this I think I need to access some kind of collection that represents the set of tasks that are being updated as a result of user input. This is where I need help. I am not sure how to access this information.
For your information here are the code elements I have written for the existing macro.
This section goes in "ThisProject":
<code>
Private Sub Project_Open(ByVal pj As Project)
   EnableEvents
End Sub
</code>
This section goes in a module named "modTaskUpdate":
<code>
Public TskUpdate As New clsTaskUpdate
Sub EnableEvents()
   Set TskUpdate.App = MSProject.Application
End Sub
</code>
Finally, this section goes in a Class Module named "clsTaskUpdate":
<code>
Public WithEvents App As MSProject.Application
Private Sub App_ProjectBeforeTaskChange(ByVal tsk As Task, ByVal Field As Long, ByVal NewVal As Variant, Cancel As Boolean)
'Code for managing 100% complete and Date Completed
'(This part works OK, see the next section for the code I need to modify)
    If ((Field = pjTaskPercentComplete) And (NewVal = 100)) Then
        'Add today's date to completed date field
        'MsgBox "Adding today's date: " & Date & " to the Date2(DateCompleted) field."
        tsk.Date2 = Date
    End If
    If ((Field = pjTaskPercentComplete) And (NewVal = 0)) Then
        'Remove date from completed date field
        'MsgBox "Removing date from the Date2(DateCompleted) field."
        tsk.Date2 = ""
    End If
'Code for managing warnings to user if PST dates will change.
' Currently this message is triggered for each task that causes a change.
' Can we only trigger this task once for each group of changed dates?
    If ((Field = pjTaskStart) Or (Field = pjTaskFinish)) Then
        If (insrt(tsk.Text15, "PST") <> 0) Then
            MsgBox "Warning! You have changed a date that is linked to a line in the PST. As a result the PST has been automatically updated."
        End If
    End If
End Sub
</code>
FYI: The PST is an external Excel file that has its values automatically update via linked cells in Project.
Thank you for your time and consideration.
Please let me know if you have any questions.
Nate

Answer 1

Nate,
Yes, as far as I know, there is no "collection" of task changes. Remember, a collection is a group of objects and a change isn't an object.
I see you found one of the posts I responded to regarding paste links. If you have ABSOLUTE file discipline management, then you might be okay with paste links, but since there is a much better alternative (i.e. VBA) to do what you need I'd avoid the paste
link idea. As Clint Eastwood said in his Dirty Harry movie, "Do you feel lucky?"
There have been various posts with code to export Project data to Excel. Unfortunately I find the search capabilities of these forums to be sorely lacking so rather than a link, here is some sample code you can adapt.
Option Explicit
Sub CalendarExceptions()
'Basic macro code created by Kiran.K and posted on MSDN Project
' customizing and programming forum Feb 7,2013
'Code streamlined and updated by John - Project June 2,2014
Dim MyXL As Object
Set MyXL = CreateObject("Excel.Application")
Dim i As Integer, j As Integer
Dim E As Exception
Dim r As Resource
Dim xlRng As Range
'open Excel, define workbook, and set column headers
MyXL.Workbooks.Add
MyXL.Visible = True
MyXL.ActiveWorkbook.Worksheets.Add.Name = "Exception Report"
MyXL.ActiveWorkbook.Worksheets("Exception Report").Activate
Set xlRng = MyXL.ActiveSheet.Range("A1")
xlRng.Range("A1") = "Proj Cal Holidays"
xlRng.Range("B1") = "Start Date"
xlRng.Range("C1") = "Finish Date"
xlRng.Range("E1") = "Res Name"
xlRng.Range("F1") = "Res Base Cal"
xlRng.Range("G1") = "Base Cal Excep"
xlRng.Range("H1") = "Start Date"
xlRng.Range("I1") = "Finish Date"
xlRng.Range("K1") = "Resource Name"
xlRng.Range("L1") = "Res Excep"
xlRng.Range("M1") = "Start Date"
xlRng.Range("N1") = "Finish Date"
'First gather and export Project calendar exceptions
i = 2
If ActiveProject.Calendar.Exceptions.Count > 0 Then
    For Each E In ActiveProject.Calendar.Exceptions
        xlRng.Range("A" & i) = E.Name
        xlRng.Range("B" & i) = E.Start
        xlRng.Range("C" & i) = E.Finish
        i = i + 1
    Next
End If
'Next, gather and export resource base calendar exceptions along with
'   resource calendar exceptions
i = 2
For Each r In ActiveProject.Resources
    If Not r Is Nothing Then
        j = i
        If r.Type = pjResourceTypeWork Then
                For Each E In r.Calendar.BaseCalendar.Exceptions
                    xlRng.Range("E" & i) = r.Name
                    xlRng.Range("F" & i) = r.Calendar.BaseCalendar.Name
                    xlRng.Range("G" & i) = E.Name
                    xlRng.Range("H" & i) = E.Start
                    xlRng.Range("I" & i) = E.Finish
                    i = i + 1
                Next E
                For Each E In r.Calendar.Exceptions
                    xlRng.Range("K" & j) = r.Name
                    xlRng.Range("L" & j) = E.Name
                    xlRng.Range("M" & j) = E.Start
                    xlRng.Range("N" & j) = E.Finish
                    j = j + 1
                Next E
        End If
    End If
Next r
MyXL.ActiveWorkbook.Worksheets("Exception Report").Columns("A:N").AutoFit
End Sub
John