Want to create program (XYZ) for scheduling anther program(ABC)

Question

Requirement :
I have one report ABC and I want to create program XYZ for scheduling the report ABC (without executing the program ABC ).
Output : Program XYZ
1) schedule the report ABC
2) Provide the output of ABC

Answer 1

Seee if the below code help:
REPORT Z_MQSCHD NO STANDARD PAGE HEADING LINE-SIZE 170 LINE-COUNT 58 .
DATA: ZCOUNT            LIKE SY-TABIX,
      JOBNAME           LIKE TBTCJOB-JOBNAME,
      PARAMS            LIKE  PRI_PARAMS,
      JOBCOUNT          LIKE TBTCJOB-JOBCOUNT,
      AUTHCKNAM         LIKE  TBTCJOB-AUTHCKNAM,
      SDLSTRTTM         LIKE  TBTCJOB-SDLSTRTTM,
      SDLSTRTDT         LIKE  TBTCJOB-SDLSTRTDT,
      VARIANT           LIKE  RALDB-VARIANT,
      REPORT            LIKE  SY-REPID,
      ZTIME             LIKE SY-UZEIT,
      PREDJOB_CHECKSTAT LIKE TBTCSTRT-CHECKSTAT,
      PRED_JOBCOUNT     LIKE TBTCJOB-JOBCOUNT,
      PRED_JOBNAME      LIKE TBTCJOB-JOBNAME,
      RELEASED          LIKE  BTCH0000-CHAR1.
*email variables
DATA:  emailaddr(80)     TYPE c.
data: objtxt           like solisti1   occurs 10 with header line.
data: tab_lines        like sy-tabix.
DATA: OBJECT_HD_CHANGE LIKE SOOD1.
DATA: OBJECT_TYPE LIKE SOOD-OBJTP.
DATA: OBJCONT LIKE SOLI OCCURS 0 WITH HEADER LINE.
DATA: RECEIVERS LIKE SOOS1 OCCURS 0 WITH HEADER LINE.
SELECTION-SCREEN: BEGIN OF BLOCK A1 WITH FRAME TITLE TEXT-001.
PARAMETERS:
        NAME LIKE RS38M-PROGRAMM OBLIGATORY,
        VAR  LIKE RS38M-SELSET  OBLIGATORY,
        JOB  LIKE TBTCJOB-JOBNAME,
        FRQ1 LIKE SY-INDEX,
        FRQ2(2) TYPE C.
SELECTION-SCREEN END OF BLOCK A1.
SELECTION-SCREEN: BEGIN OF BLOCK A2 WITH FRAME TITLE TEXT-002.
PARAMETERS: ZDATE LIKE SY-DATUM DEFAULT SY-DATUM OBLIGATORY.
SELECT-OPTIONS:
        TIME1 FOR SY-UZEIT OBLIGATORY.
SELECTION-SCREEN END OF BLOCK A2.
SELECTION-SCREEN: BEGIN OF BLOCK A3 WITH FRAME TITLE TEXT-003.
PARAMETERS:  p_mail       AS CHECKBOX DEFAULT 'X'. "X = Mail report
SELECT-OPTIONS: so_mlist FOR emailaddr.
SELECTION-SCREEN END OF BLOCK A3.
AT SELECTION-SCREEN ON FRQ2.
  IF FRQ2 NE 'H' AND FRQ2 NE 'M' AND FRQ2 NE 'S'.
    MESSAGE E001(Z1) WITH 'Time Unit must be H or M or S'.
  ENDIF.
AT SELECTION-SCREEN ON ZDATE.
  IF ZDATE < SY-DATUM.
    MESSAGE E001(Z1) WITH 'Date must be greater than current date'.
  ENDIF.
AT SELECTION-SCREEN ON TIME1.
  IF ZDATE = SY-DATUM AND TIME1-LOW < SY-UZEIT.
    MESSAGE E001(Z1) WITH 'Time must be greater than current time'.
  ENDIF.
AT SELECTION-SCREEN OUTPUT.
  IF JOB IS INITIAL.
    JOB = NAME.
  ENDIF.
