XML download from blob

Question

Hi
I have a table which has blob column which is xml file. I need to extract xml file and store to local desktop.
Please help me.
Thanks
Ranga

Answer 1

This example generates some XML into an XMLTYPE, turns it into a BLOB and then saves it out to file...
DECLARE
   -- Data Variables
   v_xml              XMLTYPE;
   v_blob             BLOB;
   v_data_length      NUMBER;
   -- Loop Control Variables
   v_offset           NUMBER             DEFAULT 1;
   v_chunk   CONSTANT NUMBER             DEFAULT 4000;
   -- UTL_FILE variables
   fh                 UTL_FILE.file_type;
BEGIN
   -- A big query, about 27k on my PC
   SELECT XMLELEMENT ("Employees", XMLAGG (emp_dept))
     INTO v_xml
     FROM (SELECT XMLELEMENT
                     ("Employee",
                      XMLFOREST
                         (e.employee_id AS "EmployeeId",
                          e.last_name AS "Name",
                          e.job_id AS "Job",
                          e.manager_id AS "Manager",
                          e.hire_date AS "HireDate",
                          e.salary AS "Salary",
                          e.commission_pct AS "Commission",
                          XMLFOREST (d.department_id AS "DeptNo",
                                     d.department_name AS "DeptName",
                                     d.location_id AS "Location"
                                    ) AS "Dept"
                     ) emp_dept
             FROM employees e, departments d
            WHERE e.department_id = d.department_id);
   -- Turn the XML into a BLOB to bypass any 4k and 32k issues
   v_blob := v_xml.getblobval (1);
   v_data_length := DBMS_LOB.getlength (v_blob);
   -- Open the file
   fh := UTL_FILE.fopen ('XML_FILES', 'myxml.xml', 'wb', v_chunk);
   -- Da loop de loop
   LOOP
      -- Exit when our file offset is bigger than our file
      EXIT WHEN v_offset > v_data_length;
      -- Write the output chunk by chunk
      UTL_FILE.put_raw (fh, DBMS_LOB.SUBSTR (v_blob, v_chunk, v_offset),
                        TRUE);
      -- Increment the offset by the amount written
      v_offset := v_offset + v_chunk;
   END LOOP;
   -- Close the file and say byebye
   UTL_FILE.fclose (fh);
EXCEPTION
   WHEN NO_DATA_FOUND
   THEN
      -- We won't write any data, or even open the file,
      -- if the query return no rows
      NULL;
END;This next example simply queries a CLOB from the database and saves it to file...
DECLARE
  l_file    UTL_FILE.FILE_TYPE;
  l_clob    CLOB;
  l_buffer  VARCHAR2(32767);
  l_amount  BINARY_INTEGER := 32767;
  l_pos     INTEGER := 1;
BEGIN
  SELECT col1
  INTO   l_clob
  FROM   tab1
  WHERE  rownum = 1;
  l_file := UTL_FILE.fopen('DOCUMENTS', 'Sample2.txt', 'w', 32767);
  LOOP
    DBMS_LOB.read (l_clob, l_amount, l_pos, l_buffer);
    UTL_FILE.put(l_file, l_buffer);
    l_pos := l_pos + l_amount;
  END LOOP;
EXCEPTION
  WHEN OTHERS THEN
    DBMS_OUTPUT.put_line(SQLERRM);
    UTL_FILE.fclose(l_file);
END;The process will always finish with a NO_DATA_FOUND exception when the end of the CLOB is reached. For simplicity I've not trapped any of the possible UTL_FILE exceptions.
For details on using UTL_FILE...
http://www.psoug.org/reference/utl_file.html