Will a report see the results of a POST?

Question

Hello friends at www.oracle.com ,
let's suppose I edit data through Forms and, after editing them, I'll press a forms button called 'Print' that will print these data by calling Reports. But if I've updated these data by using POST built-in, will Reports find these data?
Thanks, and best regards,
Franklin Gongalves Jr.

Answer 1

A report can't see the results of a POST built-in.
Forms and Reports can't run in the same database session.
Forms must commit data (COMMIT_FORM) before using in Reports.
In simple cases you can transfer data from Forms to Reports using record groups
(and then, after printing, commit data in Forms).
One simple example - Forms transfers to Reports records from DEPT block:
DECLARE
rg_id_l RECORDGROUP;
rg_name_l VARCHAR2 (30) := 'DEPT';
row_count_l NUMBER;
rgc_id_l GROUPCOLUMN;
pl_id_l PARAMLIST;
pl_name_l VARCHAR2 (30) := 'PARAM_LIST';
BEGIN
rg_id_l := FIND_GROUP (rg_name_l);
IF NOT ID_NULL (rg_id_l) THEN
DELETE_GROUP (rg_id_l);
END IF;
rg_id_l := CREATE_GROUP (rg_name_l);
rgc_id_l := ADD_GROUP_COLUMN (rg_id_l, 'deptno', NUMBER_COLUMN);
rgc_id_l := ADD_GROUP_COLUMN (rg_id_l, 'dname', CHAR_COLUMN, 14);
rgc_id_l := ADD_GROUP_COLUMN (rg_id_l, 'loc', CHAR_COLUMN, 13);
GO_BLOCK ('dept');
FIRST_RECORD;
row_count_l := 0;
LOOP
row_count_l := row_count_l + 1;
ADD_GROUP_ROW (rg_id_l, row_count_l);
SET_GROUP_NUMBER_CELL (rg_name_l || '.deptno', row_count_l, :dept.deptno);
SET_GROUP_CHAR_CELL (rg_name_l || '.dname', row_count_l, :dept.dname);
SET_GROUP_CHAR_CELL (rg_name_l || '.loc', row_count_l, :dept.loc);
EXIT WHEN :SYSTEM.LAST_RECORD = 'TRUE';
NEXT_RECORD;
END LOOP;
IF row_count_l = 0 THEN
MESSAGE ('Nothing to print'); PAUSE;
RETURN;
END IF;
pl_id_l := GET_PARAMETER_LIST (pl_name_l);
IF NOT ID_NULL (pl_id_l) THEN
DESTROY_PARAMETER_LIST (pl_id_l);
END IF;
pl_id_l := CREATE_PARAMETER_LIST (pl_name_l);
ADD_PARAMETER (pl_id_l, 'Q_1', DATA_PARAMETER, rg_name_l);
RUN_PRODUCT (REPORTS, 'REC_GROUP_REPORT', SYNCHRONOUS, RUNTIME, FILESYSTEM, pl_id_l, NULL);
DESTROY_PARAMETER_LIST (pl_id_l);
DELETE_GROUP (rg_id_l);
END;
Reports module must have query with the same name as parameter in ADD_PARAMETER statement
(in this code - Q_1), and SQL Query Statement in Reports must have
same number and type of columns as record group, for example:
SELECT ROWID, 1 deptno, 'x' dname, 'x' loc FROM DUAL
Best regards
Zlatko Sirotic