What will be output of this cursor ?

Question

hi all,
I am in learning stage, find following example from net and want to know about what will be output of v_emp_data type
DECLARE
      CURSOR ABC_EMP
      IS
      SELECT EMPNO,
             ENAME,
             DEPTNO,
             SAL
        FROM EMP;
      TYPE v_sal_type IS TABLE OF NUMBER
         INDEX BY VARCHAR2 (50);
      v_emp_data    v_sal_type;
BEGIN
      FOR V_EMP_REC IN ABC_EMP
      LOOP
         v_emp_data (
               LPAD (V_EMP_REC.EMPNO, 4, ' ')
            || LPAD (V_EMP_REC.ENAME, 10, ' ')
            || LPAD (V_EMP_REC.DEPTNO, 2, ' ')) :=
            V_EMP_REC.SAL;
         DBMS_OUTPUT.PUT_LINE (v_emp_data.Count);
      END LOOP;
END;
it is showing 1 to 14 which is no. of records  but how I can see the actual data it contain. please help.
regards.

Answer 1

SQL> DECLARE
  2        CURSOR ABC_EMP
  3        IS
  4        SELECT EMPNO,
  5              ENAME,
  6              DEPTNO,
  7              SAL
  8          FROM EMP;
  9        --
10        TYPE v_sal_type IS TABLE OF NUMBER
11          INDEX BY VARCHAR2 (50);
12        --
13        v_emp_data    v_sal_type;
14        v_index varchar2(50);
15  BEGIN
16        FOR V_EMP_REC IN ABC_EMP
17        LOOP
18          v_emp_data (
19                LPAD (V_EMP_REC.EMPNO, 4, ' ')
20              || LPAD (V_EMP_REC.ENAME, 10, ' ')
21              || LPAD (V_EMP_REC.DEPTNO, 2, ' ')) :=
22              V_EMP_REC.SAL;
23        END LOOP;
24        DBMS_OUTPUT.PUT_LINE(v_emp_data.Count);
25          v_index := v_emp_data.FIRST;
26        LOOP
27          EXIT WHEN v_index IS NULL;
28          DBMS_OUTPUT.PUT_LINE('INDEX: ' || v_index || '        VALUE: ' ||  v_emp_data(v_index));
29          v_index := v_emp_data.NEXT(v_index);
30        END LOOP;
31  END;
32  /
14
INDEX: 7369    SMITH20        VALUE: 800
INDEX: 7499    ALLEN30        VALUE: 1600
INDEX: 7521      WARD30       VALUE: 1250
INDEX: 7566    JONES20        VALUE: 2975
INDEX: 7654    MARTIN30       VALUE: 1250
INDEX: 7698    BLAKE30        VALUE: 2850
INDEX: 7782    CLARK10        VALUE: 2450
INDEX: 7788    SCOTT20        VALUE: 3000
INDEX: 7839      KING10       VALUE: 5000
INDEX: 7844    TURNER30       VALUE: 1500
INDEX: 7876    ADAMS20        VALUE: 1100
INDEX: 7900    JAMES30        VALUE: 950
INDEX: 7902      FORD20       VALUE: 3000
INDEX: 7934    MILLER10       VALUE: 1300
PL/SQL procedure successfully completed.
SQL>
SY.