A LOT of iTunes broken links/tracks after Music folder move...

Question

So yeah, I'm getting a TON of broken links / dead track links in iTunes after having to do two things to my iTunes install recently and I'm at wits end trying to fix it.
I keep my iTunes Music Folder on an external and share the iTunes library between my work Macbook Pro and my home Macbook. Every Friday I drag my iTunes folder and all contents from my MBP onto an external and replace the iTunes folder on the 'weekend' MB, then do the same back on Monday. I keep my iTunes music 'View' as 'Date Added' so that I can always be listening to whatever is newest. It's how I roll.
Well, this week I had some data problems during the transfer and had to use a previous week's iTunes Music Folder, which was fine as I hadn't added much this week.
I also got a new external because the old one was getting a little shady, so after doing the iTunes Music Folder replacement I moved my music all over to a new external drive, told iTunes where it all was at. iTunes did it's thing, 'organized' my stuff and all seemed good - until I got back deeper into the catalogue of music and started getting a LOT of broken tracks. The songs are still there, in the correct folders and all, but for some reason iTunes isn't finding them.
When I say a LOT, I mean so far it's hundreds of my 13,000 songs.
Now I COULD use the 'Super Remove Dead Tracks' script from Doug's to find all the broken files then re-add the whole library, but it will add all the old songs out of order because they will get a new 'Added' date.
I could also manually move thru my whole library holding down the arrow key for 'Next' to find all the broken links then go thru, select them, and use the 'iTunes Track CPR' script from Doug's to re-add them to the library with ratings intact, but still they will be out of order time-wise.
I cannot find a script that will parse my library, find broken links, and re-associate them with their tracks, nor can I figure out why this happened and any other way to fix it. Repairing permissions hasn't helped. Any other ideas?

Answer 1

Just to follow up with a more comprehensive example of looping through a Library to detect & repair "missing" file-tracks:
<pre>
property kErrAENoSuchObject:(-1728)
on run
tell (application "iTunes")
set theLibraryPlaylist to (first library playlist)
tell theLibraryPlaylist
set theNumCandidateFileTracks to (count (every file track))
repeat with i from 1 to theNumCandidateFileTracks by 1
-- Get a reference to this file-track
set thisFileTrackRef to (file track i)
-- Get this file-track's info (useful for debugging, etc.)
set thisArtist to (artist of thisFileTrackRef)
set thisAlbum to (album of thisFileTrackRef)
set thisName to (name of thisFileTrackRef)
set thisFileTrackInfo to (thisArtist & " > " & thisAlbum & " > " & thisName)
-- Display a diagnostic message every 500th file-track
if ((i mod 500) = 0) then
tell me
display dialog ("Checking file-track #" & i & ": " & ¬
return & return & thisFileTrackInfo) ¬
buttons {"Cancel", "•"} giving up after 2.5
end tell -- me
end if
-- Retrieve this file-track's target file (an AS 'alias' object), if any
-- {!!! NOTE: Due to a bug in iTunes 7.x+ (esp. when downloading), AS might
-- be unable to access the 'location' field of some file-tracks !!!}
try
set thisFileTrackTargetFile to (location of thisFileTrackRef)
on error errMsg2 number errNum2
-- Check whether it's that bizarre error: (-1728) "Can't get location of …"
if (errNum2 = (kErrAENoSuchObject of me)) then
-- Set up to just skip this track (assume it's being downloaded)
set thisFileTrackTargetFile to (anything) -- (Other than 'missing value')
else (* Re-signal all other errors *)
error errMsg2 number errNum2
end if
end try
-- Check whether this file-track is "missing" its target file
if (thisFileTrackTargetFile = (missing value))
-- Inform the user
tell me
display dialog ("Repairing this missing file-track: " & ¬
return & return & thisFileTrackInfo) ¬
buttons {"Cancel", "•"} giving up after 2.5
end tell -- me
-- Set up this target file's new pathname (e.g., via explicit user input, or
-- better yet automatically reconstructed from this file-track's tags such
-- as Artist, Album, Name, Kind, etc.)
-- ... Translate this file-track's kind into a filename-extension
set thisKind to (kind of thisFileTrackRef)
set thisNameExt to "m4a" -- ... Default
if ({thisKind} is in {("Protected AAC audio file")}) then -- Older DRM'd file
set thisNameExt to "m4p"
else if ({thisKind} is in {("MPEG audio file")}) then -- MP3
set thisNameExt to "mp3"
else if (thisKind contains "movie file") then -- E.g., interactive booklet
set thisNameExt to "mov"
end -- (thisKind = "MPEG audio file") ... else if ... else ...
-- ... Auto-build this target file's new pathname
set thisTargetFileNewPathname to ("New Disk:New Path:" & ¬
thisArtist & ":" & thisAlbum & ":" & thisName & "." & thisNameExt)
-- Assign this new target file (as an AS 'alias' object) to this file-track
-- (This is the crucial step that was impossible in older versions of iTunes!)
set (location of thisFileTrackRef) to (alias thisTargetFileNewPathname)
end if -- (thisFileTrackTargetFile = (missing value))
end repeat -- with i from 1 to theNumCandidateFileTracks by 1
end tell -- theLibraryPlaylist
end tell -- (application "iTunes")
end run
</pre>
Regards,
--P