Address book save command

Question

the save command is never activated, only grayed out, I always have to export the all group. what is the save command for then. can you rename the all group.

Answer 1

I run this nightly, but you could run it more often. In OS X 10.3 iCal also regularly lost its data, so it makes local copies of both - you could easily remove the iCal part (it seems a lot more stable in 10.4).
Read the script before using!
AK
<pre style="font-family: 'Monaco', 'Courier New', Courier, monospace; overflow:auto; color: #222; background: #DDD; padding: 0.2em; font-size: 10px; width:400px">(* Backup locally the data files used by Address Book and iCal *)
(* copies are stored in ~/Library/CalBackup (created by the script) *)
(* Maintains MaxBackUps copies, most recent in folder "1", oldest in "MaxBackUps" *)
(* Save this as script CalBack in ~/Library/Scripts *)
(* Run it with cron, or as a repeating alarmed item in iCal (not recommended) *)
(* To set up for cron, start Terminal and give the command crontab -e *)
(* Type i to put the editor into insert mode *)
(* Type 1 1 * * * /users/xxxxxx/Library/Scripts/CalBack *)
(* but putting your login name instead of xxxxxx *)
(* then press the escape key to exit insert mode *)
(* Type to save the file and exit the editor, then quit the Terminal *)
(* The 1 1 * * * tells the timer to run the script at 1 minute past 1 am every day. If *)
(* you want it run at 27 minutes past 9 pm then change it to 27 21 * * * *)
(* AK March 2005 *)
set MaxBackups to 5 --change to suit your requirements
--pick up directory path
set WhoAmI to ((path to home folder) as string) & "Library"
set iCalPlace to WhoAmI & ":Application Support:iCal"
set ABPlace to WhoAmI & ":Application Support:AddressBook"
tell application "Finder"
--make our backup folder if necessary
if not (exists folder (WhoAmI & ":CalBackup")) then
make new folder with properties {name:"CalBackup"} at folder WhoAmI
end if
--Loose folder at limit
if exists folder (WhoAmI & ":CalBackup:" & (MaxBackups as string)) then
delete folder (WhoAmI & ":CalBackup:" & (MaxBackups as string))
end if
--Roll on backup folders
set TheCount to count of folder (WhoAmI & ":CalBackup:")
repeat with TheCount from TheCount to 1 by -1
set name of folder (WhoAmI & ":CalBackup:" & TheCount as string) to (TheCount + 1) as string
end repeat
--make new backup folder 1
make new folder with properties {name:"1"} at folder (WhoAmI & ":CalBackup")
duplicate every item of folder (iCalPlace) to folder (WhoAmI & ":CalBackup:1")
duplicate every item of folder (ABPlace) to folder (WhoAmI & ":CalBackup:1")
end tell
</pre>