Apple Script won't create new folder

Question

Hi all,
First of all, let me explain that in no particular way I am any good with applescript. I find it confusing at the best of times. I've got a bit of code that will check to see if a new folder is created in a specific location. If a new folder is created, then it will copy the name of the folder and create a new folder with the same name in a different place. The reason for this is that I separate my file types (I'm a photographer) and I keep my RAW files in one folder, my PSD files in another, my JPEGs in another and so on. The current code I have worked up until I installed Yosemite as well as Server on my mac mini. Here's the code:
on adding folder items to this_folder after receiving added_items
     set p to POSIX file "/Volumes/Projects/1. Raw"
     try
          tell application "Finder"
               repeat with item_ in added_items
                    if kind of item_ is "Folder" then --if its a folder then make another in Ra
                         make new folder at p with properties {name:item_}
                    end if
               end repeat
          end tell
     on error
          display dialog "Error occurred"
          return
     end try
end adding folder items to
The action is set to the JPEG folder, where an application automatically adds a folder (for this example, I'll use "z. test").
z. Test is detected in the JPEG folder, and then the folder is replicated across to the other separating folders ready for when any new files are added. Trouble is, the error occurred dialog box shows up. I have the appropriate permissions for the hard drives that the folders reside on, and are replicated to the subfolders too.
Is there anyway of finding out what the error is that's occurring? Or am I missing something since upgrading to Yosemite/Server? Any help would be most appreciated!
Ian
Th

Answer 1

Hi,
You can't rename an item with an object (the item_  is an object of type alias), use the name of item_
To know the error, use the parameter in on error block.
Try this :
on adding folder items to this_folder after receiving added_items
    try
        set p to "/Volumes/Projects/1. Raw" as POSIX file as alias
        tell application "Finder"
            repeat with item_ in added_items
                if kind of item_ is "Folder" then --if its a folder then make another in Ra
                    set tName to name of item_
                    make new folder at p with properties {name:tName}
                end if
            end repeat
        end tell
    on error err
        activate
        display dialog "Error occurred : " & err
    end try
end adding folder items to