Command-Key etc to start an App in 32-bit mode?

Question

Is there some sort of Command-Key etc to start an App in 32-bit mode, without having to go to "Get Info" ?
I have a Canoscan scanner which only runs in Photoshop under 32-bit mode. It would be nice to be able to launch PS into 32-bit mode when I need to, without going to Get Info.

Answer 1

Hi,
This AppleScript script doesn't change anything in (Get info), but launch the application in 32-bit mode.
property appName : missing value
property tpath : missing value
if appName is missing value then
      tell application "Finder"
            set appName to text 1 thru -5 of (get name of (application file id "com.adobe.Photoshop"))
            (application file id "com.adobe.Photoshop") as text
      end tell
      set tpath to quoted form of (POSIX path of (the result & ":Contents:MacOS:" & appName))
end if
get running of application appName
if the result then
      quit application appName
      tell application "System Events" to repeat while exists process appName
            delay 1
      end repeat
end if
do shell script "arch -i386 " & tpath & " > /dev/null 2>&1 &" -- launch (32-bit mode)
delay 1.5
activate application appName
Quit the application and restart to run in 64-bit mode.
To have a keyboard shortcut to run this script: you have some solutions
First solution: Make a service with Automator.
Second solution: There are some third party utilities that launches script, and you can set a keyboard shortcut.