$$* Start of selection
START-OF-SELECTION.
  IF JOB IS INITIAL.
    JOB = NAME.
  ENDIF.
  clear params.
  call function 'GET_PRINT_PARAMETERS'
       EXPORTING
            mode           = 'CURRENT'
            no_dialog      = 'X'
       IMPORTING
            out_parameters = params.
  params-paart = 'X_PAPER'.
  ZTIME       = TIME1-LOW.
  JOBNAME      = JOB.
  VARIANT      = VAR.
  REPORT       = NAME.
  AUTHCKNAM    = SY-UNAME.
  PARAMS-PRIMM = SPACE.
  SDLSTRTDT    = ZDATE.
  CLEAR: ZCOUNT.
  WHILE ZTIME LE TIME1-HIGH.
    SDLSTRTTM = ZTIME.
    CALL FUNCTION 'JOB_OPEN'
         EXPORTING
              JOBNAME  = JOB
         IMPORTING
              JOBCOUNT = JOBCOUNT
         EXCEPTIONS
              OTHERS   = 4.
    CALL FUNCTION 'JOB_SUBMIT'
         EXPORTING
              AUTHCKNAM = AUTHCKNAM
              JOBCOUNT  = JOBCOUNT
              JOBNAME   = JOB
              PRIPARAMS = PARAMS
              REPORT    = REPORT
              VARIANT   = VARIANT.
    CALL FUNCTION 'JOB_CLOSE'
         EXPORTING
              SDLSTRTDT        = SDLSTRTDT
              SDLSTRTTM        = SDLSTRTTM
              JOBCOUNT         = JOBCOUNT
              JOBNAME          = JOB
         IMPORTING
              JOB_WAS_RELEASED = RELEASED.
    IF RELEASED = 'X'.
      WRITE: / 'Job', JOBNAME, '(' ,JOBCOUNT, ')' ,'will run at', ZTIME,
          'on', ZDATE, 'with program',NAME, 'and variant', VAR.
      IF NOT P_MAIL IS INITIAL.
        CLEAR OBJCONT.
        CONCATENATE
        'Job' JOBNAME '(' JOBCOUNT ')' 'will run at' ZTIME 'on' ZDATE
       'with program' NAME  'and variant'  VAR
        INTO OBJCONT SEPARATED BY SPACE.
        APPEND OBJCONT.
      ENDIF.
    ELSE.
      WRITE: /
     'Unable to release job', JOBNAME, '(' ,JOBCOUNT, ')' ,'at', ZTIME,
        'on', ZDATE, 'with program',NAME, 'and variant', VAR.
      IF NOT P_MAIL IS INITIAL.
        CLEAR OBJCONT.
        CONCATENATE
       'Unable to release job' JOBNAME  '('  JOBCOUNT ')'  'at'  ZTIME
       'on' ZDATE 'with program' NAME  'and variant'  VAR
        INTO OBJCONT SEPARATED BY SPACE.
        APPEND OBJCONT.
      ENDIF.
    ENDIF.
    CASE FRQ2.
      WHEN 'H'.
        ZTIME = ZTIME + ( 60 * 60 * FRQ1 ).
      WHEN 'M'.
        ZTIME = ZTIME + ( 60 * FRQ1 ).
      WHEN 'S'.
        ZTIME = ZTIME + FRQ1.
      WHEN OTHERS.
    ENDCASE.
  ENDWHILE.
  IF NOT P_MAIL IS INITIAL.
    CHECK NOT SO_MLIST IS INITIAL.
    PERFORM SENDEMAIL.
  ENDIF.
*&      Form  SENDEMAIL
      text
-->  p1        text
<--  p2        text
FORM SENDEMAIL.
  clear objcont.
  append objcont.
  append objcont.
  concatenate
  'This e-mail was sent from an automated system...' sy-sysid sy-mandt
     into objcont.
  append objcont.
  clear objcont.
  objcont = 'Do not reply to this message.'(013).
  append objcont.
  MOVE: SY-LANGU TO OBJECT_HD_CHANGE-OBJLA,
        'NOTIFICATION' TO OBJECT_HD_CHANGE-OBJNAM,
        'Report from job scheduler' TO OBJECT_HD_CHANGE-OBJDES.
  MOVE 'RAW' TO OBJECT_TYPE.
  describe table objtxt lines tab_lines.
  read table objtxt index tab_lines.
*Now we will create the packing list entry for our text body.
  describe table objtxt lines tab_lines.
  read table objtxt index tab_lines.
  OBJECT_HD_CHANGE-OBJLEN  = tab_lines * 255.
*in this next section we create our recipient list.
  LOOP AT so_mlist.
    clear RECEIVERS.
    move so_mlist-low to RECEIVERS-RECEXTNAM.
    MOVE 'U' TO RECEIVERS-RECESC.
    APPEND RECEIVERS.
    if not so_mlist-high is initial.
      move so_mlist-high TO RECEIVERS-RECEXTNAM.
      MOVE 'U' TO RECEIVERS-RECESC.
      APPEND RECEIVERS.
    endif.
  ENDLOOP.
  CALL FUNCTION 'SO_OBJECT_SEND'
       EXPORTING
            OBJECT_HD_CHANGE           = OBJECT_HD_CHANGE
            OBJECT_TYPE                = OBJECT_TYPE
       TABLES
            OBJCONT                    = OBJCONT
            RECEIVERS                  = RECEIVERS
       EXCEPTIONS
            ACTIVE_USER_NOT_EXIST      = 1
            COMMUNICATION_FAILURE      = 2
            COMPONENT_NOT_AVAILABLE    = 3
            FOLDER_NOT_EXIST           = 4
            FOLDER_NO_AUTHORIZATION    = 5
            FORWARDER_NOT_EXIST        = 6
            NOTE_NOT_EXIST             = 7
            OBJECT_NOT_EXIST           = 8
            OBJECT_NOT_SENT            = 9
            OBJECT_NO_AUTHORIZATION    = 10
            OBJECT_TYPE_NOT_EXIST      = 11
            OPERATION_NO_AUTHORIZATION = 12
            OWNER_NOT_EXIST            = 13
            PARAMETER_ERROR            = 14
            SUBSTITUTE_NOT_ACTIVE      = 15
            SUBSTITUTE_NOT_DEFINED     = 16
            SYSTEM_FAILURE             = 17
            TOO_MUCH_RECEIVERS         = 18
            USER_NOT_EXIST             = 19
            ORIGINATOR_NOT_EXIST       = 20
            X_ERROR                    = 21
            OTHERS                     = 22.
  IF SY-SUBRC <> 0.
MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
        WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
  ENDIF.
ENDFORM.                    " SENDEMAIL