Check if external program (MS Excel) is active and has opened a particular file

Question

All
I need to find some solution for next problem (Visual Studio 2010). I have a form with some buttons. Those buttons open Excel-files from a network share and the Excel-files are marked as shared (meaning they can be opened/edited by multiple users from different
computers at same time).
Anyway, when the user presses the button on the form, the file opens in Excel as expected. If he presses the button again, the file is opened again in a second Excel instance. I want to build in some check: if the file is already opened in an existing Excel
instance, that instance should become visible.
That's not all: there is a possibility the user already opened the Excel-file before he launched my application. If he then presses the button, the existing Excel-instance (with this particular file) must be shown.
Of course, the user can close his Excel file. So if he then presses the button, a new Excel instance should start up which opens the file.
How can this be done?
Regards
Kris

Answer 1

Hi,
 Here is an example that will find any instances of Excel and check if they have a specified file name opened.  If it is found it will bring the Excel window to the foreground or if it is minimized it will be restored.
Imports System.Runtime.InteropServices
Public Class Form1
<DllImport("user32.dll", EntryPoint:="SetForegroundWindow")> _
Private Shared Function SetForegroundWindow(ByVal hWnd As IntPtr) As <MarshalAs(UnmanagedType.Bool)> Boolean
End Function
<DllImport("user32.dll", EntryPoint:="ShowWindow")> _
Private Shared Function ShowWindow(ByVal hWnd As IntPtr, ByVal nCmdShow As Integer) As <MarshalAs(UnmanagedType.Bool)> Boolean
End Function
<DllImport("user32.dll", EntryPoint:="IsIconic")> _
Private Shared Function IsIconic(ByVal hWnd As IntPtr) As <MarshalAs(UnmanagedType.Bool)> Boolean
End Function
<UnmanagedFunctionPointer(CallingConvention.StdCall)> _
Private Delegate Function EnumCallBackDelegate(ByVal hwnd As IntPtr, ByVal lParam As IntPtr) As Integer
<DllImport("user32.dll", EntryPoint:="EnumChildWindows")> _
Private Shared Function EnumChildWindows(ByVal hWndParent As IntPtr, ByVal lpEnumFunc As EnumCallBackDelegate, ByVal lParam As Integer) As <MarshalAs(UnmanagedType.Bool)> Boolean
End Function
<DllImport("user32.dll", EntryPoint:="GetWindowTextW")> _
Private Shared Function GetWindowTextW(ByVal hWnd As IntPtr, <MarshalAs(UnmanagedType.LPWStr)> ByVal lpString As System.Text.StringBuilder, ByVal nMaxCount As Integer) As Integer
End Function
Private Const SW_RESTORE As Integer = &H9
Private ChildHandles As New List(Of IntPtr)
Private Sub Button1_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click
'Check if Excel has "My Excel File.xls" opened
If Not IsExcelFileOpen("My Excel File.xls") Then
MessageBox.Show("Excel does not have this file opened.")
Else
MessageBox.Show("Ecell has this file opened.")
End If
End Sub
Private Function IsExcelFileOpen(ByVal filename As String) As Boolean
ChildHandles.Clear()
For Each p As Process In Process.GetProcessesByName("EXCEL")
EnumChildWindows(p.MainWindowHandle, AddressOf EnumChildWindowProc, 0)
For Each h As IntPtr In ChildHandles
Dim sb As New System.Text.StringBuilder(256)
GetWindowTextW(h, sb, 256)
If sb.ToString.ToLower.Contains(filename.ToLower) Then
If IsIconic(p.MainWindowHandle) Then
ShowWindow(p.MainWindowHandle, SW_RESTORE)
Else
SetForegroundWindow(p.MainWindowHandle)
End If
Return True
End If
Next
Next
Return False
End Function
Private Function EnumChildWindowProc(ByVal hwnd As IntPtr, ByVal lParam As IntPtr) As Integer
ChildHandles.Add(hwnd)
Return 1
End Function
End Class
If you say it can`t be done then i`ll try it