Caluclate time for insertion

Question

hi ,
Heads up : oracle 10g
I have insert SQL script for insertion into table , It takes long time to insert into table.
I have tried loading by disable indexes , but some how want to discard that process and want to narrow down on how a batch of 100 rows take to insert from the insert SQL script . unfortunately I cant use wonderful features of SQLLDR . as the data come in excel format.
please help !

Answer 1

804282 wrote:
Yes , I make a repetitive (manual insert stmnts) SQL scripts. This means that each of these SQL statements need to be compiled (hard parsed). This is very expensive and consumes a lot of CPU. A better method is soft parsing - create a single SQL statement with bind variables. This compiled SQL can then be used and re-used again and again for inserting different row values.
Basically this requires a hard parse. Each of these SQL statements requires the SQL engine to create a cursor. A 100,000 SQL statements need to be executed, then a 100,000 cursors are created.
insert into foo_tab values( 1 );
insert into foo_tab values( 2 );
insert into foo_tab values( 100000 );The correct method is using bind variables. Your create a single SQL that contains bind variables. The SQL statement looks as follows:
insert into foo_tab values( :var );The +:var+ is a the bind variable - and this cursor is executed again and again by supplying different values, thereby inserting new rows. One cursor used for inserting a 100,000 rows.
Here's an practical example of the performance difference:
SQL> create table foo_tab( id number );
Table created.
SQL> var maxrows number
SQL> exec :maxrows := 100000;
PL/SQL procedure successfully completed.
SQL> -- insert using hard parsing
SQL> declare
  2          t1      number;
  3  begin
  4          t1 := dbms_utility.get_cpu_time;
  5          for i in 1..:maxrows
  6          loop
  7                  execute immediate 'insert into foo_tab values( '||i||' )';
  8          end loop;
  9          dbms_output.put_line( 'time: '||to_char(dbms_utility.get_cpu_time-t1) );
10          dbms_output.put_line( 'rows/sec: '||to_char (:maxrows/(dbms_utility.get_cpu_time-t1),9990.0));
11          rollback;
12  end;
13  /
time: 4144
rows/sec:    24
PL/SQL procedure successfully completed.
SQL> -- inserting using soft parsing
SQL> declare
  2          t1      number;
  3  begin
  4          t1 := dbms_utility.get_cpu_time;
  5          for i in 1..:maxrows
  6          loop
  7                  execute immediate 'insert into foo_tab values( :0 )' using i;
  8          end loop;
  9          dbms_output.put_line( 'time: '||to_char(dbms_utility.get_cpu_time-t1) );
10          dbms_output.put_line( 'rows/sec: '||to_char (:maxrows/(dbms_utility.get_cpu_time-t1),9990.0));
11          rollback;
12  end;
13  /
time: 304
rows/sec:   329
PL/SQL procedure successfully completed.
SQL> Using bind variables in the above example enables us to insert 329 rows per seconds. Not using bind variables and hard parsing instead, reduces the insert rate to 24 rows per second. That is more than a 100x slower!
So how do you do it using your data? You cannot with a SQL script - the SQL*Plus client is a bit primitive and does not provide the ability to turn a script containing a 100,000 insert statements into a bind variable statement. You can force cursor sharing for that Oracle session - this work-around will improve performance a little bit, but it will still be significantly slower than explicitly using bind variables.
Instead, you should look at using an external table or SQL*Loader and load the data in CSV format. These approaches will ensure that proper SQL is used with bind variables. It can also load in parallel using Oracle's Parallel Query feature.