Word Count, but only words over certain number of letter...?

Question

Hi,
Does anyone know of a way to do a word count, but only count the words with a certain number of letters. For example all words with 4 letters or more?
Thanks

Answer 1

I never guessed that I will read such a question but why not ?
--(SCRIPT word4Count.app]
--==========
Enregistrer le script en tant qu'Application ou Progiciel : word4count.app
déplacer l'application créée dans le dossier
<VolumeDeDémarrage>:Users:<votreCompte>:Library:Scripts:Applications:Pages:
Il vous faudra peut-être créer le dossier Pages et même le dossier Applications.
menu Scripts > Pages > word4count
Le script affiche (ou insère à l'emplacement du curseur )
le nombre de mots de la couche texte et
le nombre de mots des blocs texte
dont la longueur est supérieure à la valeur définie par la property limite.
--=====
L'aide du Finder explique:
L'Utilitaire AppleScript permet d'activer le Menu des scripts :
Ouvrez l'Utilitaire AppleScript situé dans le dossier Applications/AppleScript.
Cochez la case "Afficher le menu des scripts dans la barre de menus".
--=====
Grace au programme gratuit ThisService, il est possible d'encapsuler ce script dans un service.
Télécharger ThisService depuis:
http://wafflesoftware.net/thisservice/
Lors de la création du service, cliquer le bouton "Produce output".
Il est possible d'associer un raccourci clavier au service.
--==========
Copy the script in the clipboard
Paste in a blank window of Script Editor
Save it as an Application or an Application Bundle
Move the newly created application into the folder:
<startup Volume>:Users:<yourAccount>:Library:Scripts:Applications:Pages:
Now, enter your Pages document.
Click where you want.
Go to
menu Scripts > Pages > word4count
The script will count the words whose length is higher than the value stored in the property limite.
The wordcount will be pasted at the insertion point
--=====
The Finder's Help explains:
To make the Script menu appear:
Open the AppleScript utility located in Applications/AppleScript.
Select the "Show Script Menu in menu bar" checkbox.
--=====
Thanks to the free program ThisService, we may encapsulate this script in a Service.
Download ThisService from
http://wafflesoftware.net/thisservice/
When creating the service click the button "Produce output"
We may link the service to a shortcut.
--==========
Yvan KOENIG
19 février 2009
--=====
property limite : 4
property affiche : true
--=====
property theApp : "Pages"
property ws : {}
--=====
on process()
set rezult to my commun()
tell application "System Events"
activate
display dialog rezult
end tell
return ""
end process
--=====
on commun()
local liste1, liste2, ng, c1, c2
--set my ws to {}
tell application "Pages" to tell document 1
set liste1 to words of body text
set liste2 to {}
set ng to count of graphic
repeat with i from 1 to ng
tell graphic i
try
copy items of (get words of object text) to end of liste2
end try
end tell -- graphic i
end repeat
(* Working this way we are counting the words as they are defined by Pages *)
end tell -- document 1 of Pages
if liste1 is not {} then
set my ws to liste1
set c1 to my compte4()
else
set c1 to 0
end if
if liste2 is not {} then
set my ws to liste2
set c2 to my compte4()
else
set c2 to 0
end if
set my ws to {}
if my parlefrancais() then
return "Nombre de mots dont la longueur dépasse " & limite & return & "dans la couche texte : " & c1 & return & "dans des blocs : " & c2
else
return "Count of words whose length is greater than " & limite & return & "in text layer : " & c1 & return & "in text blocks : " & c2
end if
end commun
--=====
on compte4()
local wc, w
set wc to 0
repeat with w in my ws
if length of (w as text) > limite then set wc to wc + 1
end repeat
return wc
end compte4
--=====
on parlefrancais()
local z
try
tell application theApp to set z to localized string "Cancel"
on error
set z to "Cancel"
end try
return (z = "Annuler")
end parlefrancais
--=====
on run
set rezult to my commun()
if affiche then (*
display the results *)
tell application theApp to display dialog rezult
else (*
insert the results in the text body *)
tell application "Pages" to tell document 1 to set selection to rezult
end if
end run
--=====
--[/SCRIPT]
Yvan KOENIG (from FRANCE jeudi 19 février 2009 15:45:56)